Kako automatski poslati obavijest e-poštom kada je određeni zadatak dovršen u programu Outlook

Nakon dovršetka zadatka u programu Outlook, mnogi će korisnici možda poželjeti poslati e-poruku obavijesti kako bi obavijestili nekoga, primjerice nadređenog. Ručno slanje e-pošte bit će dugotrajno. Ovaj članak predstavit će brzu metodu automatskog slanja ove vrste e-pošte.

Iz članka “4 brza koraka za dodjeljivanje zadataka drugima u vašem Outlooku”, možete znati da će, ako vam je zadatak dodijelio vaš nadređeni i unaprijed je zahtijevao izvješće o statusu, kao na slici ispod, moći automatski primiti izvješće e-poštom.

Međutim, ako ste zadatak upravo izradili sami, Outlook nikada nikome neće poslati obavijest e-poštom kada ga označite kao dovršenog. U tom slučaju, ako želite poslati e-poruku obavijesti o svom radu, morate to učiniti ručno. No sa sljedećim VBA kodovima možete dopustiti Outlooku da to automatski izvrši.

Automatsko slanje obavijesti e-poštom kada je određeni zadatak dovršen

1. Prvo biste trebali pokrenuti Outlook i prijeći na karticu "Programer".
2. Zatim pronađite i kliknite gumb "Visual Basic". Pojavit će se novi prozor "Microsoft Visual Basic za aplikacije".
3. Nakon toga dvaput kliknite projekt “ThisOutlookSession” da biste ga otvorili, a zatim u njega kopirajte sljedeće VBA kodove.

Public WithEvents olItems As Outlook.Items

Private Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderTasks).Items
End Sub

Private Sub olItems_ItemChange(ByVal Item As Object)
    Dim obApp As Outlook.Application
    Dim olMail As Outlook.MailItem
    Dim Recip As String
 
    'Replace "test" as per your needs
    If InStr(LCase(Item.Subject), "test") > 0 And Item.Complete = True Then
       'Replace with your desired contact
       Recip = "John Smith"
       If MsgBox("Do you want to send a report to " & Recip & " ?", vbYesNo + vbQuestion, "Confirm Sending Report") = vbYes Then
          Set obApp = Outlook.Application
          Set olMail = obApp.CreateItem(olMailItem)
          With olMail
               .To = Recip
               .Subject = "Complete: " & Item.Subject
               .Body = "Dear Mr. Smith" & vbCrLf & "I've completed this task in " & DateDiff("d", Item.CreationTime, Now) & " day" & Chr(40) & "s" & Chr(41) & "." & vbCrLf & vbCrLf & "Task Name: " & Item.Subject & vbCrLf & "Start Date: " & Item.StartDate & vbCrLf & "Due Date: " & Item.DueDate & vbCrLf & "Creation Time: " & Item.CreationTime & vbCrLf & "Completed Time: " & Now & vbCrLf & vbCrLf & "Task Details: " & vbCrLf & Item.Body
               .ReadReceiptRequested = True
               'To directly send it,use ".Send" instead
               .Display
          End With
       End If
    End If
End Sub

4. Nakon toga nastavite s potpisivanjem ovog koda i promijenite postavke makronaredbe tako da dopuštaju samo digitalno potpisane makronaredbe.
5. Konačno možete izaći iz trenutnog prozora i pokušati.

• Kada označite zadatak kao dovršen, primit ćete poruku poput sljedeće slike:
• Kada kliknete na gumb "Da", otvorit će se nova poruka, prikazana na slici ispod:

Bilješka: Ako zamijenite ".display" retkom ".Send", ova će e-poruka biti poslana izravno bez prikazivanja.

Obratite pozornost na poruke s nepoznatih adresa e-pošte

Sigurno ste ikada primili mnogo e-poruka s nepoznatih adresa. Preporučljivo je biti oprezan s ovom vrstom e-pošte. To je zato što mogu izgledati bezopasno, ali sadrže zlonamjerne veze, privitke ili makronaredbe. Nakon što ih kliknete ili otvorite, vaš se Outlook može zaraziti. U tom trenutku, kako biste vratili svoje Outlook podatke, nemate izbora nego upotrijebiti stelar uslužni program za popravak oštećenih Outlook podataka, Kao što su DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popravak SQL mdf problema i softverske proizvode za popravak Outlooka. Za više informacija posjetite www.datanumen.com