3 formas rápidas de eliminar filas y columnas en blanco en su tabla de Word

En este post, le explicaremos 3 formas rápidas de eliminar filas y columnas en blanco en su tabla de Word.

Las tablas son esenciales para un documento, especialmente al contener varios tipos de datos. A veces, una tabla larga puede exceder una página y extenderse a varias. Entonces, una vez que una tabla se vuelve larga y complicada, hay medidas que puede tomar para simplificarla. Por ejemplo, puede eliminar filas y columnas en blanco innecesarias.

A continuación se muestran 3 métodos que puede utilizar.

Método 1: eliminar filas y columnas en blanco manualmente

1. En primer lugar, seleccione una fila o columna en blanco.
2. Luego haga clic derecho para obtener el menú contextual. En el menú, seleccione "Eliminar filas" o "Eliminar columnas" según corresponda.

Desafortunadamente, no puede seleccionar varias filas o columnas no consecutivas y eliminarlas junto con esta forma. Para esta demanda, puede consultar nuestro artículo anterior: 5 métodos rápidos para eliminar por lotes varias filas o columnas en su tabla de Word

Método 2: Eliminar por lotes todas las filas y columnas en blanco de una tabla

El método 1 tiene su limitación. Por lo tanto, le ofreceremos la forma de eliminar filas y columnas por lotes en una tabla a través de códigos VBA.

1. Para empezar, coloque el cursor dentro de un tarconseguir mesa.
2. En segundo lugar, active el editor de VBA presionando "Alt + F11".
3. En el editor, primero haga clic en el proyecto "Normal".
4. Luego haga clic en la pestaña "Insertar" en la barra de menú.
5. En el menú desplegable, elija "Módulo".
6. Haga doble clic en el módulo para abrirlo y pegue los siguientes códigos allí:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Finalmente, haga clic en el botón "Ejecutar" en la barra de menú o presione "F5".

En segundos, se eliminarán todas las filas y columnas en blanco de esa tabla.

Método 3: Eliminar por lotes todas las filas y columnas en blanco en todas las tablas de un documento

1. En primer lugar, repita los pasos del método 2 para instalar y ejecutar una macro.
2. Solo que esta vez, reemplace esa macro con lo siguiente:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Recuperar documento roto

Hay más que una forma de recuperar lost datos en la actualidad. Por ejemplo, recurrir a las copias de seguridad siempre sigue siendo su máxima prioridad. Si eso no satisface su necesidad de recuperar la información más reciente, puede probar un reparación de doc .

Introducción del autor:

Vera Chen es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo reparación xlsx y pdf reparar productos de software. Para más información visite www.datanumen.com