Ինչպե՞ս ինքնաբերաբար ներմուծել պատկերները ներգնա հատուկ նամակներից Outlook VBA- ի միջոցով

Outlook լուծումներ Սեպտեմբեր 29, 2025
Կիսվել հիմա ՝

Եթե ​​ցանկանում եք, որ Outlook-ը ավտոմատ կերպով հանի և պահպանի ներկառուցված պատկերները կոնկրետ մուտքային նամակներից, կարող եք դիմել այս հոդվածին: Այստեղ մենք ձեզ կսովորեցնենք, թե ինչպես դա իրականացնել VBA կոդով։

Որոշ օգտատերեր հաճախ պետք է հանեն ներկառուցված պատկերները կոնկրետ մուտքային նամակներից և պահեն դրանք Windows-ի որոշակի պանակում: Այնքան դժվար է ամեն անգամ դա անել ձեռքով: Հետևաբար, շատերն անհամբեր սպասում են արագ և հարմար մոտեցում սովորելուն, որպեսզի Outlook-ին ավտոմատ կերպով դա կատարի: Այժմ, այստեղ մենք ձեզ հետ կկիսվենք նման մեթոդով։

Ներկառուցված պատկերների ավտոմատ արդյունահանում հատուկ մուտքային նամակներից

  1. Նախ, գործարկեք ձեր Outlook ծրագիրը, ինչպես միշտ:
  2. Այնուհետև գործարկեք Outlook VBA խմբագրիչը, ինչպես միշտ, հղումով t «Ինչպես գործարկել VBA կոդը ձեր Outlook- ում".
  3. Ավելի ուշ պատճենեք և տեղադրեք հետևյալ VBA կոդը «ThisOutlookSession» նախագծում:
Public WithEvents objInbox As Outlook.Folder
Public WithEvents objInboxItems As Outlook.Items

Private Sub Application_Startup()
    Set objInbox = Outlook.Application.Session.GetDefaultFolder(olFolderInbox)
    Set objInboxItems = objInbox.Items
End Sub

Private Sub objInboxItems_ItemAdd(ByVal Item As Object)
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.Attachments
    Dim objAttachment As Outlook.Attachment
    Dim strWindowsFolder As String
    Dim i As Long
 
    If TypeOf Item Is MailItem Then
       Set objMail = Item
 
       'Specify the emails as per your needs
       If objMail.Importance = olImportanceHigh Then
          Set objAttachments = objMail.Attachments
 
          'Specify the windows folder
          strWindowsFolder = "E:\" & objMail.Subject & Format(Now, "yymmddhhmmss")
          MkDir (strWindowsFolder)
 
          'Save all embedded images to the folder
          For i = 1 To objAttachments.Count
              Set objAttachment = objAttachments.Item(i)
              If IsEmbedded(objAttachment) = True Then
                 objAttachment.SaveAsFile strWindowsFolder & "\" & objAttachment.FileName
              End If
          Next
      End If
    End If
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

VBA Code – Ավտոմատ հանել ներկառուցված պատկերները հատուկ մուտքային նամակներից

  1. Դրանից հետո սեղմեք «Application_Startup» ենթածրագիրը։
  2. Վերջապես, սեղմեք «F5» ստեղնը՝ այս մակրո գործարկելու համար:
  3. Այսուհետ, ամեն անգամ, երբ մուտքի արկղ է գալիս կոնկրետ նոր էլ.Արդյունահանված պատկերներ Windows թղթապանակում

Պարբերաբար մաքրեք խոշոր կցորդները

Խորհուրդ է տրվում պարբերաբար մաքրել մեծ կցորդները ձեր Outlook-ից։ Դա նպատակ ունի պահպանել ձեր Outlook ֆայլը համապատասխան չափի մեջ։ Ավելի մեծ Outlook ֆայլն ավելի ենթակա է վնասման։ Ինչպես գիտեք, PST վնասը բավականին դժվար է լավ բուժել։ Հնարավոր է՝ սկզբում փորձեք այն շտկել էլ. փոստի վերականգնման գործիքի միջոցով։ Սակայն, շատ դեպքերում դա չի աշխատի։ Ձեր միակ միջոցը մասնագիտացված... PST- ի նորոգում գործիք, ինչպես DataNumen Outlook Repair, կամ համապատասխան մասնագիտական ​​վերականգնման ծառայություններ:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում mdf շտկել և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com

Կիսվել հիմա ՝

Comments փակվում են: