2 metode za brzo slanje odabranih ćelija u Excel radnom listu kao Outlook e-poruka

Podijeli sada:

Ponekad ćete možda htjeti brzo umetnuti odabrane ćelije u Excel radni list u Outlook e-poštu i poslati ovu e-poštu. Ovaj članak će se osvrnuti na ovu želju da vam ponudi 2 metode.

Moj prethodni članak “2 brza metoda za slanje Excel radnog lista kao Outlook e-pošte” vas je naučio kako da pošaljete cijeli Excel radni list kao e-poštu. Međutim, ponekad želite samo poslati odabrane ćelije na radnom listu kao e-poštu. Kao odgovor na ovaj zahtjev, ovdje ćemo vam izložiti 2 metode. Možete odabrati bilo koje prema vašim željama.

2 metode za brzo slanje odabranih ćelija u Excel radnom listu kao Outlook e-poruka

Metoda 1: Kopirajte odabrane ćelije za ručnu e-poštu

  1. Za početak, otvorite izvornu Excel datoteku i pristupite odgovarajućem Excel radnom listu.
  2. Zatim odaberite ćelije koje želite poslati kao Outlook e-poštu.
  3. Zatim pritisnite tipke “Ctrl + C” da biste kopirali odabrane ćelije.Pritisnite tasterske prečice “Ctrl + C” da biste kopirali odabrane ćelije
  4. Nakon toga pokrenite svoju Outlook aplikaciju.
  5. Zatim kliknite na dugme „Nova e-pošta” na traci „Početna” da biste kreirali novu Outlook e-poštu.
  6. Kasnije u novom prozoru poruke kliknite na odjeljak tijela poruke.
  7. Zatim pritisnite tipke “Ctrl + V” da biste zalijepili prethodno kopirane odabrane Excel ćelije.
  8. Na kraju, možete sastaviti e-poruku kao i obično i kliknuti na dugme „Pošalji“ da biste je poslali.

Metoda 2: Pošaljite odabrane ćelije kao e-poštu putem VBA

  1. Na samom početku otvorite izvornu Excel radnu svesku.
  2. Zatim pritisnite tipke “Alt + F11” za pristup Excel VBA editoru.
  3. U novom prozoru kliknite na “Insert” > “Module” da umetnete novi modul.
  4. Zatim biste trebali omogućiti Microsoft Outlook objekte. Kliknite na "Alati" > "Reference". U skočnom dijaloškom okviru pronađite i označite "Microsoft Outlook Object Library".Omogućite Microsoft Outlook objekat u Excelu
  5. Nakon toga, kopirajte sljedeći VBA kod u ovaj modul.
Sub SendSelectedCells_inOutlookEmail()
    Dim objSelection As Excel.Range
    Dim objTempWorkbook As Excel.Workbook
    Dim objTempWorksheet As Excel.Worksheet
    Dim strTempHTMLFile As String
    Dim objTempHTMLFile As Object
    Dim objFileSystem As Object
    Dim objTextStream As Object
    Dim objOutlookApp As Outlook.Application
    Dim objNewEmail As Outlook.MailItem
 
    'Copy the selection
    Set objSelection = Selection
    Selection.Copy
 
    'Paste the copied selected ranges into a temp worksheet
    Set objTempWorkbook = Excel.Application.Workbooks.Add(1)
    Set objTempWorksheet = objTempWorkbook.Sheets(1)
 
    'Keep the values, column widths and formats in pasting
    With objTempWorksheet.Cells(1)
         .PasteSpecial xlPasteValues
         .PasteSpecial xlPasteColumnWidths
         .PasteSpecial xlPasteFormats
    End With
 
    'Save the temp worksheet as a HTML file
    Set objFileSystem = CreateObject("Scripting.FileSystemObject")
    strTempHTMLFile = objFileSystem.GetSpecialFolder(2).Path & "\Temp for Excel" & Format(Now, "YYYY-MM-DD hh-mm-ss") & ".htm"
    Set objTempHTMLFile = objTempWorkbook.PublishObjects.Add(xlSourceRange, strTempHTMLFile, objTempWorksheet.Name, objTempWorksheet.UsedRange.Address)
    objTempHTMLFile.Publish (True)
 
    'Create a new email
    Set objOutlookApp = CreateObject("Outlook.Application")
    Set objNewEmail = objOutlookApp.CreateItem(olMailItem)
 
    'Read the HTML file data and insert into the email body
    Set objTextStream = objFileSystem.OpenTextFile(strTempHTMLFile)
    objNewEmail.HTMLBody = objTextStream.ReadAll
    objNewEmail.Display
    'You can specify the new email recipients, subjects here using the following lines:
    'objNewEmail.To = "johnsmith@datanumen.com"
    'objNewEmail.Subject = "DataNumen Products"
    'objNewEmail.Send --> directly send out this email
 
    objTextStream.Close
    objTempWorkbook.Close (False)
    objFileSystem.DeleteFile (strTempHTMLFile)
End Sub

VBA kod - Pošaljite odabrane ćelije u Excel radnom listu kao Outlook e-poštu

  1. Na kraju, možete probati.
  • Prvo, odaberite određene ćelije kao i obično.
  • Zatim se vratite na novi makro i pritisnite taster F5 da ga aktivirate.
  • Odjednom će se prikazati nova Outlook e-pošta u kojoj možete vidjeti da su odabrane ćelije umetnute u tijelo e-pošte, kao na sljedećem snimku ekrana:Nova e-pošta koja sadrži odabrane Excel ćelije

PST datoteka je ista ranjiva kao i Excel datoteka

Kao što znamo, Excel datoteke i Word dokumenti su skloni oštećenju. Zapravo, isto važi i za PST datoteku, koja sadrži sve stavke u vašem Outlook poštanskom sandučiću. Dakle, zaštita vaših PST podataka je težak zadatak. Jedna od najefikasnijih mjera je redovno pravljenje sigurnosnih kopija datoteke. Osim toga, kako biste osigurali trenutno spašavanje, bolje je da pripremite iskusan alat, kao što je DataNumen Outlook Repair, koji je u stanju da oporaviti Outlook podataka bez znojenja.

Uvod za autora:

Shirley Zhang je stručnjak za oporavak podataka DataNumen, Inc., koji je svjetski lider u tehnologijama za oporavak podataka, uključujući popraviti mdf i Outlook softverski proizvodi za popravku. Za više informacija posjetite www.datanumen.com

Podijeli sada:

Komentari su zatvoreni.