Cómo buscar y reemplazar texto por lotes en varios correos electrónicos de Outlook

De forma predeterminada, Outlook no le permite buscar y reemplazar texto en varios correos electrónicos al mismo tiempo. Por tanto, si quieres hacerlo, puedes consultar este artículo. Aquí le enseñaremos cómo realizarlo a través del código VBA.

Por ejemplo, ha terminado varios correos electrónicos en Outlook. Antes de enviarlos, descubre algunos errores y desea modificar algunos textos en estos correos electrónicos. En general, debe realizar "Buscar y reemplazar" en cada correo electrónico uno por uno. Sin embargo, es demasiado engorroso. Por lo tanto, aquí le mostraremos una forma más efectiva, que puede permitirle lograrlo a granel.

Buscar y reemplazar texto por lotes en varios correos electrónicos

1. Para empezar, inicie su programa Outlook.
2. Luego, acceda al editor de VBA a través de las teclas "Alt + F11".
3. En la nueva ventana, coloque el código VBA a continuación en un módulo o proyecto.

Sub FindReplaceInMultipleEmails()
    Dim strFind, strReplace As String
    Dim objInspectors As Outlook.Inspectors
    Dim objInspector As Outlook.Inspector
    Dim objMail As Outlook.MailItem
    Dim objMailDocument As Word.Document
 
    'Enter the specific text
    strFind = InputBox("Enter the text for find: (Case Sensitive)")
    strReplace = InputBox("Enter the text for replacement: (Case Sensitive)")
 
    If Trim(strFind) <> "" Then
       Set objInspectors = Outlook.Application.Inspectors
 
       For Each objInspector In objInspectors
           If objInspector.CurrentItem.Class = olMail Then
              If objInspector.EditorType = olEditorWord Then
                 Set objMail = objInspector.CurrentItem
                 Set objMailDocument = objMail.GetInspector.WordEditor
 
                 'Find & replace specific text
                 With objMailDocument.Content.Find
                      .ClearFormatting
                      .Text = strFind
                      .Replacement.ClearFormatting
                      .Replacement.Text = strReplace
                      .Forward = True
                      .Wrap = wdFindContinue
                      .Format = False
                      .MatchCase = True
                      .MatchWholeWord = False
                      .Execute Replace:=wdReplaceAll
                End With
                objMail.Save
             End If
         End If
      Next
 
      MsgBox "Completed!", vbInformation + vbOKOnly
    End If
End Sub

4. Después de eso, agregue esta macro a la barra de herramientas de acceso rápido de acuerdo con "Cómo ejecutar código VBA en su Outlook".
5. Posteriormente, puede probar esta macro ahora.

• Abra los correos electrónicos de origen.
• Luego, haga clic en el botón de macro en la barra de herramientas de acceso rápido.
• A continuación, debe ingresar los textos específicos para buscar y reemplazar.
• Cuando reciba el mensaje "Completado", puede verificar los correos electrónicos de origen.

Restaurar Outlook de bloqueos inesperados

Outlook puede fallar de vez en cuando si maneja su Outlook de manera incorrecta. Además, por lo general, en caso de una falla grave de Outlook, su archivo de Outlook tiende a estar dañado. En ese momento, debe intentar la recuperación de datos de Outlook. Por supuesto, será considerablemente simple si tiene una copia de seguridad de datos actualizada. Pero si no es así, se le pedirá que aplique una herramienta externa convincente y acreditable, como DataNumen Outlook Repair. Se puede arreglar PST archivo sin sudar.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparación de mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com