3 τρόποι μακροεντολής για γρήγορη μετατροπή των εγγράφων του Word σε PDF Αρχεία

Σε αυτό το άρθρο, θα επικεντρωθούμε στην παροχή 3 μακροεντολών στις οποίες μπορείτε να χρησιμοποιήσετε για να μετατρέψετε γρήγορα τα έγγραφα του Word σε pdf αρχεία.

Στο Word 2003, υπάρχει ένα εικονίδιο στη γραμμή μενού. Με ένα μόνο κλικ, οι χρήστες μπορούν να ενεργοποιήσουν το παράθυρο "Αποθήκευση ως" αμέσως και να αποθηκεύσουν το έγγραφο pdf μορφή.

Ωστόσο, όπως παρατηρείτε, η διάταξη του Word 2010 αλλάζει πολύ. Και οι χρήστες πρέπει να κάνουν κλικ στην καρτέλα "Αρχείο" και στη συνέχεια στην εντολή "Αποθήκευση ως" για να ενεργοποιήσουν το παράθυρο "Αποθήκευση ως". Επιπλέον, πρέπει να επιλέξετε χειροκίνητα τον τύπο αποθήκευσης πριν πατήσετε το κουμπί "Αποθήκευση".

Με όλα αυτά τα κλικ, δεν είναι αρκετά γρήγορο. Επομένως, σε αυτήν την ανάρτηση, θα θέλαμε να παρουσιάσουμε τον μακροοικονομικό τρόπο για να το κάνουμε αυτό.

Μακροεντολή 1: Ενεργοποιήστε το παράθυρο "Αποθήκευση ως" γρήγορα

1. Πρώτα απ 'όλα, κάντε κλικ στην καρτέλα "Προγραμματιστής" και, στη συνέχεια, κάντε κλικ στην εντολή "Visual Basic" για να ανοίξετε τον επεξεργαστή VBA. Βέβαια, τα 2 κλικ πρέπει να γίνουν όταν εμφανίζεται ήδη η καρτέλα "Προγραμματιστής". Ο εναλλακτικός τρόπος είναι να πατήσετε "Alt+ F11".
2. Δεύτερον, κάντε κλικ στο "Κανονικό" έργο.
3. Τρίτον, κάντε κλικ στο «Εισαγωγή» και μετά επιλέξτε «Ενότητα» στο μενού λίστας
4. Τώρα κάντε διπλό κλικ στην ενότητα για να εμφανιστεί η περιοχή επεξεργασίας.
5. Στη συνέχεια, επικολλήστε τους ακόλουθους κωδικούς:

Sub TriggerSaveAsWindow()
  Dim dlgSaveAs As Dialog
 
  Set dlgSaveAs = Dialogs(wdDialogFileSaveAs)
  With dlgSaveAs
    .Format = wdFormatPDF
    .Show
    .Execute
  End With
End Sub

6. Στη συνέχεια κάντε κλικ στο "Εκτέλεση".

Τώρα υπάρχει το παράθυρο «Αποθήκευση ως». Και ο τύπος αποθήκευσης είναι ήδη σε μορφή pdf. Το μόνο που μένει να κάνετε είναι να κάνετε κλικ στο κουμπί «Αποθήκευση». Αυτή η μακροεντολή σάς επιτρέπει να αλλάξετε το όνομα του αρχείου, εάν είναι απαραίτητο.

Μακροεντολή 2: Άμεση αποθήκευση αρχείων Word σε PDF

Σε περίπτωση που κάποια άτομα θέλουν να αποθηκεύσουν το αρχείο απευθείας στο pdf χωρίς αναθεώρηση του ονόματος αρχείου, εδώ είναι η μακροεντολή που χρειάζεται.

1. Πρώτα απ 'όλα, επαναλάβετε τα πρώτα 4 βήματα παραπάνω.
2. Στη συνέχεια, επικολλήστε τους ακόλουθους κωδικούς αντ 'αυτού:

'Directly save Word file as Pdf and aumatically open it.
Sub DirectlySaveDocxToPdf()
  Dim objDoc As Document
 
  Set objDoc = ActiveDocument
  objDoc.ExportAsFixedFormat _
    OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
    ExportFormat:=wdExportFormatPDF, OpenAfterExport:=True, OptimizeFor:=wdExportOptimizeForPrint, _
    Range:=wdExportAllDocument, Item:=wdExportDocumentContent
End Sub

3. Ομοίως, κάντε κλικ στο "Εκτέλεση".

Μακροεντολή 3: Μαζική μετατροπή αρχείων Word Docx σε PDF

1. Τοποθετήστε πρώτα όλα τα αρχεία docx σε έναν φάκελο.
2. Ακολουθήστε τα παραπάνω βήματα για να ανοίξετε την περιοχή επεξεργασίας.
3. Στη συνέχεια επικολλήστε την παρακάτω μακροεντολή:

Sub BatchConvertDocxToPDF()
  Dim objDoc As Document
  Dim strFile As String, strFolder As String
 
  'Initialization
  strFolder = "C:\Users\Test\Desktop\Test Files\"
  strFile = Dir(strFolder & "*.docx", vbNormal)
 
  'Precess each file in the file folder and convert them to pdf.
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=strFolder & strFile)
 
    objDoc.ExportAsFixedFormat _
      OutputFileName:=Replace(objDoc.FullName, ".docx", ".pdf"), _
      ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False, OptimizeFor:=wdExportOptimizeForPrint, _
      Range:=wdExportAllDocument, Item:=wdExportDocumentContent
 
    objDoc.Close
    strFile = Dir()
  Wend
End Sub

4. Μην ξεχάσετε ποτέ να κάνετε κλικ στο κουμπί "Εκτέλεση".

Σημείωση: Σε κωδικούς "strFolder = "C: \ Users \ Test \ Desktop \ Test Files \"", ο ""C: \ Users \ Test \ Desktop \ Test Files \" " είναι η διαδρομή αρχείου του φακέλου. Θυμηθείτε να το αλλάξετε ανάλογα.

Μετά την εκτέλεση αυτής της μακροεντολής, τα αρχεία pdf θα αποθηκευτούν στον ίδιο φάκελο όπου βρίσκονται τα έγγραφα του Word.

Ασφαλή αρχεία όσο μπορείτε

Υπάρχουν προληπτικά μέτρα, αλλά και ενέργειες μετά από καταστροφές, για την ανάκτηση κατεστραμμένων αρχείων. Εάν συνεχίζετε να δημιουργείτε αντίγραφα ασφαλείας των αρχείων σας σε τακτική βάση, η ανάκτηση του αρχικού αρχείου είναι παιχνιδάκι. Η αλήθεια είναι ότι λίγοι άνθρωποι μπορούν να τηρήσουν το σχέδιο δημιουργίας αντιγράφων ασφαλείας τους, αυξάνοντας έτσι τον κίνδυνο απώλειας πολύτιμων δεδομένων. Υπό αυτές τις συνθήκες, ήρθε η ώρα να καταφύγετε σε μια προηγμένη λύση. Εργαλείο διόρθωσης διαφθοράς στο Word.

Εισαγωγή συγγραφέα:

Η Vera Chen είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένη επιδιόρθωση Excel xlsx και pdf επισκευή προϊόντων λογισμικού. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com