Kako brzo priložiti posljednju izmijenjenu datoteku u Windows folderu u Outlook e-poštu

Ponekad ćete možda htjeti brzo pronaći i priložiti posljednju izmijenjenu datoteku u određenoj Windows mapi u Outlook e-poruku. U tom slučaju možete koristiti metodu predstavljenu u ovom članku.

Neki korisnici žele da Outlook brzo pronađe i doda zadnju izmijenjenu datoteku u Windows mapi u e-poruku, kao što je nedavno kreirana, izmijenjena ili sačuvana datoteka. Međutim, Outlook ne nudi takvu direktnu i izvornu funkciju. Stoga ćemo u nastavku prikazati dio VBA koda koji to može lako realizirati.

Priložite posljednju izmijenjenu datoteku u Windows folderu u e-poštu

1. Na samom početku, trebali biste pokrenuti svoju Outlook aplikaciju.
2. Zatim, nakon što uđete u glavni Outlook prozor, možete pritisnuti tipke “Alt + F11”.
3. Zatim ćete uspješno pristupiti prozoru Outlook VBA editora.
4. Nakon toga, trebali biste pronaći i otvoriti modul koji se ne koristi.
5. Zatim kopirajte i zalijepite sljedeći VBA kod u prozor ovog modula.

Sub AttachLastModifiedSpecificFile()
    Dim objShell As Object
    Dim objSelectedFolder As Object
    Dim objFileSystem As Object
    Dim strSourceFolderPath As String
    Dim objSourceFolder As Object
    Dim objFile As Object
    Dim dLastModifiedDate As Date
    Dim strLastModifiedFilePath As String
    Dim objMail As Outlook.MailItem
 
    On Error GoTo ErrorHandler
    'Select a local source folder
    Set objShell = CreateObject("Shell.Application")
    Set objSelectedFolder = objShell.BrowseForFolder(0, "Select the source folder", 0, "")
    strSourceFolderPath = objSelectedFolder.self.Path
 
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    Set objSourceFolder = objFileSystem.GetFolder(strSourceFolderPath)
 
    If objSourceFolder.Files.Count > 0 Then
       For Each objFile In objSourceFolder.Files
           'Find the last modified file within "xlsx" file type in the selected Windows folder
           If (objFile.DateLastModified > dLastModifiedDate) And (objFileSystem.GetExtensionName(objFile) = "xlsx") Then
              'You can add or change criteria, such as
              'Left(objFile.Name, 4) = "Test" ---> file whose name begins with "Test"
              '(objFile / 1024) / 1024 > 2 --> File exceeds 2 MB
              'Note: Use "And" to connect more than one criteria
              strLastModifiedFilePath = objFile.Path
              dLastModifiedDate = objFile.DateLastModified
           End If
       Next
 
       If strLastModifiedFilePath <> "" Then
          'Confirm attaching it to the current outlook email
          strMsg = "The last modified file in the " & Chr(34) & strSourceFolderPath & Chr(34) & " is: " & vbCrLf & vbCrLf & "File: " & strLastModifiedFilePath & vbCrLf & "Date: " & dLastModifiedDate & vbCrLf & vbCrLf & "Do you want to attach it?"
          nPrompt = MsgBox(strMsg, vbQuestion + vbYesNo, "Confirm Attaching Last Modified File")
 
          If nPrompt = vbYes Then
             Set objMail = Outlook.Application.ActiveInspector.CurrentItem
             objMail.Attachments.Add strLastModifiedFilePath
         End If
      Else
         MsgBox "No file in the selected folder can meet your predefined criteria!", vbExclamation + vbOKOnly
      End If
    Else
      MsgBox "No file exists in the selected Windows folder!", vbExclamation + vbOKOnly
    End If
 
ErrorHandler:
    Exit Sub
End Sub

6. Nakon toga, možete izaći iz trenutnog prozora VBA editora i nastaviti sa dodavanjem novog makroa na traku sa alatkama za brzi pristup ili traku prozora poruke.
7. Kasnije ćete morati promijeniti nivo sigurnosti makroa Outlooka na niski.
8. Na kraju možete probati.

• Prvo, kreirajte i sastavite novu Outlook e-poštu kao i obično.
• Zatim pritisnite dugme za makro na traci sa alatkama za brzi pristup, kao na slici ispod:
• Zatim će se od vas tražiti da odaberete izvorni Windows folder i pritisnete “OK”.
• Ako postoji takva datoteka u odabranom Windows folderu, dobit ćete upit kao na sljedećem snimku ekrana:
• Kada pritisnete „Da“, ovaj fajl će biti priložen odjednom.

Riješite probleme s Outlookom što je prije moguće

Kad god naiđete na bilo kakve probleme s Outlookom, preporučuje se da ih riješite što je prije moguće. U ovoj situaciji, bolje je pripremiti robusnu Outlook popravka alat unapred, kao npr DataNumen Outlook Repair. U stanju je da popravi PST greške i efikasno spasi vaše Outlook podatke.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com