Cómo copiar rápidamente la estructura de carpetas de un archivo PST de Outlook a otro a través de VBA

Si desea copiar la estructura de carpetas de un archivo PST de Outlook a otro, puede usar el método presentado en este artículo, que le enseñará cómo usar VBA para obtenerlo de una vez.

Quizás, para administrar mejor sus correos electrónicos, haya creado varias carpetas personalizadas en su archivo principal de Outlook. Por lo tanto, al crear un nuevo archivo PST de Outlook, es posible que desee aplicar la misma estructura de carpetas. De hecho, en mi artículo anterior: "2 pasos para mantener la jerarquía de carpetas actual en un nuevo archivo de Outlook.”, Puede aprender un método tradicional, que utiliza la función" Archivo "para lograrlo. Sin embargo, en realidad, todavía es un poco tedioso. Comparado con él, usar códigos VBA para obtenerlo será mucho más rápido. Por lo tanto, a continuación, te contamos los pasos y códigos detallados.

Copiar la estructura de carpetas de un archivo PST de Outlook a otro

1. Para empezar, inicie su programa Outlook.
2. Luego, en la ventana de Outlook, presione los botones de tecla "Alt + F11".
3. A continuación, ingresará a la ventana del editor de Outlook VBA.
4. Posteriormente, copie y pegue los siguientes códigos VBA en un nuevo módulo.

Public objNewPSTFolder As Outlook.Folder
 
Sub CopyFolderStructure()
    Dim objFolders As Outlook.Folders
    Dim objFolder As Outlook.Folder
 
    'Get the folders of the source Outlook PST file
    Set objFolders = Outlook.Application.Session.Folders("Personal").Folders
 
    'Create the new pst file in your desired local folder and name
    Outlook.Application.Session.AddStore "E:\New PST File.pst"
    Set objNewPSTFolder = Session.Folders.GetLast()
 
    For Each objFolder In objFolders
        CreateFolder objFolder
    Next
 
    MsgBox "Completed!", vbOKOnly + vbInformation, "Copy Folder Structure"
End Sub
 
Sub CreateFolder(objFolder As Outlook.Folder)
    Dim objSubFolder As Outlook.Folder
 
    'Only copy the mail folder
    If (objFolder.DefaultItemType = olMailItem) Then
       'New Outlook PST file auto includes the "Deleted Items" folder, so skip it
       'Skip the useless mail folders - "Conversation Action Settings" and "Quick Step Settings"
       If (objFolder.Name <> "Deleted Items") And (objFolder.Name <> "Conversation Action Settings") And (objFolder.Name <> "Quick Step Settings") Then
 
          'Create the new folder
          objNewPSTFolder.Folders.Add objFolder.Name
          Set objNewPSTFolder = objNewPSTFolder.Folders.Item(objFolder.Name)
 
          For Each objSubFolder In objFolder.Folders
              CreateFolder objSubFolder
          Next
 
          Set objNewPSTFolder = objNewPSTFolder.parent
       End If
    End If

End Sub

5. Después de eso, cambie su nivel de seguridad macro a bajo.
6. Más tarde, regrese a la ventana del editor de VBA y presione el botón "F5" para ejecutar la macro.
7. Finalmente, después de que la macro termine de funcionar, recibirá un mensaje que indica "Completado!".
8. En este punto, puede ir al panel de navegación de correo. Verá un nuevo archivo de datos de Outlook que está en la misma estructura de carpetas que el archivo PST de origen, como la imagen a continuación:

Hacer frente a los desalentadores problemas del PST

Como Outlook PST es propenso a errores, muchos de ustedes deben haber encontrado varios problemas en Outlook. Frente a ellos, primero puede usar la herramienta de reparación de la bandeja de entrada de Outlook para intentarlo. Si falla, puede aplicar una herramienta de terceros más potente, como DataNumen Outlook Repair, Que puede arreglar Outlook Errores PST como una brisa.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo SQL Server reparar y productos de software de reparación de Outlook. Para más información visite www.datanumen.com