Cómo adjuntar rápidamente el último archivo modificado en una carpeta de Windows a su correo electrónico de Outlook

A veces, es posible que desee buscar y adjuntar rápidamente el último archivo modificado en una carpeta específica de Windows a un correo electrónico de Outlook. En este caso, puede utilizar el método presentado en este artículo.

Algunos usuarios desean que Outlook detecte rápidamente el último archivo modificado en una carpeta de Windows y lo adjunte a un correo electrónico (por ejemplo, el archivo creado, modificado o guardado más recientemente). Sin embargo, Outlook no ofrece esta función de forma nativa. Por lo tanto, a continuación, mostraremos un fragmento de código VBA que permite lograrlo fácilmente.

Adjunte el último archivo modificado en una carpeta de Windows al correo electrónico

1. Desde el principio, debe iniciar su aplicación Outlook.
2. Luego, después de ingresar a la ventana principal de Outlook, puede presionar los botones de tecla "Alt + F11".
3. A continuación, accederá a la ventana del editor de Outlook VBA con éxito.
4. Posteriormente, debe buscar y abrir un módulo que no se esté utilizando.
5. Y luego copie y pegue el siguiente código VBA en la ventana de este módulo.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Después de eso, puede salir de la ventana del editor de VBA actual y proceder a agregar la nueva macro a la barra de herramientas de acceso rápido o la cinta de la ventana de mensaje.
7. Más tarde, debe cambiar el nivel de seguridad de macros de Outlook a bajo.
8. Eventualmente puedes intentarlo.

• En primer lugar, cree y redacte un nuevo correo electrónico de Outlook como de costumbre.
• Luego presione el botón de macro en la barra de herramientas de acceso rápido, como la imagen a continuación:
• A continuación, se le pedirá que seleccione una carpeta de origen de Windows y presione "Aceptar".
• Si hay un archivo de este tipo en la carpeta de Windows seleccionada, aparecerá un mensaje como la siguiente captura de pantalla:
• Cuando presione "Sí", este archivo se adjuntará de inmediato.

Resuelva los problemas de Outlook lo antes posible

Siempre que encuentre algún problema con Outlook, se recomienda resolverlo lo antes posible. En esta situación, será mejor que prepare un Corrección de Outlook herramienta de antemano, como DataNumen Outlook Repair. Es capaz de corregir errores de PST y rescatar sus datos de Outlook de manera efectiva.

Introducción del autor:

Shirley Zhang es experta en recuperación de datos en DataNumen, Inc., que es el líder mundial en tecnologías de recuperación de datos, incluyendo mdf dañado y productos de software de reparación de Outlook. Para más información visite www.datanumen.com