Come impostare automaticamente un tempo di promemoria diverso per le riunioni di Outlook in diverse categorie di colori

Se stai classificando le riunioni di Outlook in base a categorie di colori e desideri impostare tempi di promemoria diversi per le riunioni in diverse categorie di colori, puoi fare riferimento a questo articolo. Qui ti insegneremo a realizzarlo con Outlook VBA.

Ad esempio, si desidera suddividere le riunioni in due gruppi. Un gruppo rientra nella categoria "Fuori sede" perché la sede della riunione è troppo distante, mentre l'altro rientra nella categoria "In sede" perché la sede è vicina. Ora, si desidera che Outlook imposti automaticamente il promemoria per le riunioni "fuori sede" un'ora prima dell'inizio e per le riunioni "in sede" 15 minuti prima dell'inizio. Considerando questa esigenza, di seguito illustreremo un metodo rapido.

Imposta automaticamente un promemoria diverso per le riunioni in diverse categorie di colori

1. Per cominciare, avvia la tua applicazione Outlook.
2. Quindi, premi i pulsanti "Alt + F11" per accedere alla finestra dell'editor VBA.
3. Successivamente, nella finestra successiva, copia e incolla il codice VBA sottostante nel progetto "ThisOutlookSession".

Public WithEvents objCalendar As Outlook.Folder
Public WithEvents objCalendarItems As Outlook.Items

Private Sub Application_Startup()
    Set objCalendar = Outlook.Application.Session.GetDefaultFolder(olFolderCalendar)
    Set objCalendarItems = objCalendar.Items
End Sub

Private Sub objCalendarItems_ItemAdd(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub objCalendarItems_ItemChange(ByVal Item As Object)
    Call SetReminder_BasedOnCategories(Item)
End Sub

Private Sub SetReminder_BasedOnCategories(ByVal objCalendarItem As Object)
    Dim objMeeting As Outlook.AppointmentItem
    Dim strCategories As String
 
    If objCalendarItem.Class = olAppointment Then
       'Check if the item is a meeting
       If objCalendarItem.MeetingStatus = olMeeting Then
          Set objMeeting = objCalendarItem
          strCategories = objMeeting.Categories
 
          'Set Reminder as 60 min before start for offsite appointments
          If InStr(strCategories, "Offsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 60
                 .Save
             End With
             'Set Reminder as 15 min before start for onsite appointments
          ElseIf InStr(strCategories, "Onsite") > 0 Then
             With objMeeting
                 .ReminderSet = True
                 .ReminderMinutesBeforeStart = 15
                 .Save
             End With
          End If
       End If
    End If
End Sub

4. Successivamente, è necessario fare clic sulla subroutine "Application_Startup" e premere il tasto "F5" per eseguire questa macro.
5. Da allora, ogni volta che una nuova riunione viene aggiunta al calendario predefinito o si modifica una riunione esistente, Outlook controllerà automaticamente le categorie della riunione e imposterà automaticamente il diverso orario del promemoria.

Elimina gli errori di Outlook

Di tanto in tanto possono verificarsi diversi problemi con Outlook. Pertanto, è estremamente importante che gli utenti imparino come affrontare i problemi di Outlook. Per cominciare, è meglio eseguire regolarmente backup dei dati di Outlook. Inoltre, se possibile, si consiglia di mantenere un backup efficace. Riparazione di Outlook strumento nelle vicinanze, ad esempio DataNumen Outlook Repair. Può scansionare il tuo file PST per capire i problemi di Outlook e quindi risolverli con facilità.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui ripristino sql e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com