Kako grupno otkazati sve Outlook sastanke zakazane u određenom rasponu datuma

Ako želite da otkažete sve sastanke zakazane u određenom rasponu datuma u vašem Outlooku, možete koristiti sredstva predstavljena u ovom članku. To vas može spasiti od ručnog pretraživanja i otkazivanja takvih sastanaka.

Ako iz nekog razloga ne možete da organizujete ili učestvujete na sastancima koji će se održati u određenom periodu u budućnosti, možda ćete želeti da otkažete sve takve sastanke. Općenito, prvo ih morate saznati, a zatim ih poništiti jednu po jednu. Biće prilično problematično. Stoga ćemo vam u nastavku podijeliti još jedan način, koji je daleko praktičniji.

Grupno otkazivanje svih sastanaka zakazanih u određenom rasponu datuma

1. Na samom početku, start vaš Outlook program.
2. Zatim, u Outlooku, trebate pritisnuti tipke “Alt + F11”.
3. Zatim ćete ući u prozor „Microsoft Visual Basic za aplikacije“.
4. U ovom prozoru trebate otvoriti neiskorišteni modul ili jednostavno umetnuti novi.
5. Nakon toga, možete kopirati sljedeći VBA kod u ovaj modul.

Sub BatchCancelAllMeetingsInSpecificDateRange()
    Dim dStartDate As Date
    Dim dEndDate As Date
    Dim objCalendarFolder As Outlook.folder
    Dim objItems As Outlook.Items
    Dim objItemsInDateRange As Outlook.Items
    Dim objAppointment As Outlook.AppointmentItem
    Dim objResponse As Outlook.MeetingItem
 
    'Specify the start date and end date
    dStartDate = InputBox("Enter the start date:", , "10/1/2017")
    dEndDate = InputBox("Enter the end date:", , "10/8/2017")
 
    If dStartDate <> #1/1/4501# And dEndDate <> #1/1/4501# Then
       'Select a calendar folder
       Set objCalendarFolder = Outlook.Application.Session.PickFolder
       Set objItems = objCalendarFolder.Items
       objItems.IncludeRecurrences = True
       objItems.Sort "[Start]"
 
       'Get the appointments in the specific date range
       strFilter = "[Start] >= " & Chr(34) & dStartDate & " 00:00 AM" & Chr(34) & " AND [End] <= " & Chr(34) & dEndDate & " 11:59 PM" & Chr(34)
       Set objItemsInDateRange = objItems.Restrict(strFilter)
 
       objItemsInDateRange.Sort "[Start]"
       For Each objAppointment In objItemsInDateRange
           'Cancel the meetings in this date range
           If objAppointment.MeetingStatus = olMeeting Then
              If objAppointment.Organizer = Outlook.Session.CurrentUser Then
                 objAppointment.MeetingStatus = olMeetingCanceled
                 objAppointment.Save
                 objAppointment.Send
                 objAppointment.Delete
              Else
                 Set objResponse = objAppointment.Respond(olMeetingDeclined)
                 objResponse.Send
                 objAppointment.Delete
              End If
            End If
       Next
    End If
End Sub

6. Na kraju, ovaj makro možete pokrenuti upravo sada.

• U trenutnom prozoru makroa, pritisnite dugme “F5”.
• Zatim ćete morati navesti raspon datuma.
• Nakon toga, prikazat će se drugi dijaloški okvir u kojem se traži da odaberete izvornu mapu kalendara i kliknete na “OK”.
• Na kraju, kada se makro završi, mogli biste vidjeti da su svi sastanci u određenom rasponu datuma otkazani.
• U folderu “Poslane stavke” možete pronaći otkazivanja sastanka, kao na slici ispod:

Popravite Outlook greške

Ako ste Outlook koristili decenijama, sigurno ste naišli na nekoliko grešaka. Na sreću Outlook dolazi sa ugrađenim alatom za popravku – Scanpst. Možete ga koristiti za popravi Outlook greške. Ipak, ako ne uspije, vaše posljednje sredstvo su vanjski alati za popravku kao što su DataNumen Outlook Repair. Može skenirati Outlook datoteku i popraviti most greške, pa čak i lako vratiti oštećene Outlook podatke.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popraviti sql i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com