Outlook-ում պատասխանելիս էլփոստի բնօրինակ կցորդները պահելու 6 եղանակ

Outlook լուծումներ Սեպտեմբեր 29, 2025

Շատ օգտատերեր հույս ունեն կարգավորել իրենց Outlook-ը, որպեսզի էլփոստի բնօրինակ կցորդները պահեն նամակին պատասխանելիս: Այս հոդվածը կբացահայտի 5 լուծումներ, ինչպես նաև խելացի միջոց, որն օգտագործում է VBA-ն՝ այն ինքնաբերաբար իրականացնելու համար:

Ես լսել եմ բազմաթիվ օգտատերերի, ովքեր բողոքում են, որ Outlook-ը չունի բնօրինակ հատկություն՝ նամակներին պատասխանելիս բնօրինակ կցորդները պահելու համար: Հետևաբար, այստեղ մենք ձեզ կկիսվենք 6 եղանակով, որոնցից մեկը բավականին օգտակար է, քանի որ այն օգտագործում է VBA-ն, որպեսզի Outlook-ը ավտոմատ կերպով կցի բնօրինակ հավելվածները պատասխանող էլ. Այժմ կարդացեք դրանք մանրամասնորեն ստանալու համար:

1. Պատասխանել կցված բնօրինակ էլ

Թեև Outlook-ը չի տրամադրում էլփոստի բնօրինակ կցորդները նամակին պատասխանելիս պահելու հատկություն, այն թույլ է տալիս օգտվողներին կցված պահել էլփոստի բնօրինակը: Հետևաբար, դա կամընտիր լուծում է ձեզ համար: Պատասխանների կարգավորումները փոխելու համար կարող եք գնալ «Ֆայլ» > «Ընտրանքներ» > «Փոստ» > «Պատասխաններ և փոխանցումներ» բաժինը: Մանրամասների համար խորհուրդ եմ տալիս անդրադառնալ իմ նախորդ հոդվածին – «Outlook- ի բնօրինակ հավելվածներով պատասխանելու 5 քայլ»: Բայց, եթե դուք դեռ հույս ունեք պահպանել միայն բնօրինակ հավելվածները, անցեք մյուս միջոցները սովորելուն:

2. Ձեռքով քաշեք և բաց թողեք հավելվածները

Սկսելու համար կրկնակի սեղմեք այդպիսի աղբյուրի էլ.փոստի վրա՝ այն առանձին պատուհանում բացելու համար։
Այնուհետև սեղմեք «Պատասխանել» կոճակը, որը կհայտնվի պատասխանող նամակը:
Այնուհետև դուք պետք է փոքրացնեք երկու հաղորդագրությունների պատուհանները, մինչև դրանք տեսնեք նույն էկրանին:
Դրանից հետո ընտրեք բոլոր հավելվածները բնօրինակ նամակում:
Վերջապես, քաշեք և թողեք դրանք պատասխանող էլ.փոստի «Կցված» տողում:

3. Ձեռքով պատճենեք և տեղադրեք հավելվածները

Սկզբում սկզբնաղբյուր նամակը բացելուց հետո ընտրեք բոլոր հավելվածները։
Այնուհետև կտտացրեք «Պատճենել» կոճակը «Կցորդներ» ներդիրում:
Այնուհետև սեղմեք «Պատասխանել» կոճակը «Հաղորդագրություն» ներդիրի տակ՝ պատասխան նամակ բացելու համար:
Ի վերջո, պատասխան նամակում կտտացրեք «Կցված» տողին և սեղմեք «Ctrl + V» կոճակը՝ նախկինում պատճենված հավելվածները տեղադրելու համար:

4. Փոխանցել էլփոստը և լրացնել Ստացողը

Սկզբում ընտրեք այդպիսի նամակ և սեղմեք ժապավենի «Առաջ» կոճակը:
Հաղորդագրության նոր բացվող պատուհանում պահվում են բնօրինակ հավելվածները: Այժմ դուք պետք է լրացնեք «Դեպի» դաշտը բնօրինակ նամակ ուղարկողին:
Ընտրովի, դուք կարող եք փոխել թեման ըստ ձեր կարիքների:

5. Կրկին ուղարկեք այս էլփոստը և փոխեք ստացողներին

