3 načina za dobivanje statističkih podataka o broju riječi povezanih s tekstualnim okvirima, fusnotama i bilješkama u vašem dokumentu

U današnjem članku postoje 3 brza načina za dobivanje statističkih podataka o broju riječi povezanih s tekstnim okvirima, fusnotama i krajnjim bilješkama u vašem dokumentu.

Nije teško dobiti ukupan broj riječi u dokumentu. Ali ako želite dobiti broj riječi različitih vrsta tekstova, bit će potrebno više operacija. Slijede 3 metode. Pročitajte kako biste vidjeli što možete koristiti. 

Metoda 1: Brojite riječi uključujući tekstove iz tekstnih okvira, fusnote i bilješke

Prema zadanim postavkama, Word broji sve riječi koje se pojavljuju u dokumentu, uključujući tekstove u tekstnim okvirima te riječi iz fusnota i bilješki.

1. Prvo i najvažnije, idite na statusnu traku i kliknite "Riječi" da biste otvorili okvir "Broj riječi".
2. Tamo ćete vidjeti sve vrste statistika. Provjerite jeste li označili okvir "Uključi tekstne okvire, fusnote i endnote".
3. Zatim kliknite "Zatvori".
4. Ako ne možete pronaći naredbu “Riječi” na statusnoj traci, kliknite tamo desnom tipkom.
5. Zatim provjerite "Broj riječi".

Metoda 2: Isključite tekstove iz tekstnih okvira, fusnote i bilješke iz brojanja riječi

Ovo je suprotno metodi 1. Dakle, samo trebate poništiti okvir "Uključi tekstne okvire, fusnote i endnote".

Metoda 3: Pokrenite Word makronaredbu da dobijete odvojeni broj riječi iz tekstualnih okvira, fusnota i bilješki

1. Prvo pokrenite okvir "Broj riječi" na način iz metode 1 i osigurajte da je okvir opcije označen.
2. Zatim pritisnite “Alt+ F11” da biste otvorili VBA editor.
3. Zatim umetnite novi modul u "Normal" projekt tako da prvo kliknete "Normal".
4. Zatim kliknite "Umetni".
5. Zatim odaberite “Modul”.
6. Dvaput kliknite na modul da biste otvorili područje kodiranja i tamo zalijepite sljedeće kodove:

Sub SeparateCountNumberOfTextboxFootnoteEndnote()
  Dim lTextboxWords As Long
  Dim lTextboxChars As Long
  Dim lDocumntWords As Long
  Dim lDocumntChars As Long
  Dim objTextboxShape As Shape
  Dim objTemp As Dialog
  Dim bDone As Boolean
  Dim objRange As Range
  Dim lFootnoteWords As Long
  Dim lFootnoteChars As Long
  Dim lEndnoteWords As Long
  Dim lEndnoteChars As Long
 
  Application.ScreenUpdating = False

 Do
   bDone = True
   For Each objTextboxShape In ActiveDocument.Shapes
     If objTextboxShape.Type = msoGroup Then
       objTextboxShape.Ungroup
       bDone = False
     End If
   Next objTextboxShape
 Loop Until bDone

 '  Count the words and characters in the whole document.
 Selection.HomeKey Unit:=wdStory
 Set objTemp = Dialogs(wdDialogToolsWordCount)
   objTemp.Update
   objTemp.Execute
   lDocumntWords = objTemp.Words
   lDocumntChars = objTemp.Characters
 
 With ActiveDocument
 '  Count the words and characters in all textboxes.
   lTextboxWords = 0
   lTextboxChars = 0
   If ActiveDocument.Shapes.Count > 0 Then
     For Each objTextboxShape In .Shapes
       objTextboxShape.Select
       objTemp.Execute
       lTextboxWords = lTextboxWords + objTemp.Words
       lTextboxChars = lTextboxChars + objTemp.Characters
     Next objTextboxShape
   Else
     MsgBox ("There is no text box in this document")
   End If

   '  Count the words and characters in all footnotes.
   lFootnoteWords = 0
   lFootnoteChars = 0
   If ActiveDocument.Footnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdFootnotesStory Then
         objRange.Select
         objTemp.Execute
         lFootnoteWords = lFootnoteWords + objTemp.Words
         lFootnoteChars = lFootnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no footnote in this document")
   End If

   '  Count the words and characters in all endnotes. 
   lEndnoteWords = 0
   lEndnoteChars = 0
   If ActiveDocument.Endnotes.Count > 0 Then
     For Each objRange In .StoryRanges
       If objRange.StoryType = wdEndnotesStory Then
         objRange.Select
         objTemp.Execute
         lEndnoteWords = lEndnoteWords + objTemp.Words
         lEndnoteChars = lEndnoteChars + objTemp.Characters
       End If
     Next objRange
   Else
     MsgBox ("There is no Endnote in this document")
   End If
 End With
 
 Application.ScreenUpdating = True

 MsgBox (" In this document there are totally" & vbCr _
   & Str(lDocumntWords) & " word(s) and" & Str(lDocumntChars) & " characters" & vbCr & vbCr _
   & "Including:" & vbCr _
   & Str(ActiveDocument.Shapes.Count) & " textboxes contain(s)" & vbCr _
   & Str(lTextboxWords) & " word(s)," & Str(lTextboxChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Footnotes.Count) & " footnotes contain(s)" & vbCr _
   & Str(lFootnoteWords) & " word(s)," & Str(lFootnoteChars) & " characters" & vbCr & vbCr _
   & Str(ActiveDocument.Endnotes.Count) & " Endnotes contain(s)" & vbCr _
   & Str(lEndnoteWords) & " word(s)," & Str(lEndnoteChars) & " characters")
End Sub

7. Na kraju kliknite gumb "Pokreni".

Ako nema tekstualnog okvira, fusnote ili krajnje bilješke, primit ćete okvir s porukom kao što je ovaj:

Samo kliknite "OK" za nastavak. Tada ćete vidjeti još jedan okvir s popisom svih pojedinosti o broju riječi.

Nabavite alat za oporavak

Budući da se Word može iznenada srušiti, preporučljivo je nabaviti napredni proizvod za popravak koji će obaviti posao popravljanja. Takav alat može biti izvrstan ušteda za pokvarena Riječ. Stoga, iskoristite vrijeme da ga nabavite što prije.

Uvod za autora:

Vera Chen stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popraviti xls i pdf popraviti softverske proizvode. Za više informacija posjetite www.datanumen.com