Cómo encontrar rápidamente párrafos de una oración en su documento de Word

En esta publicación, queremos mostrarte la forma rápida de encontrar todos los párrafos de una sola oración en tu documento de Word mediante VBA.

De vez en cuando, algunos documentos pueden tener requisitos muy específicos para su formato y estructura. Por ejemplo, es posible que no se le permita tener párrafos con una sola oración. Estos párrafos no son difíciles de reconocer, pero lleva tiempo, especialmente si es un documento largo.

Hoy, le ofreceremos la manera más rápida de especificar todos los párrafos de una oración en su documento.

Encuentre todos los párrafos de una oración en un documento

1. En primer lugar, Word cuenta un punto como una oración. Entonces, si hay palabras como "Sr." o "Sra.", Word lo considera como una oración. Para excluir tal distracción, debe reemplazar "Sr." con "Mr". Y cuando termine de buscar el párrafo de una sola oración, puede volver a cambiarlos. Para reemplazar palabras, puede consultar este enlace: Cómo buscar y reemplazar varios elementos en su documento de Word
2. En segundo lugar, presione "Alt + F11" para activar el editor de VBA.
3. Luego haga clic en el proyecto "Normal".
4. Haga clic en la pestaña "Insertar" en la barra de menú y seleccione "Módulo" en su menú desplegable.
5. Luego haga doble clic en el módulo para abrirlo.
6. Pegue los siguientes códigos en el módulo:

Sub HighlightParagraphsWithSingleSentence()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim nHighlightNum As Integer
 
  nCountParagraph = ActiveDocument.Paragraphs.Count
  nHighlightNum = 0
 
  For nParagraphNum = 1 To nCountParagraph
    Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
    nCountSentence = objParagraphRange.Sentences.Count
    ' Highlight all paragraphs with single-sentence.
    If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
      nHighlightNum = nHighlightNum + 1
      objParagraphRange.HighlightColorIndex = wdYellow
    End If
  Next

  If nHighlightNum > 0 Then
    MsgBox ("There are " & nHighlightNum & " paragraphs with single sentence and they are highlighted.")
  Else
    MsgBox ("There are no paragraphs with single sentence")
  End If

End Sub

7. Por último, pero no menos importante, haga clic en el botón "Ejecutar" o presione "F5".

Recibirá un cuadro de mensaje de este tipo, indicándole que el trabajo está hecho.

Buscar todos los párrafos de una oración en varios documentos

1. Para empezar, debes colocar todos los documentos de destino en una carpeta.
2. Luego instale y ejecute la siguiente macro:

Sub HighlightParagraphsWithSingleSentenceInMultipleFiles()
  Dim nParagraphNum As Integer
  Dim nCountParagraph As Integer
  Dim objParagraphRange As Range
  Dim nCountSentence As Integer
  Dim StrFolder As String
  Dim strFile As String
  Dim objDoc As Document
  Dim dlgFile As FileDialog
  Dim nHighlightNum As Integer
  Dim strSummary As String

  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)

  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No Folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.doc*", vbNormal)
 
  While strFile <> ""
    nHighlightNum = 0
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    Set objDoc = ActiveDocument
    nCountParagraph = ActiveDocument.Paragraphs.Count
 
    For nParagraphNum = 1 To nCountParagraph
      Set objParagraphRange = ActiveDocument.Paragraphs(nParagraphNum).Range
      nCountSentence = objParagraphRange.Sentences.Count
      ' Highlight all paragraphs with single-sentence.
      If nCountSentence = 1 And objParagraphRange.Characters.Count > 1 Then
        nHighlightNum = nHighlightNum + 1
        objParagraphRange.HighlightColorIndex = wdYellow
      End If
    Next
    objDoc.ActiveWindow.ActivePane.View.SeekView = wdSeekMainDocument
    objDoc.Save
    If nHighlightNum = 0 Then
      objDoc.Close
    End If
 
    strSummary = strSummary & strFile & " : " & nHighlightNum & " paragraphs with single sentence." & vbCrLf
    strFile = Dir()
  Wend
  MsgBox (strSummary)
 
End Sub

3. En la ventana "Examinar" abierta, elija la carpeta donde guarda los documentos y haga clic en "Aceptar".

Luego, la macro resaltará todos los párrafos de una oración y dejará los documentos abiertos. Si un documento no contiene un párrafo de una sola oración, se cerrará. Además, hay un cuadro de mensaje, que indica el número de párrafos de una oración en cada documento.

Hacer frente a un incidente de pérdida de datos

Los errores del usuario y los cortes de energía repentinos pueden provocar la muerte de Word. Si bien una palabra colapsada no solo puede afectar el trabajo diario, sino que también doc dañoEsto no es, ni mucho menos, lo más molesto de un desastre de datos. Es mejor contratar un servicio de reparación para recuperar los datos de inmediato.

Introducción del autor:

Vera Chen es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperar excel pdf reparar productos de software. Para más información visite www.datanumen.com