Come esportare in batch più e-mail di Outlook in un documento di Word tramite VBA

Se desideri esportare in batch più e-mail di Outlook in un documento di una sola parola, puoi utilizzare il codice VBA mostrato in questo articolo. Può aiutarti a svolgere questo compito in pochi secondi.

Ho mai introdotto come convertire un'e-mail di Outlook in un documento di Word nel mio precedente articolo - "2 metodi efficaci per convertire un'e-mail di Outlook in un documento di Word”. Tuttavia, entrambi i 2 mezzi citati in quella post sarà impotente nel caso in cui desideri esportare in batch molte e-mail in un documento Word. Quindi, qui ti insegneremo un altro modo. Ora, continua a leggere per ottenerlo in modo elaborato.

Esporta in batch più e-mail di Outlook in un documento di Word

1. A start con, avvia il tuo programma Outlook.
2. Quindi, dopo essere entrati nella finestra principale di Outlook, è necessario premere i pulsanti "Alt + F11".
3. Successivamente avrai accesso all'editor VBA di Outlook, in cui dovresti aprire un modulo vuoto.
4. Successivamente, copia il codice VBA di seguito nella finestra del modulo aperta.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Successivamente, è meglio aggiungere questo nuovo progetto VBA alla barra degli strumenti o al nastro di accesso rapido.
6. Alla fine, puoi fare un tentativo.

• In primo luogo, seleziona più email di Outlook.
• Quindi individuare e fare clic sul pulsante macro appena aggiunto.
• Dopo aver richiesto "Completato", è possibile accedere alla cartella locale predefinita per trovare un nuovo documento di Word.
• Apri questo documento, in cui puoi vedere che tutte le email selezionate sono state esportate.

Mantieni un potente strumento di recupero nelle vicinanze

Nonostante le numerose funzioni, Outlook non può ancora essere immune da errori. Se sei abituato a lasciare da parte gli errori, con il loro accumulo, l'arresto anomalo di Outlook si verificherà sicuramente. A quel punto, è fondamentale ricorrere a uno strumento di recupero potente ed efficace, come DataNumen Outlook Repair. È molto esperto Correzione PST. Finché con esso, non dovrai più preoccuparti della perdita di dati di Outlook.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui mdf corrotto e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com