3 modi veloci per eliminare righe e colonne vuote nella tua tabella di parole

In questo post, ti spiegheremo 3 modi veloci per eliminare righe e colonne vuote nella tua tabella di Word.

Le tabelle sono essenziali per un documento, soprattutto per contenere vari tipi di dati. A volte, una lunga tabella può superare una pagina e estendersi su più pagine. Quindi, una volta che una tabella diventa lunga e complicata, ci sono misure che puoi adottare per semplificarla. Ad esempio, puoi eliminare righe e colonne vuote non necessarie.

Di seguito sono riportati 3 metodi che è possibile utilizzare.

Metodo 1: Elimina righe e colonne vuote manualmente

1. Innanzitutto, seleziona una riga o una colonna in bianco.
2. Quindi fare clic con il tasto destro per ottenere il menu contestuale. Nel menu, seleziona "Elimina righe" o "Elimina colonne" di conseguenza.

Sfortunatamente, non puoi selezionare più righe o colonne non consecutive ed eliminarle insieme in questo modo. Per questa richiesta, puoi fare riferimento al nostro precedente articolo: 5 metodi rapidi per eliminare in batch più righe o colonne nella tua tabella di parole

Metodo 2: Elimina in batch tutte le righe e le colonne vuote in una tabella

Il metodo 1 ha i suoi limiti. Quindi ti offriremo il modo per rimuovere in batch righe e colonne in una tabella tramite codici VBA.

1. Per cominciare, posiziona il cursore all'interno di a tarprendi il tavolo.
2. In secondo luogo, attiva l'editor VBA premendo "Alt + F11".
3. Nell'editor, fai prima clic sul progetto "Normale".
4. Quindi fare clic sulla scheda "Inserisci" sulla barra dei menu.
5. Nel menu a discesa, scegli "Modulo".
6. Fare doppio clic sul modulo per aprirlo e incollare i seguenti codici lì:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Infine, fai clic sul pulsante "Esegui" sulla barra dei menu o premi "F5".

In pochi secondi, rimuoverai tutte le righe e le colonne vuote in quella tabella.

Metodo 3: Elimina in batch tutte le righe e le colonne vuote in tutte le tabelle di un documento

1. Prima di tutto, ripeti i passaggi del metodo 2 per installare ed eseguire una macro.
2. Solo che questa volta, sostituisci quella macro con la seguente:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Recupera documento danneggiato

C'è più di un modo per recuperare lost dati al giorno d'oggi. Ad esempio, il ricorso ai backup rimane sempre la tua massima priorità. Se ciò non soddisfa la tua necessità di recuperare le informazioni più recenti, puoi provare a riparazione del documento strumento.

Introduzione dell'autore:

Vera Chen è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui riparazione xlsx e pdf riparare prodotti software. Per maggiori informazioni visita www.datanumen.com