Come applicare automaticamente le categorie di un'e-mail a tutte le sue risposte e inoltri in Outlook

Quando rispondi o inoltri un'e-mail, potresti voler applicare le stesse categorie. In questo articolo ti insegneremo a realizzarlo con il codice VBA.

Se sei abituato ad assegnare le stesse categorie di colore dell'e-mail originale a tutte le sue risposte e inoltri, perché non lasci che Outlook lo faccia automaticamente? Anche se Outlook non fornisce una funzionalità così diretta, puoi comunque ottenerla con l'aiuto del codice VBA. Di seguito, ti esporremo i passaggi dettagliati e il codice.

Applica automaticamente le categorie di un'e-mail a tutte le sue risposte e inoltri

1. All'inizio, avvia l'applicazione Outlook.
2. Quindi, premi i tasti "Alt + F11" per eseguire l'editor VBA di Outlook.
3. Quindi, copia il seguente codice VBA nel progetto "ThisOutlookSession".

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem
Private strCategories As String

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If objExplorer.Selection.Item(1).Class = olMail Then
       Set objMail = objExplorer.Selection.Item(1)
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If Inspector.CurrentItem.Class = olMail Then
       Set objMail = Inspector.CurrentItem
       strCategories = objMail.Categories
    End If
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call CopyCategories(Forward)
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call CopyCategories(Response)
End Sub

Private Sub CopyCategories(ByVal objNewMail As Object)
    objNewMail.Categories = strCategories
End Sub

4. Dopodiché, riavvia Outlook per attivare il progetto.
5. Da allora, puoi provarlo seguendo i passaggi seguenti.

• Prima di tutto, seleziona un'e-mail e premi il pulsante "Inoltra".
• Quindi, verrà visualizzata un'e-mail di inoltro, in cui è possibile passare alla scheda "Opzioni" e premere l'icona dell'estensione nell'angolo in basso a destra del gruppo "Altre opzioni".
• Successivamente, nella finestra di dialogo popup "Proprietà", puoi vedere che questa e-mail è assegnata con le stesse categorie di colori dell'e-mail originale.

Correggi il file di Outlook danneggiato

Dato che Outlook è vulnerabile, devi intraprendere molte azioni per evitare la perdita di dati di Outlook. Ad esempio, è necessario eseguire backup periodici dei dati. Inoltre, è necessario fare attenzione alle e-mail sconosciute, inclusi i collegamenti o gli allegati incorporati. Ultimo ma non meno importante, dovresti procurarti uno strumento di correzione esterno di punta, come DataNumen Outlook Repair. È in grado di aiutarti a recuperare il massimo dei dati da Outlook corrotto file.

Introduzione dell'autore:

Shirley Zhang è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui SQL Server fisso e prodotti software di riparazione di Outlook. Per maggiori informazioni visita www.datanumen.com