3 formas macro de convertir rápidamente sus documentos de Word en PDF Archivos

En este artículo, nos centraremos en proporcionarle 3 macros que puede utilizar para convertir rápidamente documentos de Word en pdf archivos.

En Word 2003, hay un icono en la barra de menú. Con un solo clic, los usuarios pueden activar la ventana "Guardar como" instantáneamente y guardar el documento en pdf formato.

Sin embargo, como puede observar, el diseño en Word 2010 cambia mucho. Y los usuarios deben hacer clic en la pestaña "Archivo" y luego en el comando "Guardar como" para activar la ventana "Guardar como". Además, debe elegir manualmente el tipo de guardado antes de presionar el botón "Guardar".

Con tantos clics, no es lo suficientemente rápido. Por lo tanto, en esta publicación, nos gustaría mostrarles la forma macro de hacerlo.

Macro 1: Active la ventana "Guardar como" rápidamente

1. En primer lugar, haga clic en la pestaña "Desarrollador" y luego en el comando "Visual Basic" para abrir el editor de VBA. Es importante realizar ambos clics cuando la pestaña "Desarrollador" ya esté visible. Otra opción es presionar "Alt + F11".
2. En segundo lugar, haga clic en el proyecto "Normal".
3. En tercer lugar, haga clic en "Insertar" y luego elija "Módulo" en el menú de lista.
4. Ahora haga doble clic en el módulo para mostrar el área de edición.
5. A continuación, pega los siguientes códigos:

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

6. Luego haga clic en "Ejecutar".

Ahora aparece la ventana "Guardar como". El tipo de archivo ya está configurado como PDF. Solo queda hacer clic en el botón "Guardar". Esta macro permite cambiar el nombre del archivo si es necesario.

Macro 2: Guardar directamente archivos de Word como PDF

En caso de que algunas personas quieran guardar el archivo directamente en pdf sin revisar el nombre del archivo, aquí está la macro necesaria.

1. En primer lugar, repita los primeros 4 pasos anteriores.
2. A continuación, pegue los siguientes códigos en su lugar:

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

3. Del mismo modo, haga clic en "Ejecutar".

Macro 3: Convertir por lotes archivos Word Docx a PDF

1. Primero coloque todos los archivos docx en una carpeta.
2. Siga los pasos anteriores para tener abierta el área de edición.
3. Luego pega la siguiente macro:

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Nunca olvide hacer clic en el botón "Ejecutar".

Nota: : En códigos "strFolder = "C: \ Users \ Test \ Desktop \ Test Files \"", el ""C: \ Users \ Test \ Desktop \ Test Files \" " es la ruta del archivo de la carpeta. Recuerde cambiarlo en consecuencia.

Tras ejecutar esta macro, los archivos PDF se guardarán en la misma carpeta donde se encuentran los documentos de Word.

Proteja los archivos lo más que pueda

Existen medidas preventivas y acciones posteriores a un desastre para recuperar archivos dañados. Si realiza copias de seguridad de sus archivos con regularidad, recuperar el archivo original es muy sencillo. La verdad es que pocas personas cumplen con su plan de copias de seguridad, lo que aumenta el riesgo de perder datos valiosos. En tales circunstancias, es hora de recurrir a una solución avanzada. Herramienta de corrección de corrupción de documentos de Word.

Introducción del autor:

Vera Chen es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo corrección de Excel xlsx dañado y pdf reparar productos de software. Para más información visite www.datanumen.com