Kako grupno ukloniti sve adrese e-pošte sa određenom domenom iz Outlook kontakata

Ponekad se možete nadati da ćete ukloniti sve adrese e-pošte sa određenom domenom iz svojih kontakata. U ovoj situaciji, sigurno niste voljni da to radite jedno po jedno. Dakle, ova strost će vas naučiti daleko pametnijoj metodi.

Na primjer, kompanija promijeni ime. U međuvremenu, domen kompanije se također mijenja. Međutim, u Outlooku ste pohranili mnogo kontakata u ovu kompaniju, čije su adrese e-pošte sa starim domenom. Naravno, ove e-mail adrese više nisu važeće. Stoga, pod ovim okolnostima, ako želite ukloniti ove adrese e-pošte odjednom, možete koristiti sljedeći način.

Grupno uklanjanje svih adresa e-pošte sa određenom domenom iz kontakata

1. Za astart, pristupite Outlook VBA editoru pomoću prečice na tipku – “Alt + F11”.
2. Zatim, u novom prozoru, postavite sljedeći VBA kod u prazan modul.

Dim strDomain As String

Sub BatchRemoveAllEmailAddressesInSpecificDomain()
    Dim objStore As Store
    Dim objFolder As Folder
    Dim lTotalCount As Long
 
    'Input the specific domain
    strDomain = InputBox("Enter the specific domain:", , "@false.com")
 
    If Len(strDomain) <> 0 Then
       lTotalCount = 0
       'Process all Contact folders in your Outlook
       For Each objStore In Application.Session.Stores
           For Each objFolder In objStore.GetRootFolder.Folders
               If objFolder.DefaultItemType = olContactItem Then
                  Call ProcessContactFolders(objFolder, lTotalCount)
               End If
           Next
       Next
 
       'Prompt you
       MsgBox lTotalCount & " email addresses in " & strDomain & " are removed!", vbInformation + vbOKOnly
    End If
End Sub

Sub ProcessContactFolders(ByVal objCurrentFolder As Folder, ByRef lCount As Long)
    Dim objContacts As Items
    Dim i As Long
    Dim objContact As ContactItem
 
    Set objContacts = objCurrentFolder.Items
 
    For i = objContacts.Count To 1 Step -1
        If TypeName(objContacts(i)) = "ContactItem" Then
           Set objContact = objContacts(i)
 
           'Check 3 email addresses of each contact
           If InStr(objContact.Email1Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email1Address = ""
              objContact.Email1DisplayName = ""
           ElseIf InStr(objContact.Email2Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email2Address = ""
              objContact.Email2DisplayName = ""
           ElseIf InStr(objContact.Email3Address, strDomain) > 0 Then
              lCount = lCount + 1
              objContact.Email3Address = ""
              objContact.Email3DisplayName = ""
           End If
 
           objContact.Save
        End If
     Next
 
     If objCurrentFolder.Folders.Count > 0 Then
        For Each objSubfolder In objCurrentFolder.Folders
            Call ProcessContactFolders(objSubfolder, lCount)
        Next
     End If
End Sub

3. Nakon toga, postavite kursor u potprogram “BatchRemoveAllEmailAddressesInSpecificDomain”.
4. Na kraju, kliknite na dugme "F5" da biste pokrenuli ovaj makro.
5. Nakon toga, u iskačući dijaloški okvir unesite određenu domenu.
6. Nakon klika na “OK”, makro će se pokrenuti.
7. Kada se završi, dobit ćete poruku o rezultatima.
8. Sada možete provjeriti kontakte. Mora da su nestale sve adrese e-pošte sa određenom domenom.

Sačuvajte svoju Outlook datoteku

Sa sve više rizika koji okružuju vaš Outlook, sve je teže zaštititi svoje vrijedne Outlook podatke. Na primjer, ne samo da biste trebali ustrajati u redovnim sigurnosnim kopijama podataka, već morate paziti i na svoje operacije. Nije mudro vjerovati bilo kakvoj e-poruci nepoznatih pošiljatelja. U suprotnom, ako nosi virus, vaša Outlook datoteka će biti zaražena. U tom trenutku morate pokušati Outlook popravak putem izvanrednog alata za popravku, kao što je DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oporavi se Sql Server i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com