2 formas rápidas de extraer secciones de su documento de Word

En este artículo, le ofreceremos 2 formas rápidas y fáciles de extraer secciones de su documento de Word a otro o varios.

Sucede con bastante frecuencia extraer contenido de un documento a otro. Y en nuestro artículo anterior, hemos discutido cómo extraer páginas de un documento. Para obtener información detallada, puede consultar este artículo: 2 formas rápidas de extraer páginas individuales de su documento de Word

Hoy, le mostraremos cómo extraer por sección.    

Método 1: extraer la sección actual a un documento nuevo

1. En primer lugar, coloque el cursor en un tarobtener la sección.
2. A continuación, presione "Alt + F11" para invocar el editor de VBA en Word.
3. Luego, en la columna de la izquierda, haga clic en "Normal".
4. Y en la barra de menú, haga clic en "Insertar".
5. Luego elija "Módulo" en ese menú desplegable.
6. Haga doble clic para abrir el nuevo módulo y pegue los siguientes códigos allí:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. A continuación, haga clic en "Ejecutar" en la barra de menú o presione "F5".
8. Luego aparecerá la ventana "Examinar". Elija un lugar para almacenar el nuevo documento y haga clic en "Aceptar".
9. Y en el cuadro "Nombre de archivo", introduzca el nombre del nuevo archivo y haga clic en "Aceptar".

Ahora ha extraído la sección a un nuevo documento.

Método 2: extraiga cada sección del documento a nuevas secciones individuales

De esta manera, puede ayudarlo a procesar por lotes todas las secciones de un documento. Por supuesto, también necesitaremos una macro.

1. Para empezar, abre tarobtener documento.
2. Luego, siga los pasos del método 1 para instalar y ejecutar una macro.
3. Solo que esta vez reemplace esa macro con esta:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Aún así, en la ventana "Examinar", elija una ruta de almacenamiento y haga clic en "Aceptar".

Corregir errores de palabras irritantes

Es común encontrar algunos errores de Word al usarlo. Puede ser molesto, debemos tomarnos un tiempo para recuperar palabra tan pronto como sea posible. Porque cuanto más lo demoremos, más grave puede ser la pérdida de datos. Por lo tanto, se sugiere obtener una utilidad de reparación con anticipación.

Introducción del autor:

Vera Chen es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo xls corruptos y pdf reparar productos de software. Para más información visite www.datanumen.com