2 načina za brzo spajanje više Word dokumenata u jedan putem VBA

U ovom članku, drago nam je podijeliti s vama 2 načina za brzo spajanje više Word dokumenata u jedan putem VBA.

U Wordu postoji zadana ugrađena značajka koja pomaže korisniku pri kombiniranju ili spajanju nekoliko dokumenata u jedan. Pojedinosti su objašnjene u ovom članku: Kako kombinirati i spojiti više Word dokumenata u jedan

Kod ove metode morate napraviti nekoliko klikova i sadržaj sljedećeg dokumenta uvijek dolazi odmah nakon prethodnog. Stoga vam želimo ponuditi brže načine da to učinite.

Metoda 1: Spajanje odabranih dokumenata u jedan

1. Prvo i najvažnije, stvorite novi prazan dokument.
2. Pokrenite VBA editor u Wordu pritiskom na “Alt+ F11”.
3. Zatim kliknite "Normalno".
4. Zatim kliknite "Umetni".
5. I odaberite "Modul".
6. Dvaput kliknite na novi modul da biste otvorili prostor za uređivanje.
7. Tamo zalijepite sljedeću makronaredbu:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Zatim kliknite "Pokreni" ili pritisnite "F5".
9. Sada u prozoru “Browse” odaberite više datoteka pritiskom na “Ctrl” i kliknite “OK”.
10. Zatim će se sav sadržaj odabranih datoteka spojiti u novom dokumentu, s tekstovima svakog dokumenta koji počinju na novoj stranici.

Bilješka:

Kao što smo spomenuli, ovaj makro stavlja tekstove svakog dokumenta na novu stranicu. Ali ako trebate da budu jedan za drugim, možete promijeniti neke retke koda u makronaredbi. Samo pronađite redak “If nEachSelectedFile < nTotalFiles Then”, izbrišite ga i sljedećih šest redaka također.

Metoda 2: Spajanje svih dokumenata u mapi u jedan

U slučaju da imate mapu s datotekama koje treba kombinirati, ova će makronaredba savršeno funkcionirati.

1. Za početak, instalirajte i pokrenite makro kao što je opisano u metodi 1.
2. Zatim zamijenite makronaredbu ovim:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Pokrenite makronaredbu klikom na "Pokreni".
4. Zatim ćete vidjeti otvoren prozor "Pregledaj". Odaberite mapu u koju pohranjujete sve dokumente. I kliknite "OK".

Slično tome, tekstovi svakog dokumenta počinju na novoj stranici. Da biste ih spojili jedan za drugim, pronađite i izbrišite redak koda „.InsertBreak Type:=wdPageBreak“.

Pravilno zaštitite svoj Word dokument

Jedan od najboljih načina da zaštitite svoje Word dokumente je njihovo redovito sigurnosno kopiranje. Uz sigurnosne kopije pri ruci, nikada se nećete morati bojati gubitka podataka. Osim toga, također je preporučljivo nabaviti alat za popravak docx ako bilo koji od njih bude oštećen.

Uvod za autora:

Vera Chen stručnjakinja je za oporavak podataka u DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen Excel i pdf popraviti softverske proizvode. Za više informacija posjetite www.datanumen.com