3 brza načina da izbrišete prazne redove i kolone u vašoj Word tabeli

U ovom postu ćemo vam objasniti 3 brza načina za brisanje praznih redova i kolona u vašoj Word tabeli.

Tabele su neophodne za dokument, posebno u držanju različitih vrsta podataka. Ponekad duga tabela može premašiti stranicu i proširiti se na nekoliko. Dakle, kada tabela postane duga i komplikovana, postoje mere koje možete preduzeti da je pojednostavite. Na primjer, možete izbrisati nepotrebne prazne redove i stupce.

Slijede 3 metode koje možete koristiti.

Metoda 1: Ručno brisanje praznih redova i kolona

1. Prvo odaberite prazan red ili kolonu.
2. Zatim kliknite desnim tasterom miša da biste dobili kontekstualni meni. Na izborniku odaberite “Delete Rows” ili “Delete Columns” u skladu s tim.

Nažalost, ne možete odabrati više redova ili kolona koji nisu uzastopni i izbrisati ih zajedno na ovaj način. Za ovu potražnju možete pogledati naš prethodni članak: 5 brzih metoda za grupno brisanje više redova ili kolona u vašoj Word tablici

Metoda 2: Grupno brisanje svih praznih redova i kolona u tabeli

Metoda 1 ima svoja ograničenja. Zato ćemo vam ponuditi način grupnog uklanjanja redova i kolona u tabeli putem VBA kodova.

1. Za početak, postavite kursor unutar ciljne tabele.
2. Drugo, pokrenite VBA editor pritiskom na “Alt+ F11”.
3. U uređivaču prvo kliknite na "Normalni" projekat.
4. Zatim kliknite na karticu "Insert" na traci menija.
5. Na padajućem izborniku odaberite "Modul".
6. Dvaput kliknite na modul da ga otvorite i tamo zalijepite sljedeće kodove:

Sub DeleteBlankRowsAndTablesInATable()
  Dim objCell As Cell
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  If Selection.Information(wdWithInTable) = False Then
    MsgBox ("Put cursor inside a table first!")
    Exit Sub
  Else
    With Selection.Tables(1)
      nRows = .Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Rows(nRowIndex).Delete
          End If
      Next nRowIndex
 
      nColumns = .Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In .Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            .Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    End With
  End If

  Set objCell = Nothing

  Application.ScreenUpdating = True
End Sub

7. Na kraju, kliknite na dugme “Run” na traci menija ili pritisnite “F5”.

Za nekoliko sekundi uklonit ćete sve prazne redove i stupce u toj tablici.

Metoda 3: Grupno brisanje svih praznih redova i kolona u svim tabelama u dokumentu

1. Prvo, ponovite korake iz metode 2 da biste instalirali i pokrenuli makro.
2. Samo ovaj put, zamijenite taj makro sa sljedećim:

Sub DeleteBlankRowsAndColumnsInAllTables()
  Dim objCell As Cell
  Dim objTable As Table
  Dim nRowIndex As Integer, nRows As Integer, nColumns As Integer, nColumnIndex As Integer
  Dim varCellEmpty As Boolean
 
  Application.ScreenUpdating = False
 
  With ActiveDocument
    For Each objTable In .Tables
      nRows = objTable.Rows.Count
      For nRowIndex = nRows To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Rows(nRowIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Rows(nRowIndex).Delete
          End If
      Next nRowIndex
    Next objTable
 
    For Each objTable In .Tables
      nColumns = objTable.Columns.Count
      For nColumnIndex = nColumns To 1 Step -1
        varCellEmpty = True
        For Each objCell In objTable.Columns(nColumnIndex).Cells
          If Len(objCell.Range.Text) > 2 Then
            varCellEmpty = False
            Exit For
          End If
        Next objCell
          If varCellEmpty = True Then
            objTable.Columns(nColumnIndex).Delete
          End If
      Next nColumnIndex
    Next objTable
  End With

  Set objCell = Nothing
  Set objTable = Nothing

  Application.ScreenUpdating = True
End Sub

Oporavi slomljeni dokument

Danas postoji više od jednog načina za vraćanje izgubljenih podataka. Na primjer, pribjegavanje sigurnosnim kopijama uvijek ostaje vaš glavni prioritet. Ako to ne zadovoljava vašu potrebu za vraćanjem najnovijih informacija, možete pokušati... doc repair alat.

Uvod za autora:

Vera Chen je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući xlsx repair i pdf popravak softverskih proizvoda. Za više informacija posjetite www.datanumen.com