2 modi rapidi per estrarre singole pagine dal documento di Word

Nel post di oggi, vogliamo condividere con voi 2 metodi rapidi per estrarre singole pagine da un documento Word.

A volte in un documento Word, ogni pagina può contenere contenuti abbastanza indipendenti, come una tabella. E probabilmente dovrai inviare tabelle diverse a persone diverse. Quindi dovrai salvare ogni tabella che è ogni pagina, come un file separato.

La prima idea che ci viene in mente dovrebbe essere il classico copia e incolla. Tuttavia, qualsiasi cosa implichi la selezione a volte può essere fastidiosa, poiché trascinare e selezionare può facilmente far finire senza alcuna selezione. Per questo motivo, ti consigliamo 2 metodi rapidi utilizzando la macro per eseguire il lavoro.

Metodo 1: estrarre la pagina corrente e salvarla come nuovo documento

1. Innanzitutto, posiziona il cursore sulla pagina che desideri estrarre.
2. Fare clic sulla scheda "Sviluppatore" e quindi su "Visual Basic" per richiamare l'editor VBA. Se lo "Sviluppatore" non è attivato, premi semplicemente "Alt + F11".
3. In secondo luogo, vai al progetto "Normale" facendo clic su di esso.
4. Quindi fai clic sulla scheda "Inserisci" e scegli "Modulo".
5. Fare doppio clic sul nuovo modulo per aprire l'area di modifica.
6. Quindi incolla i seguenti codici lì:

Sub SaveCurrentPageAsANewDoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim strFileName As String
  Dim strFolder As String
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
  strFileName = InputBox("Enter file name here: ")
 
  '  Copy current page.
  objDoc.Bookmarks("\Page").Range.Select
  Selection.Copy
 
  '  Open a new document to paste the selection.
  Set objNewDoc = Documents.Add
  Selection.Paste
 
  objNewDoc.SaveAs FileName:=strFolder & "\" & strFileName & ".docx"
  objNewDoc.Close
End Sub

7. Infine, fai clic sul pulsante "Esegui".

Ora ci saranno 2 caselle di input. Immettere il percorso in cui si desidera archiviare il nuovo documento nella prima casella di input. E inserisci il nuovo nome del documento sul secondo.

Metodo 2: estrarre ogni pagina e salvarla come nuovo documento

La seguente macro ti consentirà di estrarre ogni singola pagina di un documento.

1. Innanzitutto, premi "Ctrl + Home" per andare all'inizio del documento.
2. Quindi seguire gli stessi passaggi nel metodo 1 per installare ed eseguire una macro.
3. Questa volta sostituisci la macro con questa:

Sub SaveEachPageAsADoc()
  Dim objNewDoc As Document
  Dim objDoc As Document
  Dim nPageNumber As Integer
  Dim strFolder As String
  Dim objFileName As Range
 
  '  Initialization
  Set objDoc = ActiveDocument
 
  strFolder = InputBox("Enter folder path here: ")
 
  '  Copy each page in the document to paste it into a new one.
  For nPageNumber = 1 To ActiveDocument.ComputeStatistics(wdStatisticPages)
    Application.Browser.Target = wdBrowsePage
    ActiveDocument.Bookmarks("\page").Range.Select
    Selection.Copy
 
    Set objNewDoc = Documents.Add
    Selection.Paste
 
    '  Save new doc with the name of "Page" & nPageNumber and get the first 20 characters of the new doc as part of the file name.
    Set objFileName = objNewDoc.Range(Start:=0, End:=20)
    objNewDoc.SaveAs FileName:=strFolder & "\" & "Page " & nPageNumber & " " & objFileName & ".docx"
    objNewDoc.Close
    Application.Browser.Next
  Next nPageNumber
End Sub

Affrontare i problemi di Word

Esistono e sempre esisteranno diversi problemi con Word. Il punto è imparare a risolverli correttamente. Il modo più consigliato è, ovviamente, procurarsi un sofisticato Recupero di parole attrezzo. Dovresti cogliere ogni minuto per recuperare i tuoi dati prima che sia troppo tardi.

Introduzione dell'autore:

Vera Chen è un'esperta di recupero dati in DataNumen, Inc., che è il leader mondiale nelle tecnologie di recupero dati, tra cui xlsx corrotto and pdf riparare prodotti software. Per maggiori informazioni visita www.datanumen.com