Cómo colocar rápidamente las diapositivas específicas de un PowerPoint Presentación a su correo electrónico de Outlook

Si desea extraer las diapositivas específicas de un PowerPoint presentación a una nueva presentación separada y adjuntarla a un correo electrónico de Outlook, puede utilizar la forma compartida en este artículo.

En lugar de adjuntar un PowerPoint presentación a un correo electrónico, si desea adjuntar las diapositivas específicas de la presentación, en general, primero debe copiar las diapositivas específicas a una nueva presentación. Es demasiado molesto. Por lo tanto, aquí le mostraremos un método que puede realizarlo de una vez.

Adjunte las diapositivas específicas de un PowerPoint Presentación a un correo electrónico

1. En primer lugar, abra el específico PowerPoint presentación.
2. Entonces, en el PowerPoint ventana de la aplicación, presione las teclas "Alt + F11" para acceder al editor de VBA.
3. A continuación, en la nueva ventana, cree un nuevo módulo presionando "Insertar"> "Módulo".
4. Posteriormente, copie y pegue el siguiente código VBA en este módulo.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Después de eso, puede cerrar la ventana actual.
6. Luego, vaya a "Archivo"> ​​"Opciones"> "Barra de herramientas de acceso rápido" para agregar la nueva macro a la barra de herramientas de acceso rápido.
7. Finalmente, puede probar esta macro.

• Porque comotart, seleccione las diapositivas específicas que desea extraer.
• Luego, haga clic en el botón de macro en la barra de herramientas de acceso rápido.
• Inmediatamente, aparecerá un correo electrónico de Outlook, en el que hay un PowerPoint presentación que se extrae de la presentación fuente.

Utilice una herramienta de recuperación eficaz

Como todos sabemos, Outlook está dotado de una utilidad de reparación incorporada: escaneo. Sin embargo, simplemente puede hacer frente a pequeños fallos en Outlook. Si se enfrenta a un daño grave, no tendrá efectos. En ese momento, no tiene más remedio que recurrir a otra herramienta de reparación poderosa y confiable, como DataNumen Outlook Repair. Con él, podrá rescatar su archivo de Outlook dañado.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo mdf dañado y productos de software de reparación de Outlook. Para más información visite www.datanumen.com