Cómo crear rápidamente un grupo de contactos a partir de todos los contactos de Outlook con un puesto de trabajo específico

Para comunicarse más fácilmente con los contactos con un puesto de trabajo específico, es posible que desee crear rápidamente un grupo de contactos a partir de estos contactos. Ahora, en este artículo, compartiremos contigo un método rápido.

Si envía con frecuencia correos electrónicos, tareas o invitaciones a reuniones a los contactos que tienen un puesto de trabajo específico, será mucho más conveniente si crea un grupo de contactos a partir de ellos. Generalmente, de la manera estándar, primero debe crear un nuevo grupo de contactos y luego agregar contactos al grupo como miembros uno por uno. Es un poco molesto. Por lo tanto, a continuación, le enseñaremos una forma mucho más rápida de obtenerlo.

Cree un grupo de contactos a partir de todos los contactos con un puesto de trabajo específico

1. Al principio, en una carpeta de Contactos, seleccione un contacto que tenga el puesto de trabajo específico.
2. Luego, presione "Alt + F11" para acceder al editor de Outlook VBA.
3. A continuación, copie el siguiente código VBA en un módulo o proyecto en blanco.

Dim objContact As Outlook.ContactItem
Dim strJobTitle As String
Dim objNewGroup As Outlook.DistListItem
Dim objTempMail As Outlook.MailItem

Sub CreateContactGroupfromContactsSameJobTitle()
    Dim objStore As Outlook.Store
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    Set objContact = Outlook.Application.ActiveExplorer.Selection(1)
    strJobTitle = objContact.JobTitle
 
    Set objNewGroup = Outlook.Application.CreateItem(olDistributionListItem)
    Set objTempMail = Outlook.Application.CreateItem(olMailItem)
 
    'Process all Contacts folders
    For Each objStore In Outlook.Application.Session.Stores
        Set objOutlookFile = objStore.GetRootFolder
        For Each objFolder In objOutlookFile.Folders
            If objFolder.DefaultItemType = olContactItem Then
               Call ProcessContactsFolders(objFolder)
            End If
        Next
    Next
 
    objNewGroup.AddMembers objTempMail.Recipients
    objNewGroup.Display
End Sub

Sub ProcessContactsFolders(ByVal objCurFolder As Outlook.Folder)
    Dim objItem As Object
    Dim objSubfolder As Outlook.Folder
 
    For Each objItem In objCurFolder.Items
        If objItem.Class = olContact Then
           If objItem.JobTitle = strJobTitle Then
              'Add the contact having the specific job title to the new group
              objTempMail.Recipients.Add (objItem.Email1Address)
              objTempMail.Recipients.ResolveAll
           End If
        End If
    Next
 
    'Process all subfolders recursively
    If objCurFolder.Folders.Count > 0 Then
       For Each objSubfolder In objCurFolder.Folders
           Call ProcessContactsFolders(objSubfolder)
       Next
    End If
End Sub

4. Después de eso, mueva el cursor a la primera subrutina.
5. Finalmente, toque el botón de la tecla "F5" para ejecutar esta macro.
6. Cuando se completa la macro, se mostrará un nuevo grupo de contactos. Contiene todos los contactos con el mismo puesto de trabajo del contacto seleccionado en el Paso 1.

Proteja los datos de Outlook de forma eficaz

Aunque Outlook tiene muchas funciones, no puede deshacerse del hecho de que es vulnerable. Por lo tanto, si no desea perder sus valiosos datos de Outlook, debe esforzarse por protegerlos. Por ejemplo, debe realizar copias de seguridad de los datos de Outlook a intervalos regulares. Además, si es asequible, se recomienda tener una herramienta de reparación de PST de vanguardia, como DataNumen Outlook Repair, Que puede reparar PST datos en un jiff.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo sql dañado y productos de software de reparación de Outlook. Para más información visite www.datanumen.com