2 brza načina da pronađete ili izbrišete rečenice koje sadrže određeni tekst u vašoj riječi

U ovom članku ćemo vam ponuditi 2 brza načina da pronađete ili izbrišete rečenice koje sadrže određeni tekst u vašem Wordu.

Svima je poznato da možemo koristiti funkciju "Pronađi i zamijeni" u Wordu kako bismo lako pronašli sva pojavljivanja određenih riječi. Tada nećemo imati problema s njihovim označavanjem, zamjenom ili uklanjanjem. Kao što vidite, cilj je riječ ili fraza. Međutim, danas vam s ponosom predstavljamo makro način za pronalaženje ili brisanje rečenica koje sadrže određeni tekst.

Metoda 1: Pronađite ili izbrišite rečenice koje sadrže određeni tekst

1. Za početak pritisnite “Alt+ F11” da pokrenete VBA editor u Wordu.
2. Zatim kreirajte novi modul klikom na “Normalno”.
3. Zatim kliknite na “Insert” i odaberite “Module” da dobijete novi.
4. I otvorite modul dvostrukim klikom.
5. Sada zalijepite sljedeće kodove:

Sub DeleteSentencesContainingSpecificWords()
  Dim strTexts As String
  Dim strButtonValue As String
 
  strTexts = InputBox("Enter texts to be found here: ")
 
  With Selection
    .HomeKey Unit:=wdStory
 
    '  Find the entered texts.
    With Selection.Find
      .ClearFormatting
      .Text = strTexts
      .Replacement.Text = ""
      .Forward = True
      .Wrap = wdFindContinue
      .Format = False
      .MatchCase = False
      .MatchWholeWord = False
      .MatchWildcards = False
      .MatchSoundsLike = False
      .MatchAllWordForms = False
      .Execute
    End With
 
    Do While .Find.Found = True
      '  Expand the selection to the entire sentence.
      Selection.Expand Unit:=wdSentence
      strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
      If strButtonValue = vbYes Then
        Selection.Delete
      End If
      .Collapse wdCollapseEnd
      .Find.Execute
    Loop
  End With
End Sub

6. Zatim kliknite na “Run”.
7. Pojaviće se okvir za unos u kojem će se tražiti da unesete tekst. Samo upišite uobičajeni tekst koji sadrže sve rečenice. Kliknite na “OK”.
8. Tada ćete vidjeti rečenicu koja sadrži tekst u odabiru s okvirom za poruku koji će se pojaviti. Kliknite "Da" da obrišete rečenicu i "Ne" da je zadržite.
9. Nakon potvrde, sljedeća rečenica s određenim tekstom je u selekciji. Tu je i okvir za potvrdu. Naime, makro vas vodi kroz cijeli dokument, pronalazeći ciljane rečenice i svaki put tražeći vašu potvrdu.

Metoda 2: Pronađite ili izbrišite rečenice koje sadrže bilo koji tekst na listi

Sa makroom u metodi 1, možete tražiti samo jednu riječ ili frazu. Naravno, makro možete pokrenuti više puta da biste tražili višestruke instance riječi ili fraza. Da bismo zadovoljili potrebu višestrukog pretraživanja, obezbijedit ćemo vam još jedan makro.

1. Prvo stavite sve ciljne tekstove u novi dokument. Pobrinite se da svaki dio teksta zauzima jedan paragraf bez razmaka na kraju. Zatvorite i sačuvajte dokument.
2. Zatim instalirajte i pokrenite makro s tačnim koracima u metodi 1.
3. Zatim zamijenite makro sa ovim:

Sub DeleteSentencesContainingSpecificWordsOnAList()
  Dim objListDoc As Document, objTargetDoc As Document
  Dim objParaRange As Range
  Dim objParagraph As Paragraph
  Dim strFileName As String, strButtonValue As String
  Dim dlgFile As FileDialog
 
  Set dlgFile = Application.FileDialog(msoFileDialogFilePicker)
 
  With dlgFile
    If .Show = -1 Then
      strFileName = .SelectedItems(1)
    Else
      MsgBox "No file is selected! Please select the target file."
      Exit Sub
    End If
  End With
  Set objTargetDoc = ActiveDocument
  Set objListDoc = Documents.Open(strFileName)
  objTargetDoc.Activate
 
  For Each objParagraph In objListDoc.Paragraphs
    Set objParaRange = objParagraph.Range
    objParaRange.End = objParaRange.End - 1
 
    With Selection
      .HomeKey Unit:=wdStory
 
      '  Find target words.
      With Selection.Find
        .ClearFormatting
        .Text = objParaRange
        .MatchWholeWord = True
        .MatchCase = False
        .Execute
      End With
 
      '  Expand the selection to the entire sentence.
      Do While .Find.Found
        Selection.Expand Unit:=wdSentence
        strButtonValue = MsgBox("Are you sure to delete the sentence?", vbYesNo)
        If strButtonValue = vbYes Then
          Selection.Delete
        End If
        .Collapse wdCollapseEnd
        .Find.Execute
      Loop
    End With
  Next objParagraph
End Sub

4. Sada će se otvoriti prozor “Browse”. Odaberite dokument koji ste upravo sačuvali i kliknite na “Otvori”.
5. Sljedeća procedura je ista kao u metodi 1.

Pristup rješavanju korumpiranih dokumenata

Gubitak vrijednih podataka je apsolutno poražavajući. To čak može ostaviti vaš posao na kocki. Da biste izbjegli takvu frustraciju, trebate nabaviti a Word fix alat što je pre moguće. Takav alat će vam pomoći da dobijete bitku s korupcijom dokumenata.

Uvod za autora:

Vera Chen je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popraviti Excel i pdf popravak softverskih proizvoda. Za više informacija posjetite www.datanumen.com