Ինչպես արտահանել ձեր Outlook ֆայլի թղթապանակի կառուցվածքը Excel- ին

Outlook լուծումներ Սեպտեմբեր 29, 2025
Կիսվել հիմա ՝

Եթե ​​ցանկանում եք արագ արտահանել ձեր Outlook տվյալների ֆայլի թղթապանակի կառուցվածքը Excel- ի աշխատանքային գրքույկ, կարող եք օգտագործել այս հոդվածում ներկայացված մեթոդը:

Որոշ պատճառներով, ինչպիսիք են ՝ ներկայիս Outlook պանակների և ենթապանակների գրանցումը, շատ օգտվողներ հույս ունեն արտահանել Outlook ֆայլի պանակի կառուցվածքը արտաքին ֆայլ, օրինակ ՝ Excel աշխատանքային գրքույկ: Հետևյալ բաժնում մենք ձեզ կկիսվենք VBA կոդի մի կտոր, որը կարող է օգնել ձեզ արագ հասնել դրան:

Արտահանեք ձեր Outlook ֆայլի թղթապանակի կառուցվածքը Excel- ին

Արտահանեք ձեր Outlook ֆայլի թղթապանակի կառուցվածքը Excel- ին

  1. Սկսելու համար գործարկեք ձեր Outlook ծրագիրը։
  2. Դրանից հետո Outlook- ի հիմնական պատուհանում սեղմեք «Alt + F11» ստեղնաշարի կոճակները:
  3. Հաջորդը, դուք կմտնեք Outlook VBA խմբագրի մեջ, որում պետք է բացեք չօգտագործված մոդուլ:
  4. Հետագայում այս մոդուլում կարող եք պատճենել հետևյալ VBA կոդը:
Dim objExcelApp As Excel.Application
Dim objExcelWorkbook As Excel.Workbook
Dim objExcelWorksheet As Excel.Worksheet
Dim lMainFolder As Long

Sub ExportFolderStructureToExcel()
    Dim objSourcePSTFile As Folder
 
    'Add a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    With objExcelWorksheet
         .Cells(1, 1) = "Folder Structure"
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 1).Font.Bold = True
    End With
 
    'Select an Outlook PST file
    Set objSourcePSTFile = Application.Session.PickFolder
 
    lMainFolder = Len(objSourcePSTFile.FolderPath) - Len(Replace(objSourcePSTFile.FolderPath, "\", "")) + 1
 
    Call ExportToExcel(objSourcePSTFile.FolderPath, objSourcePSTFile.Name)
    Call ProcessFolders(objSourcePSTFile.Folders)
 
    'Save this Excel workbook
    objExcelWorksheet.Columns("A").AutoFit
    strExcelFile = "E:\Folder Structure (" & Format(Now, "yyyymmddhhmmss") & ").xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

Sub ProcessFolders(ByVal objFolders As Folders)
    Dim objFolder As Folder
 
    'Process all folders recursively
    For Each objFolder In objFolders
        If objFolder.Name <> "Conversation Action Settings" And objFolder.Name <> "Quick Step Settings" Then
           Call ExportToExcel(objFolder.FolderPath, objFolder.Name)
           Call ProcessFolders(objFolder.Folders)
        End If
    Next
End Sub

Sub ExportToExcel(ByRef strFolderPath As String, strFolderName As String)
    Dim i, n As Long
    Dim strPrefix As String
    Dim nLastRow As Integer
 
    i = Len(strFolderPath) - Len(Replace(strFolderPath, "\", ""))
    For n = lMainFolder To i
        strPrefix = strPrefix & "-"
    Next
    strFolderName = strPrefix & strFolderName
 
    'Input the folder name in Excel
    nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
    objExcelWorksheet.Range("A" & nLastRow) = strFolderName
End Sub

VBA կոդ - Արտահանեք ձեր Outlook ֆայլի թղթապանակի կառուցվածքը Excel- ին

  1. Դրանից հետո դուք պետք է համոզվեք, որ Outlook- ը միացրել է մակրոները:
  2. Ի վերջո, կարող եք նկարահանել.
  • Ընթացիկ մակրո պատուհանում սեղմեք F5 ստեղնի կոճակը:
  • Մակրոի ավարտից հետո դուք կստանաք ահազանգի հուշում ՝ «Ավարտված»:
  • Ավելի ուշ, դուք կարող եք անցնել նախապես որոշված ​​տեղական թղթապանակ ՝ գտնելու նոր Excel ֆայլ: Բացեք այն և այն կանդրադառնա հետեւյալ սքրինշոթի վրա.Excel- ում ձեր Outlook ֆայլի թղթապանակի կառուցվածքը

Երբեք մի արհամարհեք Outlook- ի ցանկացած սխալ

Չնայած քանակական հնարավորություններին ՝ Outlook- ը նույնն է ենթակա սխալների և կոռուպցիայի, ինչ էլփոստի այլ հաճախորդները: Հետեւաբար, դուք պետք է կարևորեք ձեր Outlook- ի բոլոր սխալները: Մի արհամարհեք նրանց, խնդրում եմ: Հակառակ դեպքում, սխալների կուտակումը վերջապես կարող է հանգեցնել Outlook- ի կոռուպցիայի: Եթե ​​բախվում եք հանգույցի սխալների հետ, առաջարկվում է օգտագործել այնպիսի հզոր գործիք, ինչպիսին է DataNumen Outlook Repair, որը կարող է վերանորոգել Outlook- ը վայրկյանների ընթացքում սխալներ:

Հեղինակի ներածություն.

Shirley Zhang- ը տվյալների վերականգման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում sql վերականգնում և հեռանկարների նորոգման ծրագրակազմի արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com

Կիսվել հիմա ՝

Comments փակվում են: