Come eliminare in batch tutte le conferme di lettura in Outlook

Per confermare che i destinatari abbiano letto la tua email, puoi richiedere una conferma di lettura durante la composizione del messaggio. In questo caso, la tua casella di posta potrebbe riempirsi di queste conferme di lettura. Questo articolo ti spiegherà come eliminarle definitivamente in blocco.

Dopo aver letto l'articolo "Come eliminare in batch tutte le ricevute di consegna in Outlook“, potresti pensare all'approccio per eliminare in blocco tutte le conferme di lettura. In effetti, la differenza manifesta tra i due tipi di ricevute è nei loro soggetti. La ricevuta di consegna contiene "Consegnato" nell'oggetto, ma la ricevuta di lettura contiene invece "Lettura". Pertanto, è possibile utilizzare lo stesso metodo per eliminare in batch tutte le conferme di lettura. Di seguito, ti insegneremo i passaggi concreti in dettaglio.

Batch Elimina tutte le conferme di lettura

1. Innanzitutto, avvia Outlook.
2. Quindi, vai all'editor VBA di Outlook tramite "Alt + F11" secondo "Come eseguire il codice VBA in Outlook".
3. Successivamente, nella nuova finestra, apri un modulo vuoto e inserisci il seguente codice.

Dim objOutlookFile As Outlook.Folder

Sub BatchDeleteAllReadReceipts()
    Dim objStore As Outlook.Store
    Dim objFolder As Outlook.Folder
    Dim lTotalCount As Long
 
    lTotalCount = 0
   'Process all Outlook files
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olMailItem Then
               Call ProcessFolders(objFolder, lTotalCount)
            End If
        Next
    Next
 
    'Prompt you of the results
    MsgBox lTotalCount & " read receipts are deleted!", vbInformation + vbOKOnly
End Sub

Sub ProcessFolders(ByVal objCurrentFolder As Outlook.Folder, lCount As Long)
    Dim i As Long
    Dim objDeliveryReceipt As Outlook.ReportItem
    Dim objSubfolder As Outlook.Folder
    Dim objDeletedItems As Outlook.Items
    Dim objItem As Object
 
    For i = objCurrentFolder.Items.Count To 1 Step -1
        'Find read receipts
        If (TypeOf objCurrentFolder.Items(i) Is ReportItem) And (Left(objCurrentFolder.Items(i).Subject, 5) = "Read:") Then
           Set objDeliveryReceipt = objCurrentFolder.Items.Item(i)
           objDeliveryReceipt.Delete
 
           lCount = lCount + 1
 
           'Permanently delete them
           Set objDeletedItems = objOutlookFile.Folders("Deleted Items").Items
           For Each objItem In objDeletedItems
               If (TypeOf objItem Is ReportItem) And (Left(objItem.Subject, 5) = "Read:") Then
                  objItem.Delete
               End If
           Next
         End If
    Next
 
    'Loop subfolders recursively
    If objCurrentFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurrentFolder.Folders
           Call ProcessFolders(objSubfolder, lCount)
       Next
    End If
End Sub

4. Successivamente, fai clic sulla prima subroutine.
5. Infine, premi il tasto "F5".
6. Immediatamente, la macro funzionerà per eliminare tutte le conferme di lettura dal tuo Outlook.
7. Al termine, riceverai un messaggio sul risultato, come lo screenshot qui sotto.
8. Al momento, puoi controllare le tue cartelle di posta. Tutte le conferme di lettura sono sparite.

Difendi i dati di Outlook

Sebbene il file di Outlook sia certamente suscettibile di corruzione, possiamo intraprendere azioni per salvaguardarlo. Ad esempio, dovremmo mantenere il file di Outlook di piccole dimensioni, proteggerlo da fattori dannosi ed eseguirne il backup su base regolare. Ultimo ma non meno importante, faresti meglio a preparare un potente strumento di riparazione PST esterno, come DataNumen Outlook Repair. Avrà un grande impatto sulla riparazione Outlook corrotto file.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui riparazione sql e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com