Kako efikasno dodati beleške u Outlook e-poštu putem VBA i korisničkog obrasca

Ponekad se možete nadati da ćete urediti ili dodati bilješke svojim e-porukama u Outlooku. Ovaj članak će vam predstaviti efikasan način za postizanje ove funkcije.

Od „4 jednostavna metoda za umetanje bilješke u Outlook poruke“, možete naučiti da umetnete bilješke u poštu putem izvornih funkcija Outlooka, kao što je korištenje prilagođenih zastavica, kucanje bilješke u predmetu ili tijelo ili prilaganje postojećih stavki bilješke ovoj e-poruci. Ipak, sve su to samo zaobilazna rješenja. Ovdje ćemo vas naučiti mnogo efikasnijoj metodi. Preko njega ćete moći dodavati bilješke u e-poštu i uređivati ​​ili brisati postojeće bilješke po želji.

Dodajte bilješke u Outlook e-poštu

1. Za početak, pristupite VBA editoru pritiskom na “Alt + F11” u Outlooku.
2. Zatim kliknite na “Insert” > “UserForm”.
3. Zatim, u novom korisničkom obrascu, kreirajte okvir za tekst kao na slici ispod.
4. Zatim promijenite “Name” tekstualnog okvira u “txtNotes”, kao na snimku ekrana.
5. Nakon toga kreirajte dva komandna dugmeta u obrascu.
6. Zatim odaberite “CommandButton 1”. Promijenite njegovo “Name” u “btnOK” i promijenite njegov “Caption” u “OK”.
7. Nakon toga, promijenite “Name” za “CommandVutton 2” u “btnCancel” i “Caption” u “Cancel”.
8. Zatim odaberite cijeli korisnički obrazac i promijenite njegovo “Name” u “frmAddNote” i “Caption” u “Unesite svoju bilješku”.
9. Nakon toga, kliknite desnim tasterom miša na “fromAddNote” i odaberite “View Code”.
10. Na novom ekranu kopirajte sljedeći kod u njega.

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objNote = Application.CreateItem(olNoteItem)
 
    objNote.Body = strNote
    objNote.Save
    objMail.Attachments.Add objNote
    objMail.Save
    objNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

11. Kasnije stavite VBA kod ispod u neiskorišteni modul.

Sub AddNote()
    frmAddNote.Show
End Sub

12. Na kraju, idite na “File” > “Options” > “Customize Ribbon” da dodate ovaj makro na vrpcu.
13. Sada možete probati. Odaberite e-poštu i kliknite na novo dugme „Dodaj napomenu“ na traci.
14. U iskačućem dijaloškom okviru možete unijeti svoju bilješku i kliknuti na “OK”.
15. Odmah će se odabranoj e-poruci dodati nova napomena.

Uredite ili izbrišite postojeće bilješke za Outlook e-poštu

Ponekad ćete možda htjeti urediti ili izbrisati sve postojeće bilješke u e-poruci. Možete slijediti dolje navedene korake.

1. Prvo, kreirajte drugi korisnički obrazac i nazovite ga kao “frmEditNote” i modificirajte njegov naslov u “Uredi svoju bilješku”.
2. Zatim umetnite novi okvir za tekst u obrazac i promijenite njegovo “Name” u “txtNotes”.
3. Zatim dodajte dva komandna dugmeta – “OK” i “Cancel”.
4. Nakon toga, kliknite desnim tasterom miša na “frmEditNote” i izaberite “View Code”.
5. U novu kodnu stranicu “frmEditNote” stavite sljedeći kod.

Private Sub UserForm_Initialize()
    Dim objAttachNote As Outlook.Attachment
    Dim objTempNote As Outlook.NoteItem

    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    Set objMail = objAttachNote.Parent
 
    If Right(objAttachNote.FileName, 3) = "msg" Then
       strTempFolder = Environ("Temp")
       strFilePath = strTempFolder & "\" & objAttachNote.FileName
       objAttachNote.SaveAsFile strFilePath
    End If
 
    Set objTempNote = Session.OpenSharedItem(strFilePath)
    txtNotes.Text = objTempNote.Body

    objTempNote.Close olDiscard
End Sub

Private Sub btnOK_Click()
    Dim strNote As String
    Dim objMail As Outlook.MailItem
    Dim objAttachNote As Outlook.Attachment
    Dim objNewNote As Outlook.NoteItem
 
    strNote = txtNotes.Text
 
    Set objNewNote = Application.CreateItem(olNoteItem)
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    Set objAttachNote = ActiveExplorer.AttachmentSelection.Item(1)
    objAttachNote.Delete

    objNewNote.Body = strNote
    objNewNote.Save
    objMail.Attachments.Add objNewNote
    objMail.Save
    objNewNote.Delete
    Unload Me
End Sub

Private Sub btnCancel_Click()
    Unload Me
End Sub

6. Nakon toga otvorite modul i kopirajte VBA kod u njega.

Sub EditNote()
    frmEditNote.Show
End Sub

Sub DeleteNotes()
    Dim objSelectedAttachments As Outlook.AttachmentSelection
    Dim objAttachment As Outlook.Attachment
    Dim objMail As Outlook.MailItem
 
    Set objSelectedAttachments = Application.ActiveExplorer.AttachmentSelection
 
    For Each objAttachment In objSelectedAttachments
        If Right(objAttachment.FileName, 3) = "msg" Then
           objAttachment.Delete
        End If
    Next
 
    Set objMail = Application.ActiveExplorer.Selection.Item(1)
    objMail.Save
End Sub

7. Konačno, možete dodati makroe “EditNote” i “DeleteNotes” na traku.
8. Na kraju, nakon što kliknete na “OK” i vratite se na glavni prozor, možete pokušati urediti bilješku.

• Odaberite bilješku i kliknite na dugme „Uredi belešku“.
• Zatim će se pojaviti novi dijaloški okvir u kojem možete urediti odabranu bilješku.
• Nakon uređivanja kliknite na “OK”. Bilješka će biti ažurirana.

9. Također, možete pokušati izbrisati sve bilješke.

• Odaberite bilješku koju želite izbrisati.
• Kliknite na dugme "Izbriši bilješke" na traci.
• Ova bilješka će se odmah izbrisati.

Spriječite Outlook od gubitka podataka

Tražite li moćno rješenje za blokiranje gubitka podataka u Outlooku? Iskreno, sve dok redovno pravite rezervne kopije podataka u Outlooku, možete s lakoćom izbjeći gubitak PST podataka. Na primjer, čak i ako se PST ošteti, i dalje možete lako oporaviti PST podaci iz sigurnosne kopije PST datoteke kao povjetarac.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporaviti sql i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com