Πώς να αποκλείσετε γρήγορα τους αρχικούς παραλήπτες "CC" όταν χρησιμοποιείτε το "Reply All" στο Outlook

Όταν χρησιμοποιείτε το "Απάντηση σε όλους", το μήνυμα ηλεκτρονικού ταχυδρομείου που απαντά θα περιλαμβάνει επίσης τους παραλήπτες "CC" του αρχικού email στο πεδίο "CC". Ωστόσο, εάν θέλετε να εξαιρέσετε αυτόν τον τύπο παραλήπτη, μπορείτε να χρησιμοποιήσετε τη μέθοδο που παρουσιάζεται σε αυτό το άρθρο.

Κατά καιρούς, θέλετε να απαντήσετε ένα μήνυμα ηλεκτρονικού ταχυδρομείου στον αρχικό αποστολέα και στους παραλήπτες "Προς". Σε αυτό το σενάριο, σίγουρα θα σκεφτείτε να χρησιμοποιήσετε την επιλογή "Απάντηση σε όλους". Ωστόσο, με αυτόν τον τρόπο, εάν το αρχικό μήνυμα έχει επίσης παραλήπτες "CC", το μήνυμα "Απάντηση σε όλους" θα αντιγράψει αυτόματα τους παραλήπτες "CC" στο πεδίο "CC". Εάν δεν θέλετε να τους απαντήσετε, πρέπει να τα αφαιρέσετε χειροκίνητα, κάτι που είναι λίγο ενοχλητικό. Τώρα, στα ακόλουθα, θα σας διδάξουμε πώς να αφήσετε το Outlook να το πραγματοποιήσει αυτόματα σύμφωνα με τις ανάγκες σας.

Γρήγορη εξαίρεση των αρχικών παραληπτών "CC" όταν χρησιμοποιείτε το "Reply All"

1. Για αρχή, ξεκινήστε το Outlook.
2. Στη συνέχεια, αποκτήστε πρόσβαση στον επεξεργαστή VBA διαβάζοντας το προηγούμενο άρθρο - "Τρόπος εκτέλεσης κώδικα VBA στο Outlook".
3. Στη συνέχεια, αντιγράψτε τον ακόλουθο κώδικα VBA στο έργο "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objExplorer_Activate()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

'Occurs when you click "Reply All"
Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objRecipient As Outlook.Recipient
    Dim i As Long
 
    'Ask you if to exclude CC recipients
    If MsgBox("Do you want to exclude original CC recipients? " , vbQuestion + vbYesNo) = vbYes Then
       'If select Yes, remove CC recipients
       For i = Response.Recipients.Count To 1 Step -1
           If Response.Recipients(i).Type = olCC Then
              Response.Recipients.Remove (i)
           End If
       Next
    End If
End Sub

4. Στη συνέχεια, επανεκκινήστε το Outlook για να ενεργοποιήσετε αυτό το νέο έργο.
5. Από τότε, κάθε φορά που πατάτε το κουμπί "Απάντηση σε όλους", θα λαμβάνετε ένα μήνυμα, όπως φαίνεται στην παρακάτω εικόνα, που θα σας ρωτά εάν θέλετε να εξαιρέσετε τους αρχικούς παραλήπτες CC.
6. Εάν επιλέξετε «Ναι», το Outlook θα αφαιρέσει αυτόματα τους παραλήπτες στο πεδίο «CC».

Μείνετε καλά προετοιμασμένοι για ζημιές στο Outlook

Όπως όλοι γνωρίζουμε, κανείς δεν μπορεί να διασφαλίσει 100% ότι θα είναι άτρωτος από ζημιές στο Outlook. Ως εκ τούτου, είναι σημαντικό όλοι οι τακτικοί χρήστες του Outlook να λάβουν πολλές προφυλάξεις. Πρώτα απ 'όλα, μία από τις πιο σημαντικές είναι η διατήρηση ενός σταθερού και ενημερωμένου αντιγράφου ασφαλείας των δεδομένων του Outlook. Στη συνέχεια, είναι απαραίτητο να μάθετε πώς να χρησιμοποιείτε το εργαλείο επιδιόρθωσης εισερχομένων. Τέλος, είναι συνετό και συνιστάται να διατηρείτε έναν έμπειρο χρήστη. Επιδιόρθωση του Outlook εργαλείο κοντά, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων ανάκτηση mdf και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com