Cómo retrasar la entrega a un miembro específico al enviar un correo electrónico de Outlook a un grupo de contactos

Este artículo compartirá un fragmento de código VBA, que puede permitirle retrasar rápidamente la entrega a un miembro específico al enviar un correo electrónico a un grupo de contactos en Outlook.

Cuando redacta y envía un correo electrónico de Outlook a un grupo de contactos, si desea retrasar el envío de este correo electrónico a un miembro específico de este grupo, puede utilizar el siguiente método para realizarlo. Automáticamente expandirá el grupo de contacto y generará un mismo correo electrónico que se retrasa para el miembro específico. Ahora, sigue leyendo para conocer los pasos detallados.

Retrasar la entrega a un miembro específico al enviar un correo electrónico a un grupo de contactos

1. Para empezar, abre tu programa Outlook.
2. Luego, en la ventana principal emergente de Outlook, debe presionar los botones de tecla "Alt + F11".
3. Posteriormente, obtendrá acceso al editor de Outlook VBA, en el que debe insertar un nuevo módulo o simplemente abrir un módulo que no está en uso.
4. Después de eso, puede copiar y pegar el siguiente código VBA en este módulo.

Sub DelayEmail_aSpecificMemberinContactGroup()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objDelayedMail As MailItem
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact group in "To" field
          For i = objRecipients.count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend

    'Find the specific memebr in the recipients
    For Each objRecipient In objRecipients
        If objRecipient.Address = "shelly@datanumen.com" Then
 
           'Create a same email
           Set objDelayedMail = objCurrentMail.Copy
           With objDelayedMail
                .To = ""
                .Recipients.Add objRecipient.Address
                .Recipients.ResolveAll
                'Change the deferred delivery time as per your needs
                .DeferredDeliveryTime = (Date + 1) & " 09:00:00"
                .Send
          End With
 
          objRecipient.Delete
       End If
    Next
 
    objCurrentMail.Send
End Sub

5. A continuación, para un acceso conveniente posterior, es mejor que agregue la macro recién agregada a la barra de herramientas de acceso rápido de la ventana de mensajes.
6. Y luego debe modificar la configuración de macro de Outlook para habilitar todas las macros en la "Configuración de macros" del "Centro de confianza".
7. Eventualmente, puedes tomar una foto.

• En primer lugar, redacte un correo electrónico de este tipo para el grupo de contacto como de costumbre.
• Luego, puede hacer clic en el botón de nueva macro en la barra de herramientas de acceso rápido.
• De inmediato, se creará un mismo correo electrónico y se configurará para que se envíe al miembro específico a la hora programada.
• Mientras tanto, el correo electrónico actual se enviará al resto de miembros del grupo de contacto.

Esté atento a todos los riesgos relacionados con su Outlook

En la era contemporánea, los virus y el software espía se están volviendo cada vez más frecuentes. Por lo general, se disfrazan de correos electrónicos inofensivos. Por lo tanto, debe estar atento a varios riesgos relacionados con su Outlook, como los correos electrónicos maliciosos. Debe tener cuidado con los correos electrónicos de contactos desconocidos. Además, para arreglar Outlook tan pronto como su archivo PST sea atacado por malware, debe preparar una herramienta de reparación con experiencia, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo sql dañado y productos de software de reparación de Outlook. Para más información visite www.datanumen.com