Kako brzo izvesti ukupno vrijeme provedeno na Outlook terminima u svakoj kategoriji boja

Ako želite da kreirate izveštaj o ukupnom vremenu koje ste potrošili na sastanke u svakoj kategoriji boja, možete koristiti metodu predstavljenu u ovom članku. Može vam pomoći da to postignete u kratkom vremenu bez potrebe da ručno brojite.

Mnogi korisnici su navikli da većinu svojih aktivnosti zapisuju u Outlook kalendar. Također, kako bi ih lakše upravljali i razlikovali, svakoj od njih dodjeljuju kategorije. U tom slučaju, neki korisnici žele generirati izvještaj koji prikazuje ukupno vrijeme provedeno na stavkama kalendara u svakoj kategoriji boja. Nema sumnje da je teško brojati i unositi podatke ručno. Stoga ćemo ovdje podijeliti način na koji se ovaj zadatak može obaviti jednostavnim klikom.

Izvezi ukupno vrijeme provedeno na sastancima u svakoj kategoriji boja

1. Prvo pokrenite svoju Outlook aplikaciju.
2. Zatim, nakon ulaska u Outlook prozor, možete dodirnuti tipke “Alt + F11”.
3. Nakon toga, dobićete pristup prozoru „Microsoft Visual Basic za aplikacije“.
4. Zatim ćete morati omogućiti "Microsoft Excel Object Library". Možete kliknuti na "Alati" > "Referenca" da biste to učinili.
5. Zatim biste trebali pronaći i otvoriti modul koji nije u upotrebi.
6. Nakon toga, morate kopirati sljedeći VBA kod u ovaj modul.

Sub ExportTimeSpentOnAppointmentsInEachColorCategory()
    Dim objDictionary As Object
    Dim objAppointments As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim strCategory As String
    Dim arrCategory As Variant
    Dim varCategory As Variant
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkbook As Excel.Workbook
    Dim objExcelWorksheet As Excel.Worksheet
    Dim arrKey As Variant
    Dim arrItem As Variant
    Dim i As Long
    Dim nLastRow As Integer
 
    Set objDictionary = CreateObject("Scripting.Dictionary")
    Set objAppointments = Application.Session.PickFolder.Items
  
    For Each objAppointment In objAppointments
        arrCategory = Split(objAppointment.Categories, ",")
        For Each varCategory In arrCategory
            strCategory = Trim(varCategory)
            If objDictionary.Exists(strCategory) Then
               objDictionary.Item(strCategory) = objDictionary.Item(strCategory) + objAppointment.Duration
            Else
               objDictionary.Add strCategory, objAppointment.Duration
            End If
        Next
    Next
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkbook = objExcelApp.Workbooks.Add
    Set objExcelWorksheet = objExcelWorkbook.Sheets(1)
    objExcelApp.Visible = True
    objExcelWorkbook.Activate
 
    With objExcelWorksheet
         .Cells(1, 1) = "Color Category"
         .Cells(1, 1).Font.Bold = True
         .Cells(1, 1).Font.Size = 14
         .Cells(1, 2) = "Total Time (min)"
         .Cells(1, 2).Font.Bold = True
         .Cells(1, 2).Font.Size = 14
    End With
 
    arrKey = objDictionary.Keys
    arrItem = objDictionary.Items
 
    For i = LBound(arrKey) To UBound(arrKey)
        nLastRow = objExcelWorksheet.Range("A" & objExcelWorksheet.Rows.count).End(xlUp).Row + 1
 
        objExcelWorksheet.Cells(nLastRow, 1) = arrKey(i)
        objExcelWorksheet.Cells(nLastRow, 2) = arrItem(i)
    Next

    objExcelWorksheet.Columns("A:B").AutoFit
End Sub

7. Konačno možete pokrenuti ovaj makro, bez obzira na to klikom na ikonu “Run” na traci s alatima ili pritiskom na tipku “F5”.
8. Zatim će se od vas tražiti da odaberete određeni kalendar.
9. Nakon što odaberete i pritisnete “OK”, makro će nastaviti da radi. Nakon što završi, pojavit će se nova Excel datoteka koja se prikazuje u pozadini.
10. Možete mu pristupiti. To će izgledati kao na sljedećem snimku ekrana:

Pazite na potencijalne prijetnje oko vašeg Outlooka

Korisnici Outlooka trebali bi paziti na sve potencijalne rizike, uključujući nepoznate priloge e-pošte, ugrađene veze i ljudske greške. U suprotnom, vaš Outlook se može oštetiti u bilo kojem trenutku. Takođe, neophodno je napraviti redovne rezervne kopije podataka u Outlook-u i držanje specijalizovanog alata za popravku. DataNumen Outlook Repair je jedan od najpreporučljivijih alata za popravke. Može popraviti Outlook problemi za tren.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com