Cómo exportar rápidamente el tiempo total dedicado a las citas de Outlook en cada categoría de color

Si desea crear un informe sobre el tiempo total que dedica a las citas en cada categoría de color, puede utilizar el método presentado en este artículo. Puede ayudarlo a lograr esto en poco tiempo sin necesidad de contar manualmente.

Muchos usuarios están acostumbrados a registrar la mayoría de sus actividades en el calendario de Outlook. Además, para gestionarlas y diferenciarlas más fácilmente, les asignan categorías. En este caso, algunos usuarios desean generar un informe que muestre el tiempo total dedicado a cada elemento del calendario, clasificado por color. Sin duda, contar e introducir los datos manualmente resulta engorroso. Por ello, aquí les mostraremos una forma de realizar esta tarea con un simple clic.

Exportar el tiempo total invertido en las citas en cada categoría de color

1. En primer lugar, inicie su aplicación Outlook.
2. Luego, después de ingresar a la ventana de Outlook, puede tocar los botones de la tecla "Alt + F11".
3. Posteriormente, obtendrá acceso a la ventana "Microsoft Visual Basic para aplicaciones".
4. A continuación, deberá habilitar la “Biblioteca de objetos de Microsoft Excel”. Para ello, haga clic en “Herramientas” > “Referencias”.
5. Luego, debe buscar y abrir un módulo que no esté en uso.
6. Después de eso, debe copiar el siguiente código VBA en este módulo.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Por último, puede activar esta macro, sin importar si hace clic en el icono "Ejecutar" en la barra de herramientas o si presiona el botón de la tecla "F5".
8. Luego, se le pedirá que seleccione un calendario específico.
9. Después de seleccionar y presionar "Aceptar", la macro continuará ejecutándose. Una vez que finalice, habrá un nuevo archivo de Excel que se mostrará en segundo plano.
10. Puedes acceder a él. Se verá como la siguiente captura de pantalla:

Esté atento a las posibles amenazas en torno a su Outlook

Los usuarios de Outlook deben estar atentos a todos los riesgos potenciales, incluidos los archivos adjuntos de correo electrónico desconocidos, los enlaces incrustados y los errores humanos. De lo contrario, Outlook puede dañarse en cualquier momento. Además, es necesario realizar copias de seguridad de datos de Outlook con regularidad y mantener una herramienta de reparación especializada. DataNumen Outlook Repair es una de las herramientas de reparación más recomendadas. Puede reparar Outlook problemas en un santiamén.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo mdf dañado y productos de software de reparación de Outlook. Para más información visite www.datanumen.com