Kako brzo izvesti statistiku glasovanja iz Outlook e-pošte u Excel radni list

Ako ste poslali e-poštu s gumbima za glasovanje, nakon što vam primatelji pošalju svoje odgovore, možda ćete htjeti prebrojati i izvesti statistiku glasovanja u Excel radni list. Dakle, u ovoj strost, naučit ćemo vas kako to brzo postići.

Outlook je toliko moćan da nudi čak i značajku "Glasovanje". Moj prethodni članak "Vješto korištenje MS Outlooka za glasovanje” je naučio kako ga učinkovito koristiti. Također, most vremena, nakon glasovanja, možete nastaviti s izvozom statistike glasovanja u Excel radni list iz nekih razloga, kao što je želja za ispisom statistike. Ali Outlook to ne podržava prema zadanim postavkama. Stoga ćemo vas u nastavku naučiti kako to realizirati poput čepa.

Izvezite statistiku glasovanja iz e-pošte u Excel radni list

1. Na samom početku pokrenite svoju Outlook aplikaciju.
2. Zatim biste trebali pritisnuti tipke "Alt + F11" u glavnom prozoru programa Outlook.
3. Zatim u prozoru "Microsoft Visual Basic za aplikacije" trebali biste omogućiti "Microsoft Excel Object Library”. Kliknite "Alati" > "Referenca". Zatim u skočnom dijaloškom okviru označite potvrdni okvir ispred “Microsoft Excel Object Library” i na kraju pritisnite “OK”.
4. Nakon toga možete umetnuti novi modul ili otvoriti onaj koji nije u upotrebi.
5. Nakon toga kopirajte i zalijepite sljedeće VBA kodove u ovaj modul.

Sub ExportVotingStatistics _Excel ()
    Dim objMail As Outlook.MailItem
    Dim objRecipient As Outlook.recipient
    Dim objVoteDictionary As Object
    Dim varVotingCounts As Variant
    Dim varVotingOptions As Variant
    Dim varVotingOption As Variant
    Dim i As Long
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim nRow As Integer
 
    Set objMail = Application.ActiveExplorer.Selection(1)
 
    'Create a new excel worksheet
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
 
    'Fill in the predefined values
    With objExcelWorksheet
         .Cells.Font.Name = "Cambria"
         .Cells(1, 1) = "Voting Results for Email:"
         .Cells(1, 2) = Chr(34) & objMail.Subject & Chr(34)
         .Cells(3, 1) = "Voting Options"
         .Cells(3, 2) = "Voting Counts"
    End With
 
    Set objVoteDictionary = CreateObject("Scripting.Dictionary")
    'get the default voting options
    varVotingOptions = Split(objMail.VotingOptions, ";")
    'Add the voting responses to the dictionary
    For Each varVotingOption In varVotingOptions
        objVoteDictionary.Add varVotingOption, 0
    Next
    'Add a custom voting response - "No Reply"
    objVoteDictionary.Add "No Reply", 0
 
    'Process the all voting responses
    For Each objRecipient In objMail.Recipients
        If objRecipient.TrackingStatus = olTrackingReplied Then
           If objVoteDictionary.Exists(objRecipient.AutoResponse) Then
              objVoteDictionary.Item(objRecipient.AutoResponse) = objVoteDictionary.Item(objRecipient.AutoResponse) + 1
           Else
              objVoteDictionary.Add objRecipient.AutoResponse, 1
           End If
        Else
           objVoteDictionary.Item("No Reply") = objVoteDictionary.Item("No Reply") + 1
        End If
    Next
 
    'Get the voting options and vote counts
    varVotingOptions = objVoteDictionary.Keys
    varVotingCounts = objVoteDictionary.Items
 
    'Fill in the values in specific cells
    nRow = 4
    For i = LBound(varVotingOptions) To UBound(varVotingOptions)
        With objExcelWorksheet
             .Cells(nRow, 1) = varVotingOptions(i)
             .Cells(nRow, 2) = varVotingCounts(i)
        End With
        nRow = nRow + 1
    Next
 
    'Save the new Excel file
    objExcelWorksheet.Columns("A:B").AutoFit
    strExcelFile = "E:\Voting Results " & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".xlsx"
    objExcelWorkbook.Close True, strExcelFile

    MsgBox "Complete!", vbExclamation
End Sub

5. Nakon toga, radi praktičnog pristupa, bolje je dodati novu makronaredbu na alatnu traku za brzi pristup.
6. Naposljetku, možete pokušati.

• Prvo odaberite izvornu e-poštu koja sadrži gumbe za glasovanje.
• Zatim kliknite gumb makronaredbe na alatnoj traci za brzi pristup.
• Nakon što se ova makronaredba završi s izvođenjem, možete pregledavati unaprijed definiranu lokalnu mapu u kojoj ćete vidjeti novu Excel radnu knjigu.
• Otvorite ovu Excel radnu knjigu. Sada ćete vidjeti statistiku glasovanja, prikazanu na slici ispod:

Nitko ne može temeljito spriječiti Outlookove pogreške

Iako Outlook dolazi s nizom mogućnosti, ne postoji takva značajka koja bi nam pomogla da izbjegnemo pogreške programa Outlook. Sve vrste faktora mogu uzrokovati Outlook pogreške. Na primjer, ako često napuštate Outlook na nepravilan način, vjerojatno ćete patiti PST korupcija. U takvom scenariju nemate drugog izbora nego upotrijebiti neke moćne alate za spašavanje vaše PST datoteke, npr. DataNumen Outlook Repair. Zaslužio je mnogo pohvala zbog svoje visoke stope oporavka.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući pokvaren mdf i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com