Kako grupno ukloniti priloge iz zastarjelih stavki kalendara u vašem Outlooku

Ako želite ukloniti priloge sa zastarjelih sastanaka i sastanaka u Outlooku, možete pročitati ovaj članak. Ovdje ćemo vam predstaviti kako to realizirati u jednom potezu.

Da biste smanjili veličinu Outlook datoteke, vrlo je preporučljivo očistiti stare stavke. Ovo se može ostvariti ugrađenom funkcijom “AutoArchive”, koja može automatski izbrisati stare stavke u redovnim intervalima. Međutim, neki korisnici samo žele izbrisati priloge u starim stavkama bez utjecaja na same stavke. U nastavku ćemo vas naučiti kako grupno uklanjati priloge iz starih stavki kalendara.

Skupno uklanjanje priloga iz zastarjelih stavki kalendara

1. Za početak, pristupite Outlook VBA editoru pomoću “Alt + F11”.
2. Zatim, u prozoru „Microsoft Visual Basic za aplikacije“, kopirajte VBA kod u modul.

Sub BatchDeleteAttachmentsOfOldCalendarItems()
    Dim objOutlookFile As Outlook.Folder
    Dim objFolder As Outlook.Folder
 
    'Change to your own Outlook file
    Set objOutlookFile = Outlook.Application.Session.Folders("John Smith")
 
    For Each objFolder In objOutlookFile.Folders
        If objFolder.DefaultItemType = olAppointmentItem Then
           Call LoopCalendars(objFolder)
        End If
    Next
End Sub

Sub LoopCalendars(ByVal objCalendar As Outlook.Folder)
    Dim i, n As Long
    Dim objCalendarItem As Outlook.AppointmentItem
    Dim nDateDiff As Integer
    Dim objAttachments As Outlook.Attachments
    Dim objSubCalendar As Outlook.Folder
 
    For i = objCalendar.Items.Count To 1 Step -1
        Set objCalendarItem = objCalendar.Items(i)
 
        'Remove attachments from items that are more than 2 months old
        'Change the datediff as per your needs
        nDateDiff = DateDiff("m", objCalendarItem.End, Now) '=> "m" refers to month; "d" for day; "y" for year
        If nDateDiff > 2 Then
           Set objAttachments = objCalendarItem.Attachments
           If objAttachments.Count > 0 Then
              For n = objAttachments.Count To 1 Step -1
                  objAttachments(n).Delete
              Next
           End If
           objCalendarItem.Save
        End If
    Next

    'Process all subfolders recursively
    If objCalendar.Folders.Count > 0 Then
       For Each objSubCalendar In objCalendar.Folders
           Call LoopCalendars(objSubCalendar)
       Next
    End If
End Sub

3. Nakon toga kliknite na makro "BatchDeleteAttachmentsOfOldCalendarItems".
4. Na kraju, pritisnite dugme “F5” da pokrenete ovaj makro.
5. Kada se makro završi, možete provjeriti sve svoje Outlook kalendare.
6. Outlook mora da je obrisao sve priloge stavki kalendara koje su starije od 2 meseca.

Nosite se s oštećenim Outlook datotekama

Jeste li se ikada susreli s korupcijom u Outlooku? Kako ga obično odlažete? Češće nego ne, prvo biste isprobali alat za popravku pristigle pošte – scanpst. Ali, u slučaju ozbiljnog oštećenja PST-a, ugrađeni uslužni program vam ne može pomoći. Stoga se predlaže da u blizini držite iskusniji i izvanredniji alat treće strane, kao što je npr DataNumen Outlook Repair.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući sql repair i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com