Kako brzo izvesti detalje svih članova u Outlook grupi kontakata u Excel

Podrazumevano, možete vidjeti samo imena članova i adrese e-pošte u grupi kontakata. Ako želite da dobijete ostale podatke o članovima, možete koristiti način predstavljen u ovom članku.

Kada dvaput kliknete na grupu kontakata da biste je otvorili, u njenom prozoru možete vidjeti samo imena članova grupe i adrese e-pošte. Ne možete dobiti ostale podatke o članovima, kao što su kompanija, naziv radnog mjesta, broj telefona ili poslovna adresa, itd. Općenito, da biste dobili ove detalje, morate ručno pronaći kontakte koji odgovaraju članovima u vašem folderu Kontakti. Previše je problematično. Ovdje ćemo vam pokazati dio VBA koda, koji može brzo izvesti ove detalje u Excel radnu knjigu.

Izvezite detalje svih članova u kontakt grupi u Excel

1. Za početak, pokrenite Outlook aplikaciju.
2. Zatim trebate pritisnuti tipke “Alt + F11” u glavnom prozoru programa Outlook.
3. Zatim u novom prozoru „Microsoft Visual Basic za aplikacije“, morate otvoriti modul koji nije u upotrebi ili direktno umetnuti novi modul.
4. Nakon toga, kopirajte i zalijepite sljedeći VBA kod u ovaj modul.

Sub ExportMemberContactDetailsToExcel()
    Dim objContactGroup As Outlook.DistListItem
    Dim objGroupMember As Outlook.recipient
    Dim objContacts As Outlook.Items
    Dim objFoundContact As Outlook.ContactItem
    Dim objExcelApp As Excel.Application
    Dim objExcelWorkBook As Excel.Workbook
    Dim objExcelWorkSheet As Excel.Worksheet
    Dim i As Integer
    Dim nRow As Integer
    Dim strFilename As String
 
    Set objContactGroup = Application.ActiveExplorer.Selection(1)
 
    'Create a new Excel workbook
    Set objExcelApp = CreateObject("Excel.Application")
    Set objExcelWorkBook = objExcelApp.Workbooks.Add
    Set objExcelWorkSheet = objExcelWorkBook.Worksheets(1)
 
    'Set the seven column headers
    With objExcelWorkSheet
         .Cells(1, 1) = "Name"
         .Cells(1, 2) = "Email Address"
         .Cells(1, 3) = "Company"
         .Cells(1, 4) = "Job Title"
         .Cells(1, 5) = "Phone Number"
         .Cells(1, 6) = "Mailing Address"
         .Cells(1, 7) = "Birthday"
    End With
 
    Set objContacts = Application.Session.GetDefaultFolder(olFolderContacts).Items.Restrict("[Email1Address]>''")
 
    nRow = 2
    For i = 1 To objContactGroup.MemberCount
        Set objGroupMember = objContactGroup.GetMember(i)
 
        strFilter = "[Email1Address] = '" & objGroupMember.Address & "'"
        Set objFoundContact = objContacts.Find(strFilter)
 
        If Not (objFoundContact Is Nothing) Then
           'Input the Contact Details
           With objExcelWorkSheet
                .Cells(nRow, 1) = objFoundContact.FullName
                .Cells(nRow, 2) = objFoundContact.Email1Address
                .Cells(nRow, 3) = objFoundContact.CompanyName
                .Cells(nRow, 4) = objFoundContact.JobTitle
                .Cells(nRow, 5) = objFoundContact.BusinessTelephoneNumber
                .Cells(nRow, 6) = objFoundContact.MailingAddress
             If objFoundContact.Birthday = #1/1/4501# Then
                .Cells(nRow, 7) = ""
             Else
                .Cells(nRow, 7) = objFoundContact.Birthday
             End If
           End With
       Else
           With objExcelWorkSheet
               .Cells(nRow, 1) = objGroupMember.Name
               .Cells(nRow, 2) = objGroupMember.Address
           End With
       End If
       nRow = nRow + 1
    Next
 
    'Fit the columns
    objExcelWorkSheet.Columns("A:G").AutoFit
 
    'Change the Path as per where you want to save the new Excel file
    strFilename = "E:\" & objContactGroup.DLName & " Member Contact Details.xlsx"
    'Save the Excel workbook
    objExcelWorkBook.Close True, strFilename
 
    MsgBox ("Complete!")
End Sub

5. Nakon toga, za praktičnu provjeru, možete dodati novi VBA projekat na traku sa alatkama za brzi pristup ili traku.
6. Kasnije postavite svoj Outlook makro sigurnosni nivo na niski.
7. Na kraju, možete probati.

• Prvo odaberite grupu kontakata.
• Zatim pritisnite dugme za makro na traci sa alatkama za brzi pristup ili vrpci.
• Makro će se odmah pokrenuti.
• Kada se završi, dobit ćete upit "Završeno!"
• Nakon toga možete otići u unaprijed definiranu odredišnu lokalnu mapu u kojoj možete pronaći novu Excel datoteku.
• Otvorite ga, vidjet ćete kontakt detalje članova grupe kao što je sljedeći snimak ekrana:

Nemojte paničariti pred problemima sa Outlookom

Niko nije voljan prihvatiti bilo kakve probleme s Outlookom, bez obzira na popup poruku o grešci ili oštećeni Outlook fajl sa podacima. Stoga će korisnici biti skloni panici kada naiđu na probleme s Outlookom. Ako u tom slučaju želite da ostanete mirni, trebate imati dvije stvari koje su vam potrebne. Jedna je trenutna sigurnosna kopija podataka Outlook. Drugi je moćan Outlook softver za popravke, kao DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql oporavak i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com