Cómo convertir rápidamente todas las imágenes incrustadas en archivos adjuntos en su correo electrónico de Outlook

Si desea cambiar rápidamente todas las imágenes incrustadas en el cuerpo del mensaje a archivos adjuntos de correo electrónico, no es necesario que las elimine y vuelva a adjuntar manualmente. Puede usar el fragmento de código VBA expuesto en este artículo.

A veces, es posible que desee convertir por lotes todas las imágenes incrustadas en archivos adjuntos. Por ejemplo, demasiadas imágenes en el cuerpo del mensaje interrumpirán su lectura de los textos en el cuerpo. Por lo tanto, desea eliminarlos del cuerpo del correo electrónico y agregarlos como archivos adjuntos. Por supuesto, puede hacerlo manualmente. Pero debe ser más útil si alguna herramienta o código VBA puede obtener esto de una vez. Aquí le mostraremos un código VBA de este tipo.

Convierta rápidamente todas las imágenes incrustadas en archivos adjuntos

1. En primer lugar, start su programa Outlook.
2. Luego puede cambiar a la pestaña "Desarrollador" y presionar el botón "Visual Basic".
3. A continuación, accederá a la ventana del editor de Outlook VBA.
4. Posteriormente, debe copiar el siguiente código VBA en un módulo en blanco.

Sub TurnEmebeddedImagestoAttachments()
    Dim objMail As Outlook.MailItem
    Dim objAttachments As Outlook.attachments
    Dim objAttachment As Outlook.Attachment
    Dim objFileSystem As Object
    Dim strTempFolder As String
    Dim strFile As String
    Dim i As Long
 
    Select Case Outlook.Application.ActiveWindow.Class
           Case olInspector
                Set objMail = ActiveInspector.CurrentItem
           Case olExplorer
                Set objMail = Application.ActiveExplorer.Selection.Item(1)
    End Select

    Set objAttachments = objMail.attachments
 
    'Create a temp folder
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempFolder = objFileSystem.GetSpecialFolder(2).Path & "\Temp " & Format(Now, "YYYY-MM-DD hh-mm-ss")
    MkDir (strTempFolder)
 
    'Save all embedded images to temp folder
    For i = objAttachments.Count To 1 Step -1
        Set objAttachment = objAttachments.Item(i)
        If IsEmbedded(objAttachment) = True Then
           objAttachment.SaveAsFile strTempFolder & "\" & objAttachment.FileName
        End If
    Next
 
    'Add extracted images as attachments
    strTempFolder = strTempFolder & "\"
    strFile = Dir(strTempFolder)
 
    While Len(strFile) > 0
          objMail.attachments.Add (strTempFolder & strFile)
          strFile = Dir
    Wend
 
    'Remove embedded images from message body
    With objMail
        .BodyFormat = olFormatPlain
    End With
End Sub

Function IsEmbedded(objCurAttachment As Outlook.Attachment) As Boolean
    Dim objPropertyAccessor As Outlook.PropertyAccessor
    Dim strProperty As String
 
    Set objPropertyAccessor = objCurAttachment.PropertyAccessor
    strProperty = objPropertyAccessor.GetProperty("http://schemas.microsoft.com/mapi/proptag/0x3712001E")
 
    If InStr(1, strProperty, "@") > 0 Then
       IsEmbedded = True
    Else
       IsEmbedded = False
    End If
End Function

5. Después de eso, debe confirmar que su Outlook está configurado para permitir macros.
6. Opcionalmente, si lo necesita con frecuencia, será mejor que agregue la nueva macro a la barra de herramientas de acceso rápido para una verificación conveniente en el futuro.
7. Eventualmente puedes intentarlo. Seleccione o abra un correo electrónico y luego ejecute la macro haciendo clic en el botón de nueva macro en la barra de herramientas de acceso rápido.
8. Inmediatamente, todas las imágenes incrustadas se cambiarán a archivos adjuntos como la siguiente captura de pantalla:

Trucos para proteger sus valiosos datos de Outlook

Como todos sabemos, el archivo PST de Outlook es igual de vulnerable que los archivos comunes, como los documentos de Word o las hojas de cálculo de Excel. Por lo tanto, debe estar atento a todos los riesgos relacionados con su archivo PST, como virus o manipulaciones inadecuadas. Por lo tanto, debe realizar copias de seguridad de datos regulares para su archivo PST. Además, si puede permitírselo, es aconsejable mantener un Reparación de Outlook herramienta a mano, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperar mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com