Kako grupno izvesti više Outlook e-poruka u jedan Word dokument putem VBA

Ako želite grupno izvesti više Outlook e-poruka u jedan Word dokument, možete koristiti VBA kod prikazan u ovom članku. Može vam pomoći da izvršite ovaj zadatak u roku od nekoliko sekundi.

Ikad sam predstavio kako pretvoriti Outlook e-poštu u Word dokument u svom prethodnom članku – "2 učinkovite metode za pretvaranje Outlook e-pošte u Word dokument”. Međutim, oba 2 sredstva spomenuta u toj strost bit će bespomoćan u slučaju kada želite grupno izvesti mnogo e-poruka u jedan Word dokument. Stoga ćemo vas ovdje naučiti još jedan način. Sada čitajte dalje da biste to detaljno shvatili.

Skupni izvoz više Outlook e-pošte u jedan Word dokument

1. Za start pomoću, pokrenite svoj Outlook program.
2. Zatim, nakon ulaska u glavni prozor programa Outlook, morate pritisnuti tipke "Alt + F11".
3. Zatim ćete dobiti pristup Outlook VBA editoru, u kojem trebate otvoriti prazan modul.
4. Nakon toga kopirajte donji VBA kod u otvoreni prozor modula.

Sub ExportMultipleEmails_OneWordDocument()
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim objSelection As Outlook.Selection
    Dim objMail As Outlook.MailItem
    Dim strFileName As String
    Dim objWordApp As Word.Application
    Dim objNewWordDocument As Word.Document
    Dim objWordRange As Word.Range
    Dim strWordDocument As String
    Dim i As Long
  
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp" & Format(Now, "YYYYMMDDhhmmss")
    MkDir (strTempFolder)
 
    On Error Resume Next
    'Save each selected email as an individual Word document in a temp folder
    Set objSelection = Outlook.Application.ActiveExplorer.Selection
    For Each objMail In objSelection
        strFileName = objMail.Subject
 
        'Remove the unsupported characters in email subject
        strFileName = Replace(strFileName, "/", " ")
        strFileName = Replace(strFileName, "\", " ")
        strFileName = Replace(strFileName, ":", "")
        strFileName = Replace(strFileName, "?", " ")
        strFileName = Replace(strFileName, Chr(34), " ")
 
        objMail.SaveAs strTempFolder & "\" & strFileName & ".doc", olDoc
    Next
 
    'Merge all the Word documents into a single document
    Set objWordApp = CreateObject("Word.Application")
    Set objNewWordDocument = objWordApp.Documents.Add
 
    strWordDocument = Dir(strTempFolder & "\" & "*.doc")
    i = 0
    Do Until strWordDocument = ""
       i = i + 1
       Set objWordRange = objNewWordDocument.Range
       With objWordRange
           .Collapse wdCollapseEnd
           If i > 1 Then
             .InsertBreak wdSectionBreakNextPage
             .End = objNewWordDocument.Range.End
             .Collapse wdCollapseEnd
           End If
           .InsertFile strTempFolder & "\" & strWordDocument
      End With
      strWordDocument = Dir()
    Loop
 
    'Change the path as per your own needs
    objNewWordDocument.SaveAs "E:\Exported Emails " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    objWordApp.Quit
 
    'Delete the temp folder
    objFileSystem.DeleteFolder (strTempFolder)
End Sub

5. Nakon toga, bolje je dodati ovaj novi VBA projekt na alatnu traku ili vrpcu za brzi pristup.
6. U konačnici, možete pokušati.

• Na prvom mjestu odaberite više Outlook e-pošte.
• Zatim pronađite i kliknite na novododani makro gumb.
• Nakon što se od vas zatraži "Dovršeno", možete pregledavati unaprijed definiranu lokalnu mapu kako biste pronašli novi Word dokument.
• Otvorite ovaj dokument u kojem možete vidjeti da su sve odabrane e-poruke izvezene.

Držite moćan alat za oporavak u blizini

Bez obzira na brojne funkcije, Outlook ipak ne može biti imun na pogreške. Ako ste navikli ostavljati pogreške na miru, dok se one gomilaju, Outlook će se srušiti. U tom trenutku bitno je vratiti se moćnom i učinkovitom alatu za oporavak, kao što je DataNumen Outlook Repair. Dobro je upućen u PST popravak. Sve dok je s njim, više nećete morati brinuti o gubitku Outlook podataka.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećeni mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com