2 modi per unire rapidamente più documenti Word in uno tramite VBA

In questo articolo, siamo lieti di condividere con te 2 modi per unire rapidamente più documenti Word in uno tramite VBA.

In Word, c'è la funzione integrata predefinita per aiutare l'utente a combinare o unire più documenti in uno solo. I dettagli sono spiegati in questo articolo: Come combinare e unire più documenti di Word in uno

Con quel metodo, devi fare un paio di clic e il contenuto del documento successivo arriva sempre subito dopo quello del precedente. Pertanto, vogliamo offrirti modi più rapidi per farlo.

Metodo 1: unisci i documenti selezionati in uno

1. Innanzitutto, crea un nuovo documento vuoto.
2. Attiva l'editor VBA in Word premendo "Alt + F11".
3. Quindi fai clic su "Normale".
4. Quindi fare clic su "Inserisci".
5. E scegli "Modulo".
6. Fare doppio clic sul nuovo modulo per aprire lo spazio di modifica.
7. Incolla lì la seguente macro:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Quindi fai clic su "Esegui" o premi "F5".
9. Ora nella finestra "Sfoglia", seleziona più file premendo "Ctrl" e fai clic su "OK".
10. Successivamente, tutti i contenuti dei file selezionati verranno assemblati nel nuovo documento, con il testo di ciascun documento che inizierà su una nuova pagina.

Attenzione:

Come accennato, questa macro inserisce i testi di ciascun documento in una nuova pagina. Ma se hai bisogno che siano uno dopo l'altro, puoi modificare alcune righe di codice nella macro. Basta trovare la riga "If nEachSelectedFile <nTotalFiles Then", eliminarla e anche le sei righe successive.

Metodo 2: unisci tutti i documenti in una cartella in uno

Nel caso in cui tu abbia una cartella di file da unire, allora questa macro funzionerà magnificamente.

1. Per iniziare, installa ed esegui la macro come descritto nel metodo 1.
2. Quindi sostituisci macro con questo:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Eseguire la macro facendo clic su "Esegui".
4. Successivamente viene visualizzata la finestra "Sfoglia" aperta. Seleziona la cartella in cui archiviare tutti i documenti. E fai clic su "OK".

Analogamente, il testo di ciascun documento inizia su una nuova pagina. Per far sì che i testi si susseguano uno dopo l'altro, individua ed elimina la riga di codice ".InsertBreak Type:=wdPageBreak".

Proteggi correttamente il tuo documento Word

Uno dei modi migliori per proteggere i documenti di Word è eseguirne regolarmente il backup. Con i backup in mano, non dovrai mai temere la perdita di dati. Inoltre, è anche consigliabile procurarsi uno strumento riparare docx se qualcuno di loro sarà danneggiato.

Introduzione dell'autore:

Vera Chen è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui Excel danneggiato and pdf riparare prodotti software. Per maggiori informazioni visita www.datanumen.com