Kako automatski premjestiti e-poštu s određenim primaocima CC u Outlook

U stvarnosti, većina vas se možda nada da će kreirati Outlook pravilo za automatsko premještanje e-poruka s određenim primaocima CC. Ali Outlook pravilo ne podržava provjeru primalaca CC. Stoga će vas ovaj članak naučiti kako to ostvariti pomoću Outlook VBA.

Očigledno, nemoguće je da kreirate Outlook pravilo za pretraživanje određenih CC primatelja. Kao što je prikazano na sljedećem snimku ekrana, za primljene e-poruke možete provjeriti samo da li se vaše ime nalazi u polju CC. Slično, za poslane e-poruke, čak i ne postoji uslov pravila za oznaku CC okvira.

Stoga, ako želite da konfigurišete Outlook da automatski premješta e-poštu s određenim primaocima CC-a, morate potražiti druge načine. Onda. ovdje ćemo vas naučiti kako to postići pomoću Outlook VBA.

Automatsko premještanje poslanih e-poruka sa određenim CC primateljima

1. Prvo idite na karticu „Developer“ i kliknite na dugme „Visual Basic“.
2. Zatim otvorite projekt “ThisOutlookSession” i kopirajte sljedeće VBA kodove u njega.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderSentMail).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim ccRecip As String
    Dim desFolder As Folder
 
    'Replace "test" with your desired CC'd recipient name or address
    ccRecip = "test"
    'The "Test" folder is a subfolder under "Sent Items" folder
    Set desFolder = Session.GetDefaultFolder(olFolderSentMail).Folders("Test")
 
    If InStr(LCase(Mail.CC), ccRecip) > 0 Then
       Mail.Move desFolder
    End If
End Sub

3. Nakon toga, trebali biste nastaviti s potpisivanjem ovog koda i promijeniti postavke makroa kao i obično.
4. Na kraju, možete izaći iz prozora “Visual Basic”. Nakon toga, e-poruke sa određenim primaocima CC će biti premještene u navedenu mapu pošte.

Automatsko premještanje primljenih e-poruka sa određenim CC primateljima

Sada kada gornji VBA kod ima za cilj da premesti poslate e-poruke sa određenim CC primaocima, ako želite da tražite određene CC primaoce u primljenim e-porukama i zatim ga premestite, trebalo bi da koristite sledeće kodove umesto toga.

Public WithEvents olItems As Outlook.Items

Sub Application_Startup()
    Set olItems = Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Sub olItems_ItemAdd(ByVal Item As Object)
    If Item.Class = olMail Then
       MoveMail Item
    End If
End Sub

Sub MoveMail(Mail As Outlook.MailItem)
    Dim Recips As Recipients
    Dim Recip As Recipient
    Dim ccRecip As String
    Dim desFolder As Folder
 
    Set Recips = Mail.Recipients
    'Replace "test" with the specific words in your desired CC recipient address
    ccRecip = "test"
 
    For Each Recip In Recips
        If Recip.Type = olCC Then
           If InStr(LCase(Recip.Address), ccRecip) > 0 Then
              'The "Test" folder is a subfolder under "Inbox" folder
              Set desFolder = Session.GetDefaultFolder(olFolderInbox).Folders("Test")
              Mail.Move desFolder
           End If
        End If
    Next
End Sub

Budite dobro pripremljeni za oštećenje Outlooka

Iako je Outlook bogat funkcijama, ipak ne može biti imun na korupciju. Stoga biste trebali biti oprezni protiv svih potencijalnih rizika. Bez sumnje, kritični korak mora biti pravljenje dosljedne i ažurirane sigurnosne kopije za Outlook podatke. Nadalje, trebali biste zadržati a oštećeni Outlook alat za oporavak u blizini. Dobro će doći ako i rezervne kopije i Scanpst.exe ne uspiju.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući Popravak SQL Server greška u mdf fajlu i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com