Սկսելու համար բացեք սկզբնաղբյուր էլ.
Այնուհետև սեղմեք «Գործողություններ» կոճակը «Տեղափոխել» խմբում:
Հաջորդը բացվող ցանկից ընտրեք «Կրկին ուղարկել այս հաղորդագրությունը»:
Միգուցե դուք ծանուցում ստանաք, նշելով, որ դուք բնօրինակ ուղարկողը չեք: Պարզապես անտեսեք այն և սեղմեք «Այո»:
Հետագա նոր նամակում դուք պետք է փոփոխեք «Դեպի» դաշտը սկզբնական էլփոստի ուղարկողին:
Նաև հիշեք, որ էլփոստի հաշվի միջոցով ուղարկումը փոխեք ձեր սեփական հաշվին:

6. Ավտոմատ ավելացնել բնօրինակ հավելվածներ VBA-ի միջոցով

Վերը նշված բոլոր մոտեցումները, ճիշտն ասած, լուծումներ են: Եթե հուսով եք, որ Outlook-ը կարող է ինքնաբերաբար պահել բնօրինակ հավելվածները պատասխանելիս, կարող եք օգտագործել այս եղանակը:

Outlook-ի հիմնական պատուհանում սեղմեք «Alt + F11» ստեղները:
Դրանից հետո, «Microsoft Visual Basic for Applications» պատուհանում, պատճենեք ներքևի VBA կոդը «ThisOutlookSession» նախագծում:

Private WithEvents objExplorer As Outlook.Explorer
Private WithEvents objInspectors As Outlook.Inspectors
Private WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objExplorer = Outlook.Application.ActiveExplorer
    Set objInspectors = Outlook.Application.Inspectors
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeName(objExplorer.Selection.Item(1)) = "MailItem" Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeName(Inspector.CurrentItem) = "MailItem" Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when clicking "Reply" button
Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

'Occurs when clicking "Reply All" button
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call KeepOriginalAttachments(objMail, Response)
End Sub

Private Sub KeepOriginalAttachments(ByVal objOriginalMail As MailItem, objReply As Object)
    Dim strEnviro As String
    Dim strTempFolder As String
    Dim strFilePath As String
    Dim objAttachment As Outlook.Attachment
 
    'Get the temp folder in Windows
    strEnviro = CStr(Environ("USERPROFILE"))
    strTempFolder = strEnviro & "\AppData\Local\Temp"
 
    For Each objAttachment In objOriginalMail.Attachments
        'Skip the embedded image attachments
        If IsEmbeddedAttachment(objAttachment) = False Then
           strFilePath = strTempFolder & "\" & objAttachment.filename
           objAttachment.SaveAsFile strFilePath
 
           'Attach the temporarily saved attachments to the Reply
           objReply.Attachments.Add strFilePath
 
           'Delete the temporarily saved attachments
           Kill strFilePath
       End If
    Next
End Sub

'Function for checking if an attachment is embedded image attachment
Function IsEmbeddedAttachment(objCurrentAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.propertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurrentAttachment.propertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbeddedAttachment = True
    Else
       IsEmbeddedAttachment = False
    End If
End Function

Ավելի ուշ ստորագրեք այս մակրո և փոխեք ձեր Outlook մակրո կարգավորումները՝ ստորագրված մակրոները թույլ տալու համար:
Դրանից հետո վերագործարկեք ձեր Outlook ծրագիրը՝ այս VBA նախագիծը ակտիվացնելու համար։
Այսուհետ ամեն անգամ, երբ սեղմում եք «Պատասխանել» կոճակը: Պատասխանող նամակը միանգամից կցուցադրվի բնօրինակ հավելվածներով:

Դիմեք նշանավոր վերանորոգման գործիքին

Outlook-ը զիջել է էլփոստի այլ հաճախորդներին իր բազմաթիվ առանձնահատկությունների շնորհիվ: Բայց այն դեռ հակված է կոռուպցիայի։ Այսպիսով, դուք պետք է ավելի շատ ուշադրություն դարձնեք նրա առողջությանը: Ընդհանուր առմամբ, երբ բախվում եք փոքր խնդիրների, դուք պարզապես կարող եք կրկին դիմել ներկառուցված շտկման ծրագրին: Այնուամենայնիվ, եթե լուրջ անախորժություններ եք ունենում, ավելի լավ է նորից դիմեք շատ ավելի հմուտ գործիքի, ինչպիսին է DataNumen Outlook Repair. Դա կարող է շտկել Outlook- ը ֆայլը մի ակնթարթում:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql ֆիքս և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com