Ձեր բառի աղյուսակում դատարկ տողերն ու սյունները ջնջելու 3 արագ եղանակներ

Այս գրառման մեջ մենք ձեզ կբացատրենք Word աղյուսակում դատարկ տողերն ու սյուները ջնջելու 3 արագ եղանակ։

Աղյուսակները կարևոր են փաստաթղթի համար, հատկապես տարբեր տեսակի տվյալների պահման համար: Երբեմն, երկար աղյուսակը կարող է գերազանցել էջը և տարածվել մի քանիսի վրա: Այսպիսով, երբ սեղանը երկարանա և բարդանա, կան միջոցներ, որոնք կարող եք անել այն պարզեցնելու համար: Օրինակ, կարող եք ջնջել ավելորդ դատարկ շարքերն ու սյունակները:

Ստորև ներկայացված են 3 մեթոդներ, որոնք կարող եք օգտագործել:

Մեթոդ 1. Ձեռքով ջնջեք դատարկ շարքերը և սյունակները

1. Նախ ընտրեք տող կամ սյուն դատարկ:
2. Ապա աջ կտտացրեք ՝ համատեքստային ընտրացանկը ստանալու համար: Ընտրացանկում համապատասխանաբար ընտրեք «Deleteնջել շարքերը» կամ «Deleteնջել սյունակները»:

Դժբախտաբար, դուք չեք կարող ընտրել բազմաթիվ ոչ անընդմեջ տողեր կամ սյուններ և ջնջել դրանք այս եղանակով: Այս պահանջի համար կարող եք դիմել մեր նախորդ հոդվածին. Ձեր Word աղյուսակում մի քանի շարքեր կամ սյուններ խմբաքանակով ջնջելու 5 արագ մեթոդներ

Մեթոդ 2. Աղյուսակում խմբաքանակը ջնջել բոլոր դատարկ շարքերը և սյունակները

Մեթոդը 1 ունի իր սահմանափակումները: Այսպիսով, մենք ձեզ կառաջարկենք VBA կոդերի միջոցով աղյուսակում խմբաքանակը և սյունակները հեռացնելու եղանակ:

1. Սկսելու համար տեղադրեք կուրսորը թիրախային աղյուսակի ներսում։
2. Երկրորդը, գործարկեք VBA խմբագիրը `սեղմելով« Alt + F11 »:
3. Խմբագրությունում նախ կտտացրեք «Նորմալ» նախագիծը:
4. Դրանից հետո կտտացրեք «sertետեղել» ներդիրին ընտրացանկում:
5. Բացվող ընտրացանկում ընտրեք «Մոդուլ»:
6. Կրկնակի կտտացրեք մոդուլին ՝ այն բացելու համար և տեղադրեք հետևյալ կոդերը.

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Ի վերջո, կտտացրեք «Run» կոճակին ընտրացանկի վրա կամ սեղմեք «F5»:

Վայրկյանների ընթացքում այդ աղյուսակի բոլոր դատարկ տողերն ու սյունները կհեռացվեն:

Մեթոդ 3. Փաթեթի բոլոր աղյուսակների խմբաքանակը ջնջել բոլոր դատարկ շարքերը և սյունակները

1. Սկզբից, կրկնում ենք 2-րդ մեթոդի քայլերը `մակրո տեղադրելու և գործարկելու համար:
2. Միայն այս անգամ այդ մակրո-ն փոխարինեք հետևյալով.

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Վերականգնել կոտրված փաստաթուղթը

Այսօր կորցրած տվյալները վերականգնելու ավելի քան մեկ եղանակ կա։ Օրինակ, պահուստային պատճենների օգտագործումը միշտ մնում է ձեր գերակա խնդիրը։ Եթե դա չի բավարարում ձեր կարիքը՝ վերականգնելու ամենաթարմ տեղեկատվությունը, կարող եք փորձել փաստաթղթի նորոգում գործիք.

Հեղինակի ներածություն.

Վերա Չենը տվյալների վերականգնման փորձագետ է DataNumen, Inc., որը տվյալների վերականգման տեխնոլոգիաների համաշխարհային առաջատարն է, այդ թվում xlsx վերանորոգում և pdf նորոգել ծրագրային արտադրանքները: Լրացուցիչ տեղեկությունների համար այցելեք www.datanumen.com