Cómo eliminar por lotes archivos adjuntos de elementos de calendario obsoletos en Outlook

Si desea eliminar archivos adjuntos de citas y reuniones obsoletas en Outlook, puede leer este artículo. Aquí le presentaremos cómo realizarlo de una vez.

Para reducir el tamaño de su archivo de Outlook, es muy recomendable limpiar los elementos antiguos. Esto se puede realizar mediante la función incorporada "Autoarchivar", que puede eliminar los elementos antiguos automáticamente a intervalos regulares. Sin embargo, algunos usuarios solo desean eliminar los archivos adjuntos en los elementos antiguos sin afectar los elementos en sí. A continuación, le enseñaremos a eliminar de forma masiva los archivos adjuntos de los elementos del calendario antiguo.

Eliminación por lotes de archivos adjuntos de elementos de calendario obsoletos

1. Para empezar, acceda al editor de Outlook VBA con "Alt + F11".
2. Luego, en la ventana "Microsoft Visual Basic para Aplicaciones", copie el código VBA en un módulo.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Luego, haga clic en la macro "BatchDeleteAttachmentsOfOldCalendarItems".
4. Por último, presione el botón de la tecla "F5" para ejecutar esta macro.
5. Cuando se completa la macro, puede consultar todos sus calendarios de Outlook.
6. Outlook debe haber eliminado todos los archivos adjuntos de los elementos del calendario que tienen más de 2 meses de antigüedad.

Hacer frente a archivos de Outlook corruptos

¿Alguna vez se ha encontrado con la corrupción de Outlook? ¿Cómo lo desechas normalmente? La mayoría de las veces, primero debe probar la herramienta de reparación de la bandeja de entrada: escaneo. Pero, en caso de daños graves en el PST, la utilidad incorporada no puede ayudarlo. Por lo tanto, se sugiere mantener cerca una herramienta de terceros más experimentada y notable, como DataNumen Outlook Repair.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparación de sql y productos de software de reparación de Outlook. Para más información visite www.datanumen.com