Τρόπος αυτόματης χρήσης διαφορετικών χρωμάτων γραμματοσειρών για απάντηση και προώθηση μηνυμάτων ηλεκτρονικού ταχυδρομείου με το Outlook VBA

Λύσεις του Outlook Σεπτέμβριος 29, 2025

Από προεπιλογή, δεν μπορείτε να επιτρέψετε στο Outlook να χρησιμοποιεί αυτόματα διαφορετικά χρώματα γραμματοσειράς για την απάντηση και την προώθηση μηνυμάτων ηλεκτρονικού ταχυδρομείου. Επομένως, εάν έχετε μια τέτοια απαίτηση, μπορείτε να διαβάσετε αυτήν τη σελost για να μάθετε μια έξυπνη προσέγγιση.

Το Outlook σάς επιτρέπει μόνο να καθορίσετε μια γραμματοσειρά που χρησιμοποιείται τόσο για την απάντηση όσο και για την προώθηση μηνυμάτων ηλεκτρονικού ταχυδρομείου. Μπορείτε να μεταβείτε στο «Αρχείο» > «Επιλογές». Στη συνέχεια, στις «Επιλογές του Outlook», μεταβείτε στην καρτέλα «Αλληλογραφία» και κάντε κλικ στο κουμπί «Χαρτικά και γραμματοσειρές…». Στο επόμενο παράθυρο, μπορείτε να δείτε το κουμπί "Γραμματοσειρά" στην ενότητα "Απάντηση ή προώθηση μηνυμάτων". Κάντε κλικ σε αυτό και, στη συνέχεια, μπορείτε να ορίσετε ένα συγκεκριμένο χρώμα γραμματοσειράς για την απάντηση και την προώθηση email.

Ωστόσο, πολλοί χρήστες ελπίζουν να χρησιμοποιούν διαφορετικά χρώματα γραμματοσειράς για την απάντηση ή την προώθηση email. Αν και το Outlook δεν παρέχει άμεσες δυνατότητες για αυτό, εξακολουθεί να μπορεί να πραγματοποιηθεί με κώδικα VBA. Τώρα, διαβάστε για να λάβετε ένα τέτοιο κομμάτι κώδικα VBA.

Αυτόματη χρήση διαφορετικών χρωμάτων γραμματοσειράς για απάντηση και προώθηση email

Για ωςtart, ξεκινήστε την εφαρμογή Outlook.
Στη συνέχεια, ενεργοποιήστε το πρόγραμμα επεξεργασίας VBA με αναφορά στο "Τρόπος εκτέλεσης κώδικα VBA στο Outlook".
Στη συνέχεια, σύμφωνα με το «Πώς να προσθέσετε ένα αντικείμενο Library Αναφορά στο VBA", προσθέστε την αναφορά στο "MS Word Object Librarγ ».
Στη συνέχεια, αντιγράψτε τον παρακάτω κώδικα στο έργο "ThisOutlookSession".

Public WithEvents objInspectors As Outlook.Inspectors
Public WithEvents objExplorer As Outlook.Explorer
Public WithEvents objMail As Outlook.MailItem

Private Sub Application_Startup()
    Set objInspectors = Outlook.Application.Inspectors
    Set objExplorer = Outlook.Application.ActiveExplorer
End Sub

Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
    If TypeOf Inspector.CurrentItem Is MailItem Then
       Set objMail = Inspector.CurrentItem
    End If
End Sub

Private Sub objExplorer_SelectionChange()
    On Error Resume Next
    If TypeOf objExplorer.Selection.Item(1) Is MailItem Then
       Set objMail = objExplorer.Selection.Item(1)
    End If
End Sub

Private Sub objMail_Reply(ByVal Response As Object, Cancel As Boolean)
    Dim objReply As Outlook.MailItem
    Dim objReplyDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReply = objMail.Reply
    objReply.Display
    Set objReplyDoc = objReply.GetInspector.WordEditor
    objReplyDoc.Range(0, 0).Select
    Set objDocSelection = objReplyDoc.Application.Selection
    'Use "Pink" font in "Reply"
    objDocSelection.Font.ColorIndex = wdPink
End Sub

Private Sub objMail_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Dim objReplyAll As Outlook.MailItem
    Dim objReplyAllDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objReplyAll = objMail.ReplyAll
    objReplyAll.Display
    Set objReplyAllDoc = objReplyAll.GetInspector.WordEditor
    objReplyAllDoc.Range(0, 0).Select
    Set objDocSelection = objReplyAllDoc.Application.Selection
    'Use "Green" font in "Reply All"
    objDocSelection.Font.ColorIndex = wdGreen
End Sub

Private Sub objMail_Forward(ByVal Forward As Object, Cancel As Boolean)
    Dim objForward As Outlook.MailItem
    Dim objForwardDoc As Word.Document
    Dim objDocSelection As Word.Selection
 
    Cancel = True
    Set objForward = objMail.Forward
    objForward.Display
    Set objForwardDoc = objForward.GetInspector.WordEditor
    objForwardDoc.Range(0, 0).Select
    Set objDocSelection = objForwardDoc.Application.Selection
    'Use "Blue" font in Forward
    objDocSelection.Font.ColorIndex = wdBlue
End Sub

Μετά από αυτό, restart Outlook για να ενεργοποιήσετε αυτήν τη μακροεντολή.
Τέλος, μπορείτε να δοκιμάσετε.

Επιλέξτε ή ανοίξτε ένα email.
Στη συνέχεια, κάντε κλικ στο κουμπί «Απάντηση». Κατά την απάντηση email, μπορείτε να πληκτρολογήσετε μερικές λέξεις στο σώμα. Το χρώμα της γραμματοσειράς πρέπει να είναι ροζ.
Ή κάντε κλικ στο κουμπί "Απάντηση σε όλους". Στη νέα αλληλογραφία "απαντώντας σε όλα", εισαγάγετε λέξεις στο σώμα. Το χρώμα της γραμματοσειράς είναι σίγουρα πράσινο.
Ομοίως, κάντε κλικ στο κουμπί "Προώθηση". Στην αποστολή αλληλογραφίας, οι νέες λέξεις θα εμφανίζονται με μπλε χρώμα.

Καταφύγετε σε αξιόπιστο λογισμικό

Σε περίπτωση Διαφθορά στο Outlook, Most Οι χρήστες τείνουν να καταφεύγουν στο λογισμικό αποκατάστασης του Outlook. Υπάρχουν πολλά τέτοια προγράμματα διαθέσιμα στην αγορά. Και μερικά από αυτά είναι ακόμη και δωρεάν. Ωστόσο, θα πρέπει να προσέχετε όσους προέρχονται από άγνωστες πηγές, καθώς μπορεί να κάνουν την τρέχουσα υπόθεση χειρότερη και χειρότερη. Θα πρέπει να λάβετε βοήθεια από ένα αξιόπιστο και έμπειρο εργαλείο, όπως DataNumen Outlook Repair.

Εισαγωγή συγγραφέα:

Η Shirley Zhang είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένο sql και προϊόντα λογισμικού επισκευής προοπτικών. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com