Ինչպես արագորեն պարզել Outlook- ում հատուկ նշանակման հետ հակասող մյուս բոլոր նշանակումները

Երբ դուք ստեղծում կամ փոխում եք հանդիպում Outlook-ի օրացույցում, Outlook-ը ավտոմատ կերպով կստուգի, թե արդյոք կան հակասող հանդիպումներ։ Այս պահին, եթե ցանկանում եք ստուգել հակասությունները, կարող եք օգտագործել այս գրառման մեջ ներկայացված մեթոդը։

Հավանաբար, երբևէ տեսել եք «Հակամարտություններ այլ նշանակման հետ» տեքստը Outlook- ի նշանակումը ստեղծելիս կամ փոխելիս: Դա պայմանավորված է նրանով, որ Outlook- ը կարող է ինքնաբերաբար ստուգել հակամարտությունները: Այնուամենայնիվ, Outlook- ը չի կարող օգնել ձեզ արագ գտնել հակամարտությունները ՝ իր նախնական հատկանիշներով: Այսպիսով, այստեղ մենք ձեզ կասենք մի մեթոդ ՝ բոլոր հակասական նշանակումները որոնելու գործառույթ գեներացնելու համար:

Պարզեք բոլոր այլ նշանակումները, որոնք հակասում են հատուկ նշանակմանը

1. Հենց սկզբից գործարկեք ձեր Outlook ծրագիրը:
2. Այնուհետև, Outlook- ի հիմնական պատուհանում կտտացրեք «Alt + F11» ստեղների կոճակները:
3. Միանգամից մուտք կգործեք Outlook VBA խմբագիր, որում պետք է բացեք չօգտագործված մոդուլ:
4. Հաջորդը, պատճենեք հետևյալ VBA կոդը այս մոդուլում:

Sub FindOutConflictingAppointments()
    Dim objAppointment As AppointmentItem
    Dim dStartTime, dEndTime As Date
    Dim strFilter As String
    Dim objAppointments As Items
    Dim objFoundAppointments As Items
    Dim objItem As AppointmentItem
    Dim i As Long
    Dim strConflicts As String
    Dim strMsg As String
 
    Select Case Application.ActiveWindow.Class
           Case olExplorer
                Set objAppointment = Application.ActiveExplorer.Selection(1)
           Case olInspector
                Set objAppointment = Application.ActiveInspector.CurrentItem
    End Select
 
    dStartTime = objAppointment.start
    dEndTime = objAppointment.End
 
    Set objAppointments = Application.ActiveExplorer.CurrentFolder.Items
 
    i = 1
 
    '1: Find all appts whose end time within the start and end time of source appt
    strFilter = "[End] >= " & Chr(34) & Format(dStartTime, "mm/dd/yyyy hh:mm AMPM") & Chr(34) & " AND [End] <= " & Chr(34) & Format(dEndTime, "mm/dd/yyyy hh:mm AMPM") & Chr(34)
 
    Set objFoundAppointments = objAppointments.Restrict(strFilter)
 
    For Each objItem In objFoundAppointments
        If objItem.Subject <> objAppointment.Subject Then
           strConflicts = strConflicts & i & ". " & objItem.Subject & vbCrLf
           i = i + 1
        End If
    Next
 
    '2: Find all appts occurring within the start and end time of source appt
    strFilter = "[Start] >= " & Chr(34) & Format(dStartTime, "mm/dd/yyyy hh:mm AMPM") & Chr(34) & " AND [End] <= " & Chr(34) & Format(dEndTime, "mm/dd/yyyy hh:mm AMPM") & Chr(34)
 
    Set objFoundAppointments = objAppointments.Restrict(strFilter)
 
    For Each objItem In objFoundAppointments
        If objItem.Subject <> objAppointment.Subject Then
           strConflicts = strConflicts & i & ". " & objItem.Subject & vbCrLf
           i = i + 1
        End If
    Next
 
    '3: Find all appts whose start time within the start and end time of source appt
    strFilter = "[Start] >= " & Chr(34) & Format(dStartTime, "mm/dd/yyyy hh:mm AMPM") & Chr(34) & " AND [Start] <= " & Chr(34) & Format(dEndTime, "mm/dd/yyyy hh:mm AMPM") & Chr(34)
 
    Set objFoundAppointments = objAppointments.Restrict(strFilter)
 
    For Each objItem In objFoundAppointments
        If objItem.Subject <> objAppointment.Subject Then
           strConflicts = strConflicts & i & ". " & objItem.Subject & vbCrLf
           i = i + 1
        End If
    Next
 
    '4: Find all appts cover the entire source appt
    strFilter = "[Start] <= " & Chr(34) & Format(dStartTime, "mm/dd/yyyy hh:mm AMPM") & Chr(34) & " AND [End] >= " & Chr(34) & Format(dEndTime, "mm/dd/yyyy hh:mm AMPM") & Chr(34)
 
    Set objFoundAppointments = objAppointments.Restrict(strFilter)
  
    For Each objItem In objFoundAppointments
        If objItem.Subject <> objAppointment.Subject Then
           strConflicts = strConflicts & i & ". " & objItem.Subject & vbCrLf
           i = i + 1
        End If
    Next
 
    strMsg = i - 1 & " Conflicting Appointments:" & vbCrLf & vbCrLf & strConflicts
    MsgBox strMsg, vbInformation + vbOKOnly, "Check Conflicts"
End Sub

5. Դրանից հետո դուք կարող եք դուրս գալ ընթացիկ պատուհանից:
6. Այնուհետև ավելացրեք այս մակրոտն ինչպես արագ մուտք գործելու գործիքագոտին:
7. Հետագայում պետք է նաև ապահովագրեք, որ մակրոները միացված են ձեր Outlook- ում: Պարզապես գնացեք «Մակրո կարգավորումներ» ՝ այն ստուգելու համար:
8. Վերջապես կարող եք փորձել:

• Նախ, ընտրեք կամ բացեք հանդիպում, որում կա «Հակամարտություններ այլ նշանակման հետ» հուշում:
• Դրանից հետո կտտացրեք մակրո կոճակին Արագ մուտքի գործիքագոտում:
• Միանգամից դուք կստանաք հաղորդագրություն, որը պարունակում է բոլոր հակասական նշանակումները, որը ցուցադրվում է որպես հետևյալ սքրինշոթ:

Անհրաժեշտ նախազգուշական միջոցներ նախքան Outlook կոռուպցիան

Հայտնի է, որ Outlook-ը հակված է խափանումների և սխալների։ Հետևաբար, անհրաժեշտ է լավ պատրաստ լինել Outlook-ի վնասմանը։ Ամենակարևոր նախազգուշական միջոցներից մեկը պարբերաբար պահուստավորումն է։ Բացի այդ, խորհուրդ է տրվում պատրաստել հզոր մասնագիտացված... Outlook- ի նորոգում գործիք, ինչպես DataNumen Outlook Repair.

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում mdf վերականգնում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com