2 načina za brzo spajanje više Word dokumenata u jedan putem VBA

U ovom članku drago nam je da podijelimo s vama 2 načina za brzo spajanje više Word dokumenata u jedan putem VBA.

U Wordu postoji podrazumevana ugrađena funkcija koja pomaže korisniku da kombinuje ili spoji nekoliko dokumenata u jedan. Detalji su objašnjeni u ovom članku: Kako spojiti i spojiti više Word dokumenata u jedan

Kod ove metode morate napraviti nekoliko klikova i sadržaj sljedećeg dokumenta uvijek dolazi odmah iza prethodnog. Stoga vam želimo ponuditi brže načine da to učinite.

Metoda 1: Spojite odabrane dokumente u jedan

1. Prvo i najvažnije, kreirajte novi prazan dokument.
2. Pokrenite VBA editor u Wordu pritiskom na “Alt+ F11”.
3. Zatim kliknite na “Normalno”.
4. Zatim kliknite na “Insert”.
5. I odaberite “Module”.
6. Dvaput kliknite na novi modul da otvorite prostor za uređivanje.
7. Tamo zalijepite sljedeći makro:

Sub MergeMultiDocsIntoOne()
  Dim dlgFile As FileDialog
  Dim nTotalFiles As Integer
  Dim nEachSelectedFile As Integer

  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    .AllowMultiSelect = True
    If .Show <> -1 Then
      Exit Sub
    Else
      nTotalFiles = .SelectedItems.Count
    End If
  End With
 
  For nEachSelectedFile = 1 To nTotalFiles
    Selection.InsertFile dlgFile.SelectedItems.Item(nEachSelectedFile)
    If nEachSelectedFile < nTotalFiles Then
      Selection.InsertBreak Type:=wdPageBreak
    Else
      If nEachSelectedFile = nTotalFiles Then
        Exit Sub
      End If
    End If
  Next nEachSelectedFile
End Sub

8. Zatim kliknite na “Run” ili pritisnite “F5”.
9. Sada u prozoru "Pretraži" odaberite više datoteka pritiskom na "Ctrl" i kliknite "OK".
10. Zatim će sav sadržaj odabranih datoteka biti spojen u novom dokumentu, pri čemu će tekstovi svakog dokumenta početi na novoj stranici.

Bilješka:

Kao što smo spomenuli, ovaj makro stavlja tekstove svakog dokumenta na novu stranicu. Ali ako trebate da budu jedan za drugim, možete promijeniti neke linije koda u makrou. Samo pronađite redak “If nEachSelectedFile < nTotalFiles Then”, izbrišite ga i sljedećih šest redova.

Metoda 2: Spojite sve dokumente u fascikli u jedan

U slučaju da imate fasciklu sa datotekama za kombinovanje, onda će ovaj makro raditi prelepo.

1. Za početak, instalirajte i pokrenite makro kao što je opisano u metodi 1.
2. Zatim zamijenite makro sa ovim:

Sub MergeFilesInAFolderIntoOneDoc()
  Dim dlgFile As FileDialog
  Dim objDoc As Document, objNewDoc As Document
  Dim StrFolder As String, strFile As String
 
  Set dlgFile = Application.FileDialog(msoFileDialogFolderPicker)
 
  With dlgFile
    If .Show = -1 Then
      StrFolder = .SelectedItems(1) & "\"
    Else
      MsgBox ("No folder is selected!")
      Exit Sub
    End If
  End With
 
  strFile = Dir(StrFolder & "*.docx", vbNormal)
  Set objNewDoc = Documents.Add
 
  While strFile <> ""
    Set objDoc = Documents.Open(FileName:=StrFolder & strFile)
    objDoc.Range.Copy
    objNewDoc.Activate
    With Selection
      .Paste
      .InsertBreak Type:=wdPageBreak
      .Collapse wdCollapseEnd
    End With
 
    objDoc.Close SaveChanges:=wdDoNotSaveChanges
 
    strFile = Dir()
  Wend
 
  objNewDoc.Activate
  Selection.EndKey Unit:=wdStory
  Selection.Delete
End Sub

3. Pokrenite makro tako što ćete kliknuti na “Run”.
4. Zatim vidite da je otvoren prozor "Pretraži". Odaberite fasciklu u koju ćete pohraniti sve dokumente. I kliknite na “OK”.

Slično tome, tekstovi svakog dokumenta počinju na novoj stranici. Da biste ih spojili jedan za drugim, pronađite i izbrišite liniju koda „.InsertBreak Type:=wdPageBreak“.

Propisno zaštitite svoj Word dokument

Jedan od najboljih načina da zaštitite svoje Word dokumente je da ih redovno pravite rezervne kopije. Sa rezervnim kopijama u ruci, nikada se nećete morati plašiti gubitka podataka. Osim toga, preporučljivo je nabaviti i alat popraviti docx ako se neko od njih ošteti.

Uvod za autora:

Vera Chen je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući oštećen Excel i pdf popravak softverskih proizvoda. Za više informacija posjetite www.datanumen.com