2 formas de imprimir las listas de tareas de Outlook con diferentes categorías en diferentes páginas

Si ha asignado varias categorías de color a sus tareas de Outlook y ahora desea imprimir las listas de tareas con diferentes categorías en diferentes páginas, puede consultar este artículo. Aquí te compartiremos 2 métodos para conseguirlo.

Para clasificar y administrar bien sus tareas, quizás haya aplicado categorías de color a sus tareas. Ahora, si desea imprimir las listas de sus tareas con diferentes categorías en diferentes páginas, siga leyendo. A continuación, le presentaremos 2 medios para obtenerlo.

Método 1: imprimir manualmente las listas de tareas una por una

1. En primer lugar, en Outlook, acceda al panel "Tareas".
2. Luego, abra una carpeta de tareas.
3. A continuación, presione "Ctrl + E" para activar la cinta "Buscar".
4. Después de eso, en la pestaña "Buscar", haga clic en el botón "Categorizar".
5. De la lista desplegable, elija una categoría de color.
6. Entonces, solo las tareas con la categoría seleccionada se dejarán en la lista.
7. Ahora, vaya a "Archivo"> ​​"Imprimir" para imprimir esta lista de tareas.
8. Posteriormente, de la misma forma, imprima las listas de tareas con las demás categorías de color una a una de forma manual.

Método 2: Imprima por lotes las listas de tareas por VBA

1. Desde el principio, active el editor de VBA de acuerdo con "Cómo ejecutar código VBA en su Outlook".
2. Luego, agregue la referencia a “Biblioteca de objetos de MS Excel” según “Cómo agregar una referencia a una biblioteca de objetos en VBA".
3. A continuación, copie el siguiente código VBA en un módulo.

Sub PrintTaskList_SpecificColorCategory()
    Dim objTasks As Outlook.Items
    Dim objTask As Outlook.TaskItem
    Dim objDictionary As Object
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim varKey As Variant
    Dim strKey As String
    Dim i As Long
    Dim bSheetFound As Boolean
    Dim nLastRow As Integer
    Dim objSheet As Excel.Worksheet
 
    Set objTasks = Application.Session.GetDefaultFolder(olFolderTasks).Items
    Set objDictionary = CreateObject("Scripting.Dictionary")
 
     'Get All Tasks' Categories
    For Each objTask In objTasks
        arrCategory = Split(objTask.Categories, ",")
        For Each varCategory In arrCategory
            If objDictionary.Exists(Trim(varCategory)) = False Then
               objDictionary.Add Trim(varCategory), 0
            End If
        Next
    Next
 
    'Export the Tasks with Different Categories into Different Sheet in an Excel Workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    objExcelApp.Visible = True
 
    i = 0
    For Each varKey In objDictionary.Keys
        strKey = CStr(varKey)

        On Error Resume Next
        objExcelWorkbook.Sheets(strKey).Select
        bSheetFound = (Err = 0)
        On Error GoTo 0
        If bSheetFound = False Then
           i = i + 1
           If i < 4 Then
              Set objExcelWorksheet = objExcelWorkbook.Sheets(i)
           Else
              Set objExcelWorksheet = objExcelWorkbook.Sheets.Add(After:=objExcelWorkbook.Sheets(objExcelWorkbook.Sheets.Count))
           End If
           objExcelWorksheet.Name = strKey
        End If
 
        With objExcelWorksheet
             .Cells(1, 1) = strKey
             .Cells(1, 1).Font.Bold = True
             .Cells(1, 1).Font.Size = 18
             .Cells(2, 1) = "Subject"
             .Cells(2, 1).Font.Bold = True
             .Cells(2, 2) = "Start Date"
             .Cells(2, 2).Font.Bold = True
             .Cells(2, 3) = "Due Date"
             .Cells(2, 3).Font.Bold = True
        End With
 
        For Each objTask In objTasks
            If InStr(objTask.Categories, strKey) > 0 Then
               nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.Count).End(xlUp).Row + 1
               With objExcelWorksheet
                    .Range("A" & nLastRow) = objTask.Subject
                    .Range("B" & nLastRow) = objTask.startDate
                    .Range("C" & nLastRow) = objTask.DueDate
               End With
            End If
        Next
 
        objExcelWorksheet.Columns("A:C").AutoFit
    Next
 
    'Print out All Sheets in this Excel Workbook
    For Each objSheet In objExcelWorkbook.Sheets
        objSheet.PrintOut
    Next
 
    objExcelWorkbook.Close False
    objExcelApp.Quit
End Sub

4. Luego, presione el botón de la tecla "F5" para ejecutar esta macro de inmediato.
5. Cuando finalice la macro, las listas de tareas con diferentes categorías se imprimirán en diferentes páginas, como se muestra en la siguiente captura de pantalla.

Recupere datos valiosos de un archivo PST comprometido

Si está sujeto a un archivo PST inaccesible, su siguiente paso es, sin duda, Reparación de PST. En este caso, primero puede probar la herramienta de reparación de la bandeja de entrada. Siempre que falle, puede proceder a probar otra herramienta externa, como DataNumen Outlook Repair. Es capaz de recuperar datos PST en poco tiempo.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo recuperar mdf y productos de software de reparación de Outlook. Para más información visite www.datanumen.com