2 γρήγοροι τρόποι εξαγωγής ενοτήτων από το έγγραφο του Word

Σε αυτό το άρθρο, θα σας προσφέρουμε 2 γρήγορους και εύκολους τρόπους εξαγωγής τμημάτων από το έγγραφο του Word σε ένα ή περισσότερα.

Συμβαίνει αρκετά συχνά να εξαγάγετε περιεχόμενο από ένα έγγραφο σε άλλο. Και στο προηγούμενο άρθρο μας, συζητήσαμε πώς να εξαγάγουμε σελίδες από έγγραφο. Για λεπτομερείς πληροφορίες, μπορείτε να ανατρέξετε σε αυτό το άρθρο: 2 γρήγοροι τρόποι εξαγωγής μεμονωμένων σελίδων από το έγγραφο του Word

Σήμερα, θα σας δείξουμε πώς να εξαγάγετε κατά ενότητα.    

Μέθοδος 1: Εξαγωγή τρέχουσας ενότητας σε νέο έγγραφο

1. Πρώτα απ 'όλα, τοποθετήστε τον κέρσορα σε μια ενότητα-στόχο.
2. Στη συνέχεια, πατήστε "Alt + F11" για να καλέσετε τον επεξεργαστή VBA στο Word.
3. Στη συνέχεια, στην αριστερή στήλη, κάντε κλικ στο "Normal".
4. Και στη γραμμή μενού, κάντε κλικ στο «Εισαγωγή».
5. Στη συνέχεια, επιλέξτε "Module" σε αυτό το αναπτυσσόμενο μενού.
6. Κάντε διπλό κλικ για να ανοίξετε τη νέα ενότητα και επικολλήστε τους ακόλουθους κωδικούς εκεί:

Sub SaveCurrentSectionAsNewDoc()
  Dim strFolder As String
  Dim dlgFile As FileDialog
  Dim strNewFileName As String
  Dim objDocAdded As Document
  Dim objDoc As Document
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  ' Pick a place to store the new file.
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  strNewFileName = InputBox("Enter new file name here: ", "File Name")
 
  ' Select and copy current section range.
  objDoc.Bookmarks("\Section").Range.Select
  Selection.Copy
 
  ' Open a new document to paste the above selection.
  Set objDocAdded = Documents.Add
  Selection.Paste
 
  ' Save and close the new document.
  objDocAdded.SaveAs FileName:=strFolder & strNewFileName & ".docx"
  objDocAdded.Close
End Sub

7. Στη συνέχεια, κάντε κλικ στο "Εκτέλεση" στη γραμμή μενού ή πατήστε "F5".
8. Τότε θα εμφανιστεί το παράθυρο «Αναζήτηση». Επιλέξτε ένα μέρος για να αποθηκεύσετε το νέο έγγραφο και κάντε κλικ στο "OK".
9. Και στο πλαίσιο "Όνομα αρχείου", εισαγάγετε το όνομα για νέο αρχείο και κάντε κλικ στο "OK".

Τώρα έχετε εξαγάγει την ενότητα σε ένα νέο έγγραφο.

Μέθοδος 2: Εξαγωγή κάθε ενότητας στο έγγραφο σε μεμονωμένους νέους

Αυτός ο τρόπος μπορεί να σας βοηθήσει να επεξεργαστείτε μαζικά όλες τις ενότητες σε ένα έγγραφο. Φυσικά, θα χρειαστούμε και μια μακροεντολή.

1. Αρχικά, ανοίξτε το έγγραφο προορισμού.
2. Στη συνέχεια, ακολουθήστε τα βήματα στη μέθοδο 1 για να εγκαταστήσετε και να εκτελέσετε μια μακροεντολή.
3. Μόνο αυτή τη φορά αντικαταστήστε αυτήν τη μακροεντολή με αυτήν:

Sub SaveEachSectionAsADoc()
  Dim objDocAdded As Document
  Dim objDoc As Document
  Dim nSectionNum As Integer
  Dim strFolder As String

  Dim dlgFile As FileDialog
 
  ' Initialization
  Set objDoc = ActiveDocument
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  ' Pick a location to keep new files.
  With dlgFile
    If .Show = -1 Then
      strFolder = .SelectedItems(1) & "\"
    Else
      MsgBox "Select a folder first!"
      Exit Sub
    End If
  End With
 
  ' Step through each section in current document, copy and paste each to a new one.
  For nSectionNum = 1 To ActiveDocument.Sections.Count
    Selection.GoTo What:=wdGoToSection, Which:=wdGoToNext, Name:=nSectionNum
    ActiveDocument.Sections(nSectionNum).Range.Copy
 
    Set objDocAdded = Documents.Add
    Selection.Paste
 
    ' Save and close new documents.
    objDocAdded.SaveAs FileName:=strFolder & "Section " & nSectionNum & ".docx"
    objDocAdded.Close
  Next nSectionNum
End Sub

4. Ωστόσο, στο παράθυρο "Αναζήτηση", επιλέξτε μια διαδρομή αποθήκευσης και κάντε κλικ στο "OK".

Διορθώστε τα ερεθιστικά σφάλματα του Word

Είναι συνηθισμένο να συναντήσετε ορισμένα σφάλματα του Word κατά τη χρήση του. Μπορεί να είναι ενοχλητικό, πρέπει να αφιερώσουμε χρόνο ανακτήστε τη λέξη όσο το δυνατόν συντομότερα. Επειδή όσο το καθυστερούμε, τόσο μεγαλύτερη είναι η απώλεια δεδομένων. Επομένως, προτείνεται να αποκτήσετε εκ των προτέρων ένα βοηθητικό πρόγραμμα επιδιόρθωσης.

Εισαγωγή συγγραφέα:

Η Vera Chen είναι ειδικός ανάκτησης δεδομένων στο DataNumen, Inc., η οποία είναι ο παγκόσμιος ηγέτης στις τεχνολογίες ανάκτησης δεδομένων, συμπεριλαμβανομένων κατεστραμμένο xls και pdf επισκευή προϊόντων λογισμικού. Για περισσότερες πληροφορίες επισκεφθείτε www.datanumen.com