Kako odgoditi isporuku određenom članu prilikom slanja Outlook e-pošte kontakt grupi

Ovaj članak će podijeliti dio VBA koda, koji vam može omogućiti da brzo odgodite isporuku određenom članu prilikom slanja e-pošte kontakt grupi u Outlooku.

Kada sastavite i pošaljete Outlook e-poruku grupi kontakata, ako želite da odgodite slanje ove e-pošte određenom članu u ovoj grupi, možete koristiti sljedeću metodu da to ostvarite. Automatski će proširiti grupu kontakata i generirati isti email koji je odgođen za određenog člana. Sada čitajte dalje da biste dobili detaljne korake.

Odgodite isporuku određenom članu prilikom slanja e-pošte kontakt grupi

1. Za početak, pokrenite Outlook program.
2. Zatim, u glavnom prozoru Outlooka koji se pojavljuje, trebate pritisnuti tipke “Alt + F11”.
3. Nakon toga, dobićete pristup Outlook VBA uređivaču, u koji treba da umetnete novi modul ili jednostavno otvorite modul koji nije u upotrebi.
4. Nakon toga, možete kopirati i zalijepiti sljedeći VBA kod u ovaj modul.

Sub DelayEmail_aSpecificMemberinContactGroup()
    Dim objCurrentMail As MailItem
    Dim objRecipients As Recipients
    Dim ContactGroupFound As Boolean
    Dim i, n As Long
    Dim objDelayedMail As MailItem
 
    Set objCurrentMail = ActiveInspector.CurrentItem
    ContactGroupFound = True
 
    While ContactGroupFound = True
          Set objRecipients = objCurrentMail.Recipients
          ContactGroupFound = False
 
          'Expand the contact group in "To" field
          For i = objRecipients.count To 1 Step -1
              If objRecipients(i).AddressEntry.DisplayType <> olUser Then
                 For n = 1 To objRecipients(i).AddressEntry.Members.count
                     If objRecipients(i).AddressEntry.Members.Item(n).DisplayType = olUser Then
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Address)
                     Else
                        objCurrentMail.Recipients.Add (objRecipients(i).AddressEntry.Members.Item(n).Name)
                        ContactGroupFound = True
                     End If
                 Next
                 objRecipients(i).Delete
              End If
          Next i
          objRecipients.ResolveAll
    Wend

    'Find the specific memebr in the recipients
    For Each objRecipient In objRecipients
        If objRecipient.Address = "shelly@datanumen.com" Then
 
           'Create a same email
           Set objDelayedMail = objCurrentMail.Copy
           With objDelayedMail
                .To = ""
                .Recipients.Add objRecipient.Address
                .Recipients.ResolveAll
                'Change the deferred delivery time as per your needs
                .DeferredDeliveryTime = (Date + 1) & " 09:00:00"
                .Send
          End With
 
          objRecipient.Delete
       End If
    Next
 
    objCurrentMail.Send
End Sub

5. Zatim, za kasniji praktičan pristup, bolje je da dodate novododati makro na alatnu traku za brzi pristup prozora poruke.
6. Zatim biste trebali promijeniti postavke makronaredbe Outlooka da biste omogućili sve makroe u "Postavke makroa" u "Centar za povjerenje".
7. Na kraju, možete pucati.

• Prvo, sastavite takav email kontakt grupi kao i obično.
• Zatim možete kliknuti na dugme za novi makro na traci sa alatkama za brzi pristup.
• Odjednom će se kreirati isti email koji će biti poslan određenom članu u zakazano vrijeme.
• U međuvremenu, trenutni email će biti poslat ostalim članovima u kontakt grupi.

Pazite na sve rizike oko vašeg Outlooka

U savremenom dobu, virusi i špijunski softver postaju sve rašireniji. Obično se maskiraju kao bezopasna e-pošta. Stoga biste trebali paziti na razne rizike u vezi s vašim Outlookom, kao što su zlonamjerne e-poruke. Morate biti oprezni s e-porukama od nepoznatih kontakata. Također, kako biste... popravi Outlook čim vašu PST datoteku napadne zlonamjerni softver, morate pripremiti iskusan alat za popravku, npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen sql i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com