Kako brzo pričvrstiti određene slajdove a PowerPoint Prezentacija na vašu Outlook e-poštu

Ako želite izdvojiti specifične slajdove a PowerPoint prezentaciju u posebnu novu prezentaciju i priložite je Outlook e-pošti, možete koristiti način na koji se dijeli u ovom članku.

Umjesto pričvršćivanja cjeline PowerPoint prezentaciju u e-poštu, ako želite da priložite određene slajdove prezentacije, općenito je potrebno da prvo kopirate određene slajdove u novu prezentaciju. To je previše problematično. Stoga, ovdje ćemo vam pokazati metodu koja to može realizirati u jednom potezu.

Priložite posebne slajdove a PowerPoint Prezentacija na e-mail

1. Prvo otvorite određeni PowerPoint prezentacija.
2. Zatim u PowerPoint prozoru aplikacije, pritisnite tastere “Alt + F11” da biste pristupili VBA editoru.
3. Zatim, u novom prozoru, kreirajte novi modul pritiskom na “Insert” > “Module”.
4. Nakon toga, kopirajte i zalijepite sljedeći VBA kod u ovaj modul.

Sub AttachSpecificSlidesToOutlookEmail()
    Dim objActivePresetation As Presentation
    Dim objSlide As Slide
    Dim n As Long
    Dim strName As String
    Dim strTempPresetation As String
    Dim objTempPresetation As Presentation
    Dim objOutlookApp As Object
    Dim objMail As Object
 
    Set objActivePresetation = ActivePresentation
 
    For Each objSlide In objActivePresetation.Slides
        objSlide.Tags.Delete ("Selected")
    Next
 
    'Add a tag "Selected" to the selected slides
    For n = 1 To ActiveWindow.Selection.SlideRange.Count
        ActiveWindow.Selection.SlideRange(n).Tags.Add "Selected", "YES"
    Next n
 
    strName = objActivePresetation.Name
    strName = Left(strName, InStrRev(strName, ".") - 1)
    strTempPresetation = Environ("TEMP") & "\" & strName & ".pptx"
 
    'Copy the active presentation to a temp presentation
    objActivePresetation.SaveCopyAs strTempPresetation
    Set objTempPresetation = Presentations.Open(strTempPresetation)
 
    'Remove the untagged slides
    For n = objTempPresetation.Slides.Count To 1 Step -1
        If objTempPresetation.Slides(n).Tags("Selected") <> "YES" Then
           objTempPresetation.Slides(n).Delete
        End If
    Next n
 
    objTempPresetation.Save
    objTempPresetation.Close
 
    'Attach the temp presentation to a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objMail = objOutlookApp.CreateItem(olMailItem)
 
    'Change the email details as per your needs
    With objMail
         .To = "test@datanumen.com"
         .Subject = strName
         .Body = "Dear," & vbCr & vbCr & vbTab & "Specific slides are extracted and attached."
         .Attachments.Add strTempPresetation
         .Display
    End With
End Sub

5. Nakon toga, možete zatvoriti trenutni prozor.
6. Kasnije idite na “File” > “Options” > “Quick Access Toolbar” da dodate novi makro na traku s alatima za brzi pristup.
7. Konačno, možete isprobati ovaj makro.

• Za astart, odaberite određene slajdove koje želite izdvojiti.
• Zatim kliknite na dugme makro na traci sa alatkama za brzi pristup.
• Odjednom će se pojaviti Outlook e-pošta u kojoj se nalazi a PowerPoint prezentaciju koja je izdvojena iz izvorne prezentacije.

Koristite efikasan alat za oporavak

Kao što svi znamo, Outlook je opremljen ugrađenim uslužnim programom za popravku – scanpst. Ipak, može jednostavno da se nosi sa malim kvarovima u Outlooku. Ako je ono sa čime se suočavate ozbiljna šteta, to neće imati efekta. U tom trenutku, nemate izbora nego da se vratite na još jedan moćan i pouzdan alat za popravku, kao što je DataNumen Outlook Repair. Pomoću njega ćete moći spasiti svoju oštećenu Outlook datoteku.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com