2 τρόποι για γρήγορη συγχώνευση πολλαπλών εγγράφων Word σε ένα μέσω VBA

Σε αυτό το άρθρο, είμαστε στην ευχάριστη θέση να μοιραστούμε μαζί σας 2 τρόπους για γρήγορη συγχώνευση πολλαπλών εγγράφων του Word σε ένα μέσω VBA.

Στο Word, υπάρχει η προεπιλεγμένη ενσωματωμένη δυνατότητα που βοηθά τον χρήστη να συνδυάσει ή να συγχωνεύσει πολλά έγγραφα σε ένα. Οι λεπτομέρειες εξηγούνται σε αυτό το άρθρο: Τρόπος συνδυασμού και συγχώνευσης πολλών εγγράφων Word σε ένα

Με αυτήν τη μέθοδο, πρέπει να κάνετε μερικά κλικ και τα περιεχόμενα του επόμενου εγγράφου έρχονται πάντα αμέσως μετά από αυτά του προηγούμενου. Επομένως, θέλουμε να σας προσφέρουμε πιο γρήγορους τρόπους για να το κάνετε αυτό.

Μέθοδος 1: Συγχώνευση επιλεγμένων εγγράφων σε ένα

1. Πρώτα και κύρια, δημιουργήστε ένα νέο κενό έγγραφο.
2. Ενεργοποιήστε τον επεξεργαστή VBA στο Word πατώντας "Alt+ F11".
3. Στη συνέχεια κάντε κλικ στο "Normal".
4. Στη συνέχεια, κάντε κλικ στο «Εισαγωγή».
5. Και επιλέξτε "Ενότητα".
6. Κάντε διπλό κλικ στη νέα μονάδα για να ανοίξετε τον χώρο επεξεργασίας.
7. Επικολλήστε την ακόλουθη μακροεντολή εκεί:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Στη συνέχεια κάντε κλικ στο "Εκτέλεση" ή πατήστε "F5".
9. Τώρα στο παράθυρο "Αναζήτηση", επιλέξτε πολλά αρχεία πατώντας "Ctrl" και κάντε κλικ στο "OK".
10. Στη συνέχεια, όλα τα περιεχόμενα των επιλεγμένων αρχείων θα ενωθούν στο νέο έγγραφο, με τα κείμενα κάθε εγγράφου να ξεκινούν σε μια νέα σελίδα.

Σημείωση:

Όπως αναφέραμε, αυτή η μακροεντολή τοποθετεί τα κείμενα κάθε εγγράφου σε μια νέα σελίδα. Αλλά αν θέλετε να είναι το ένα μετά το άλλο, μπορείτε να αλλάξετε ορισμένες γραμμές κώδικα στη μακροεντολή. Απλώς βρείτε τη γραμμή "If nEachSelectedFile < nTotalFiles Τότε", τη διαγράψτε και τις επόμενες έξι γραμμές επίσης.

Μέθοδος 2: Συγχώνευση όλων των εγγράφων σε έναν φάκελο σε ένα

Σε περίπτωση που έχετε έναν φάκελο με αρχεία προς συνδυασμό, τότε αυτή η μακροεντολή θα λειτουργήσει όμορφα.

1. Για να ξεκινήσετε, εγκαταστήστε και εκτελέστε τη μακροεντολή όπως περιγράφεται στη μέθοδο 1.
2. Στη συνέχεια, αντικαταστήστε τη μακροεντολή με αυτήν:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Εκτελέστε τη μακροεντολή κάνοντας κλικ στο "Εκτέλεση".
4. Στη συνέχεια βλέπετε ανοιχτό το παράθυρο "Αναζήτηση". Επιλέξτε το φάκελο όπου αποθηκεύετε όλα τα έγγραφα. Και κάντε κλικ στο "OK".

Ομοίως, τα κείμενα κάθε εγγράφου ξεκινούν σε μια νέα σελίδα. Για να τα κάνετε να κολλάνε το ένα μετά το άλλο, βρείτε και διαγράψτε τη γραμμή κώδικα ".InsertBreak Type:=wdPageBreak".

Προστατέψτε σωστά το έγγραφο του Word

Ένας από τους καλύτερους τρόπους προστασίας των εγγράφων του Word είναι να δημιουργείτε αντίγραφα ασφαλείας σε τακτική βάση. Με τα αντίγραφα ασφαλείας στο χέρι, δεν θα χρειαστεί ποτέ να φοβάστε την απώλεια δεδομένων. Επιπλέον, είναι επίσης σκόπιμο να πάρετε ένα εργαλείο για να επισκευή docx εάν κάποιο από αυτά καταστραφεί.

Εισαγωγή συγγραφέα:

Η Vera Chen είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένο Excel και pdf επισκευή προϊόντων λογισμικού. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com